mirror of
https://github.com/NotAShelf/nvf.git
synced 2026-03-05 00:12:55 +00:00
6dba3fd0a7
Some checks are pending
Set up binary cache / cachix (default) (push) Waiting to run
Set up binary cache / cachix (maximal) (push) Waiting to run
Set up binary cache / cachix (nix) (push) Waiting to run
Treewide Checks / Validate flake (push) Waiting to run
Treewide Checks / Check formatting (push) Waiting to run
Treewide Checks / Check source tree for typos (push) Waiting to run
Treewide Checks / Validate documentation builds (push) Waiting to run
Treewide Checks / Validate documentation builds-1 (push) Waiting to run
Treewide Checks / Validate documentation builds-2 (push) Waiting to run
Treewide Checks / Validate documentation builds-3 (push) Waiting to run
Treewide Checks / Validate hyperlinks in documentation sources (push) Waiting to run
Treewide Checks / Validate Editorconfig conformance (push) Waiting to run
Build and deploy documentation / Check latest commit (push) Waiting to run
Build and deploy documentation / publish (push) Blocked by required conditions
Signed-off-by: phanirithvij <phanirithvij2000@gmail.com> Co-authored-by: Ching Pei Yang <59727193+horriblename@users.noreply.github.com>
74 lines
1.7 KiB
Nix
74 lines
1.7 KiB
Nix
{
|
|
config,
|
|
pkgs,
|
|
lib,
|
|
...
|
|
}: let
|
|
inherit (builtins) attrNames;
|
|
inherit (lib.options) mkEnableOption mkOption;
|
|
inherit (lib.modules) mkIf mkMerge;
|
|
inherit (lib.types) enum;
|
|
inherit (lib.nvim.types) mkGrammarOption deprecatedSingleOrListOf;
|
|
inherit (lib.meta) getExe;
|
|
inherit (lib.nvim.attrsets) mapListToAttrs;
|
|
|
|
cfg = config.vim.languages.elm;
|
|
|
|
defaultServers = ["elm-language-server"];
|
|
servers = {
|
|
elm-language-server = {
|
|
enable = true;
|
|
cmd = [(getExe pkgs.elmPackages.elm-language-server)];
|
|
filetypes = ["elm"];
|
|
root_markers = ["elm.json"];
|
|
workspace_required = false;
|
|
};
|
|
};
|
|
in {
|
|
options.vim.languages.elm = {
|
|
enable = mkEnableOption "Elm language support";
|
|
|
|
treesitter = {
|
|
enable =
|
|
mkEnableOption "Elm treesitter"
|
|
// {
|
|
default = config.vim.languages.enableTreesitter;
|
|
};
|
|
package = mkGrammarOption pkgs "elm";
|
|
};
|
|
|
|
lsp = {
|
|
enable =
|
|
mkEnableOption "Elm LSP support"
|
|
// {
|
|
default = config.vim.lsp.enable;
|
|
};
|
|
|
|
servers = mkOption {
|
|
type = deprecatedSingleOrListOf "vim.language.elm.lsp.servers" (enum (attrNames servers));
|
|
default = defaultServers;
|
|
description = "Elm LSP servers to use";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
(mkIf cfg.treesitter.enable {
|
|
vim.treesitter = {
|
|
enable = true;
|
|
grammars = [cfg.treesitter.package];
|
|
};
|
|
})
|
|
|
|
(mkIf cfg.lsp.enable {
|
|
vim = {
|
|
lsp.servers =
|
|
mapListToAttrs (n: {
|
|
name = n;
|
|
value = servers.${n};
|
|
})
|
|
cfg.lsp.servers;
|
|
};
|
|
})
|
|
]);
|
|
}
|