languages/elm: init (#1432)

Signed-off-by: phanirithvij <phanirithvij2000@gmail.com>
Co-authored-by: Ching Pei Yang <59727193+horriblename@users.noreply.github.com>

docs/manual/release-notes/rl-0.9.md

@@ -274,6 +274,12 @@ https://github.com/gorbit99/codewindow.nvim
 - [img-clip.nvim]'s configuration now has it's own DAG entry, separate from
   image-nvim.
 
+[phanirithvij](https://github.com/phanirithvij):
+
+[elm-language-server]: https://github.com/elm-tooling/elm-language-server
+
+- Add Elm support with [elm-language-server]
+
 [alv-around](https://github.com/alv-around):
 
 - Fix `vim.assistant.codecompanion-nvim` lazy loading with [blink-cmp]

modules/plugins/languages/default.nix

@@ -14,6 +14,7 @@ in {
     ./cmake.nix
     ./css.nix
     ./elixir.nix
+    ./elm.nix
     ./fsharp.nix
     ./gleam.nix
     ./glsl.nix

modules/plugins/languages/elm.nix

@@ -0,0 +1,74 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum;
+  inherit (lib.nvim.types) mkGrammarOption deprecatedSingleOrListOf;
+  inherit (lib.meta) getExe;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.elm;
+
+  defaultServers = ["elm-language-server"];
+  servers = {
+    elm-language-server = {
+      enable = true;
+      cmd = [(getExe pkgs.elmPackages.elm-language-server)];
+      filetypes = ["elm"];
+      root_markers = ["elm.json"];
+      workspace_required = false;
+    };
+  };
+in {
+  options.vim.languages.elm = {
+    enable = mkEnableOption "Elm language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "Elm treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+        };
+      package = mkGrammarOption pkgs "elm";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Elm LSP support"
+        // {
+          default = config.vim.lsp.enable;
+        };
+
+      servers = mkOption {
+        type = deprecatedSingleOrListOf "vim.language.elm.lsp.servers" (enum (attrNames servers));
+        default = defaultServers;
+        description = "Elm LSP servers to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim = {
+        lsp.servers =
+          mapListToAttrs (n: {
+            name = n;
+            value = servers.${n};
+          })
+          cfg.lsp.servers;
+      };
+    })
+  ]);
+}