$ cachix use neovim-flake # Optional: it'll save you CPU resources and time
$ nix run github:notashelf/neovim-flake # will run the default configuration

$ nix run github:notashelf/neovim-flake#nix
$ nix run github:notashelf/neovim-flake#tidal
$ nix run github:notashelf/neovim-flake#maximal

While you can configure neovim-flake yourself using the builder, here are a few default configurations you can use.

$ nix run github:notashelf/neovim-flake#tidal file.tidal

$ nix run github:notashelf/neovim-flake#nix test.nix

$ nix shell github:notashelf/neovim-flake#maximal test.nix

Custom configuration is done with the neovimConfiguration function. It takes in the configuration as a module. The output of the configuration function is an attrset.

{
  options = "The options that were available to configure";
  config = "The outputted configuration";
  pkgs = "The package set used to evaluate the module";
  neovim = "The built neovim package";
}

The following is an example of a barebones vim configuration with the default theme enabled.

{
  inputs.neovim-flake = {
    url = "github:notashelf/neovim-flake";
    inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = {nixpkgs, neovim-flake, ...}: let
    system = "x86_64-linux";
    pkgs = nixpkgs.legacyPackages.${system};
    configModule = {
      # Add any custom options (and feel free to upstream them!)
      # options = ...

      config.vim = {
        theme.enable = true;
      };
    };

    customNeovim = neovim-flake.lib.neovimConfiguration {
      modules = [configModule];
      inherit pkgs;
    };
  in {
    packages.${system}.neovim = customNeovim.neovim;
  };
}

You can use custom plugins, before they are implemented in the flake. To add a plugin, you need to add it to your config’s config.vim.startPlugins array. This is an example of adding the FrenzyExists/aquarium-vim plugin:

{
  config.vim.startPlugins = [
    (pkgs.fetchFromGitHub {
      owner = "FrenzyExists";
      repo = "aquarium-vim";
      rev = "d09b1feda1148797aa5ff0dbca8d8e3256d028d5";
      sha256 = "CtyEhCcGxxok6xFQ09feWpdEBIYHH+GIFVOaNZx10Bs=";
    })
  ];
}

However, just making the plugin available might not be enough. In that case, you can write custom vimscript or lua config, using config.vim.configRC or config.vim.luaConfigRC respectively. These options are attribute sets, and you need to give the configuration you’re adding some name, like this:

{
  config.vim.configRC.aquarium = "colorscheme aquiarum";
}

Note: If your configuration needs to be put in a specific place in the config, you can use functions from inputs.neovim-flake.lib.nvim.dag to order it. Refer to https://github.com/nix-community/home-manager/blob/master/modules/lib/dag.nix.

Also, if you successfully made your plugin work, please make a PR to add it to the flake, or open an issue with your findings so that we can make it available for everyone easily.

The Home Manager module allows us to customize the different vim options. To use it, we first add the input flake.

{
  neovim-flake = {
    url = github:notashelf/neovim-flake;
    # you can override input nixpkgs
    inputs.nixpkgs.follows = "nixpkgs";
  };
}

Followed by importing the HM module.

{
  imports = [ neovim-flake.homeManagerModules.default ];
}

Then we should be able to use the given module. E.g.

{
  programs.neovim-flake = {

    enable = true;
    # your settings need to go into the settings attrset
    settings = {
      vim.viAlias = false;
      vim.vimAlias = true;
      vim.lsp = {
        enable = true;
      };
    };
  };
}

{
  programs.neovim-flake = {
    enable = true;
    settings = {
      vim.startPlugins = [ pkgs.vimPlugins.nvim-surround ];
    };
  };
}

{
  programs.neovim-flake = {
    enable = true;
    settings = {
      vim.startPlugins = [ pkgs.vimPlugins.nvim-surround ];
      luaConfigRC.nvim-surround = nvim-flake.lib.nvim.dag.entryAnywhere '' # nvim-flake is a reference to the flake. Please change this accordingly to your config.
        require("nvim-surround").setup()
      '';
    };
  };
}

Language specific support means there is a combination of language specific plugins, treesitter support, nvim-lspconfig language servers, and null-ls integration. This gets you capabilities ranging from autocompletion to formatting to diagnostics. The following languages have sections under the vim.languages attribute. See the configuration docs for details.

Adding support for more languages, and improving support for existing ones are great places where you can contribute with a PR.