feat: initialise Nix tooling

Adds a package, and a dev shell for Discorss. `nix run .#` and `nix develop` will be allowed in the current mechanism, but direnv users can simply use `direnv allow` to enter a shell directly.

.envrc

@@ -0,0 +1 @@
+use flake . --builders ""

README.md

@@ -23,7 +23,7 @@ Logging was recently enabled. Make sure that the user running the script (especi
 
 To configure the script, create ~/.config/discorss/discorss.conf with the following structure:
 
-```json
+```
 {
     "feeds": [
         {
@@ -54,7 +54,7 @@ To automate feed posting, create a systemd service and timer to execute the scri
 
 Use the command `systemctl --user edit --full --force discorss.service` and then paste in something like this:
 
-```systemd
+```
 [Unit]
 Description=Discord RSS feeder
 Wants=discorss.timer
@@ -68,7 +68,7 @@ WantedBy=default.target
 ```
 
 Make sure to edit the ExecStart to point to the correct location. Then we need a systemd timer to automatically fire the script. Run `systemctl --user edit --full --force discorss.timer` and then paste in this:
-```systemd
+```
 [Unit]
 Description=Timer for DiscoRSS
 Requires=discorss.service

discorss.py

@@ -89,7 +89,7 @@ def setupPaths():
             Path(config_dir).mkdir(parents=True, exist_ok=True)
         except FileExistsError:
             print(
-                "The config dir {} already exists and is not a directory! Please fix manually. Quitting!".format(
+                "The config dir {} already exists and is not a directory! Please fix manually.".format(
                     config_dir
                 )
             )
@@ -138,12 +138,11 @@ def main():
             else:
                 continue
         if bad_time is True:
-            logger.debug(
+            logger.warning(
                 "Feed %s doesn't supply a published time, using updated time instead",
                 hook["name"],
             )
         # Hash the title and time of the latest post and use that to determine if it's been posted
-        # Yes, SHA3-512 is totally unnecessary for this purpose, but I love SHA3
         new_hash = hashlib.sha3_512(
             bytes(latest_post["title"] + str(published_time), "utf-8")
         ).hexdigest()

flake.lock

@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1741851582,
+        "narHash": "sha256-cPfs8qMccim2RBgtKGF+x9IBCduRvd/N5F4nYpU0TVE=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "6607cf789e541e7873d40d3a8f7815ea92204f32",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,34 @@
+{
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs?ref=nixos-unstable";
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    # Compose a flake for multiple systems directly. More systems, e.g. aarch64-darwin
+    # can be supported by adding them to the systems list.
+    systems = ["x86_64-linux" "aarch64-linux"];
+    forEachSystem = nixpkgs.lib.genAttrs systems;
+    pkgsForEach = nixpkgs.legacyPackages;
+  in {
+    packages = forEachSystem (system: {
+      # Add a discorss package, and alias default package to it.
+      # This will allow 'nix run .', which calls the default package.
+      default = self.packages.${system}.discorss;
+      discorss = pkgsForEach.${system}.callPackage ./nix/package.nix {};
+    });
+
+    devShells = forEachSystem (system: {
+      default = pkgsForEach.${system}.mkShellNoCC {
+        packages = [
+          # Add the Discorss package to the shell
+          self.packages.${system}.discorss
+
+          # Add the *dependencies* of the Discorss package to the shell
+          # so that it can be used to hack on the script itself.
+          self.packages.${system}.discorss.propagatedBuildInputs
+        ];
+      };
+    });
+  };
+}

nix/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenvNoCC,
+  makeWrapper,
+  python312,
+  ...
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "discorss";
+  version = "0.0.1";
+
+  # Point to the repository root for the source. `builtins.path` is used to construct
+  # a pure and reproducible source path that doesn't change based on the name
+  # of the directory our source code lives in. Alternative to this is to just use it
+  # directly, as follows:
+  # `src = ../.;`
+  src = builtins.path {
+    path = ../.;
+    name = "discorss"; # the directory will always be named discorss in the eyes of Nix
+    filter = lib.cleanSourceFilter; # avoid copying junk files and vsc dirs to the store
+  };
+
+  # programs and libraries *used at build-time* that, if they are a compiler or similar tool, produce
+  # code to run at run-time. In other words, tools used to build the new derivation
+  # Alternative is buildInputs, which includes programs and libraries used by the new derivation at run-time
+  nativeBuildInputs = [makeWrapper];
+
+  # Normally propagatedBuildInputs get, well, propagated to the final build. This is not the
+  # case for s since we omit a handful of shell hooks that would handle it for us. We can
+  # still use propagatedBuildInputs to remain close to the standard, but we will have to
+  # pass it to the wrapper manually.
+  propagatedBuildInputs = [
+    # Create a python wrapper with the dependencies that we need.
+    # This will produce a /nix/store/some-hash-python/bin/python3 that has the modules
+    # our program needs.
+    (python312.withPackages (ps: with ps; [feedparser requests]))
+  ];
+
+  dontUnpack = true; # source is not an archive
+  dontConfigure = true; # there is no configure script
+  dontPatch = true; # we are building from source, patches are redundant
+
+  buildPhase = ''
+    runHook preBuild
+
+    # Create a wrapper for Discorss with the specific version of Python (with dependencies)
+    # added to its PATH.
+    makeWrapper $src/discorss.py $out/bin/discorss \
+      --prefix PATH : "${lib.makeBinPath finalAttrs.propagatedBuildInputs}"
+
+    runHook postBuild
+  '';
+})