nvf/modules/plugins/diagnostics/nvim-lint/config.nix

{
  config,
  lib,
  ...
}: let
  inherit (lib.modules) mkIf mkMerge;
  inherit (lib.generators) mkLuaInline;
  inherit (lib.nvim.dag) entryAnywhere;
  inherit (lib.nvim.lua) toLuaObject;

  cfg = config.vim.diagnostics.nvim-lint;
in {
  config = mkMerge [
    (mkIf cfg.enable {
      vim = {
        startPlugins = ["nvim-lint"];
        pluginRC.nvim-lint = entryAnywhere ''
          require("lint").linters_by_ft = ${toLuaObject cfg.linters_by_ft}

          local linters = require("lint").linters
          local nvf_linters = ${toLuaObject cfg.linters}
          for linter, config in pairs(nvf_linters) do
            if linters[linter] == nil then
              linters[linter] = config
            else
              for key, val in pairs(config) do
                linters[linter][key] = val
              end
            end
          end

          function nvf_lint(buf)
            local ft = vim.api.nvim_get_option_value("filetype", { buf = buf })
            local linters = require("lint").linters
            local linters_from_ft = require("lint").linters_by_ft[ft]

            -- if no linter is configured for this filetype, stops linting
            if linters_from_ft == nil then return end

            for _, name in ipairs(linters_from_ft) do
              local linter = linters[name]
              assert(linter, 'Linter with name `' .. name .. '` not available')

              if type(linter) == "function" then
                linter = linter()
              end
              -- for require("lint").lint() to work, linter.name must be set
              linter.name = linter.name or name
              local cwd = linter.required_files

              -- if no configuration files are configured, lint
              if cwd == nil then
                require("lint").lint(linter)
              else
                -- if configuration files are configured and present in the project, lint
                for _, fn in ipairs(cwd) do
                  local path = vim.fs.joinpath(linter.cwd or vim.fn.getcwd(), fn);
                  if vim.uv.fs_stat(path) then
                    require("lint").lint(linter)
                    break
                  end
                end
              end
            end
          end
        '';
      };
    })
    (mkIf (cfg.enable && cfg.lint_after_save) {
      vim = {
        augroups = [{name = "nvf_nvim_lint";}];
        autocmds = [
          {
            event = ["BufWritePost"];
            callback = mkLuaInline ''
              function(args)
                nvf_lint(args.buf)
              end
            '';
          }
        ];
      };
    })
  ];
}