mirror of
https://github.com/NotAShelf/nvf.git
synced 2025-10-31 02:52:37 +00:00
21fcace3ed* flake: add lz.n and lzn-auto-require * lazy: init module * lzn-auto-require: add init lua code * wrapper: fix opt plugin format * lib.binds: add lz.n variant of bind functions * telescope: lazy load * nvim-tree: lazy load * dapui: lazy load * trouble: lazy load * toggleterm: lazy load * cheatsheet: lazy load * diffview: lazy load * icon-picker: lazy load * leap: lazy load * fidget: lazy load * docs: add section on lazy plugins * lazy: support lazy.enable=false * comment-nvim: lazy load * surround-nvim: lazy load * neo-tree: lazy load * fixup! lazy: init module * dap: appease the nix gods (fix statix lint) * flake.lock: fix merge mistake * doc: update release note * fixup! doc: update release note * neo-tree: fix duplicate neo-tree install * lazy: use attrsOf for lazy.plugins * treewide: update lazy.plugins syntax * docs: update lazy.plugins syntax * lazy: cleanup * Update docs/manual/hacking/additional-plugins.md Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com> * formatting nitpick Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com> * typo tee hee :3 Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com> * typo tee hee :4 Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com> * flake: update lz.n * lazy: update lz.n plugin spec * lazy: allow lines in place of str for lua code * copilot: lazy load * cmp: lazy load this moves cmp itself to lazy.plugins but other plugins that call cmp are not yet lazy so cmp is technically not yet lazy * luasnip: lazy load * flake: add rtp.nvim * cmp: actually lazy load source * fixup! cmp: actually lazy load source * format * docs: fix broken link * cmp-nvim-lsp: lazy load * lazy: allow key mode of str type * cmp: install sourcess via cmp.sourcePlugins * Update docs/manual/hacking/additional-plugins.md Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com> * lazy: refactor common var * nvim-dap-ui: add setupOpts * refactor: re-order plugin and lz.n configs lazy: make lzn-auto-require togglable * docs: update dag-entries * trouble: remove redundant import * lazy: remove unused module arg * toggleterm: make lazygit keybind optional * toggleterm: use toLuaObject for clarity * surround: rework keymap config * remove stale FIXME * lsp: use cmp_nvim_lsp capabilities * cmp: deduplicate attr key * theme: ensure themes load before lazy plugins * doc: update description of `theme` dag entry * lsp: avoid loading cmp on startup * doc: update configuration docs on custom plugins * cmp: skip trigger_load if lazy disabled * treesitter: remove redundant code * lsp: mark hack as HACK * comment: remove redundant plugin * Squash merge v0.7 into feature/lzn --------- Co-authored-by: raf <raf@notashelf.dev> Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>
75 lines
2 KiB
Nix
75 lines
2 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
...
|
|
}: let
|
|
inherit (lib.options) mkOption;
|
|
inherit (lib.attrsets) attrNames;
|
|
inherit (lib.strings) hasPrefix;
|
|
inherit (lib.types) bool lines enum;
|
|
inherit (lib.modules) mkIf;
|
|
inherit (lib.nvim.attrsets) mapListToAttrs;
|
|
inherit (lib.nvim.dag) entryBefore;
|
|
inherit (lib.nvim.types) hexColor;
|
|
|
|
cfg = config.vim.theme;
|
|
supportedThemes = import ./supported-themes.nix {
|
|
inherit lib config;
|
|
};
|
|
|
|
numbers = ["0" "1" "2" "3" "4" "5" "6" "7" "8" "9" "A" "B" "C" "D" "E" "F"];
|
|
base16Options =
|
|
mapListToAttrs (n: {
|
|
name = "base0${n}";
|
|
value = mkOption {
|
|
description = "The base0${n} color to use";
|
|
type = hexColor;
|
|
apply = v:
|
|
if hasPrefix "#" v
|
|
then v
|
|
else "#${v}";
|
|
};
|
|
})
|
|
numbers;
|
|
in {
|
|
options.vim.theme = {
|
|
enable = mkOption {
|
|
type = bool;
|
|
description = "Enable theming";
|
|
};
|
|
name = mkOption {
|
|
type = enum (attrNames supportedThemes);
|
|
description = ''
|
|
Supported themes can be found in {file}`supportedThemes.nix`.
|
|
Setting the theme to "base16" enables base16 theming and
|
|
requires all of the colors in {option}`vim.theme.base16-colors` to be set.
|
|
'';
|
|
};
|
|
base16-colors = base16Options;
|
|
|
|
style = mkOption {
|
|
type = enum supportedThemes.${cfg.name}.styles;
|
|
description = "Specific style for theme if it supports it";
|
|
};
|
|
transparent = mkOption {
|
|
type = bool;
|
|
default = false;
|
|
description = "Whether or not transparency should be enabled. Has no effect for themes that do not support transparency";
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = lines;
|
|
description = "Additional lua configuration to add before setup";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
vim = {
|
|
startPlugins = [cfg.name];
|
|
luaConfigRC.theme = entryBefore ["pluginConfigs" "lazyConfigs"] ''
|
|
${cfg.extraConfig}
|
|
${supportedThemes.${cfg.name}.setup {inherit (cfg) style transparent base16-colors;}}
|
|
'';
|
|
};
|
|
};
|
|
}
|