{
  config,
  pkgs,
  lib,
  ...
}: let
  inherit (lib) genAttrs;
  inherit (lib.modules) mkIf mkMerge;
  inherit (lib.options) literalExpression mkEnableOption mkOption;
  inherit (lib.types) enum listOf;
  inherit (lib.nvim.types) mkGrammarOption;

  cfg = config.vim.languages.jinja;

  defaultServers = ["jinja-lsp"];
  servers = ["jinja-lsp"];
in {
  options.vim.languages.jinja = {
    enable = mkEnableOption "Jinja template language support";

    treesitter = {
      enable =
        mkEnableOption "Jinja treesitter"
        // {
          default = config.vim.languages.enableTreesitter;
          defaultText = literalExpression "config.vim.languages.enableTreesitter";
        };
      package = mkGrammarOption pkgs "jinja";
      inlinePackage = mkGrammarOption pkgs "jinja_inline";
    };

    lsp = {
      enable =
        mkEnableOption "Jinja LSP support"
        // {
          default = config.vim.lsp.enable;
          defaultText = literalExpression "config.vim.lsp.enable";
        };
      servers = mkOption {
        description = "Jinja LSP server to use";
        type = listOf (enum servers);
        default = defaultServers;
      };
    };
  };

  config = mkIf cfg.enable (mkMerge [
    (mkIf cfg.treesitter.enable {
      vim.treesitter.enable = true;
      vim.treesitter.grammars = [
        cfg.treesitter.package
        cfg.treesitter.inlinePackage
      ];
    })

    (mkIf cfg.lsp.enable {
      vim.lsp = {
        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
        servers = genAttrs cfg.lsp.servers (_: {
          filetypes = ["jinja"];
        });
      };
    })
  ]);
}