improve helper functions

docs/release-notes/rl-0.7.md

@@ -99,6 +99,8 @@ configuration formats.
     yourself by adding `vim.opt.listchars:append({ eol = '<char>' })` to your
     lua configuration
 
+- Pre-compile lua files using LuaJIT for performance. Can be disabled with `vim.byteCompileLua = false`.
+
 [Neovim documentation on `vim.cmd`]: https://neovim.io/doc/user/lua.html#vim.cmd()
 
 - Make Neovim's configuration file entirely Lua based. This comes with a few
@@ -140,10 +142,10 @@ configuration formats.
 - Add [neo-tree.nvim] as an alternative file-tree plugin. It will be available
   under `vim.filetree.neo-tree`, similar to nvimtree.
 
-- Add `print-nvf-config` & `print-nvf-config-path` helper scripts to Neovim
+- Add `nvf-print-config` & `nvf-print-config-path` helper scripts to Neovim
   closure. Both of those scripts have been automatically added to your PATH upon
   using neovimConfig or `programs.nvf.enable`.
-  - `print-nvf-config` will display your `init.lua`, in full.
-  - `print-nvf-config-path` will display the path to _a clone_ of your
+  - `nvf-print-config` will display your `init.lua`, in full.
+  - `nvf-print-config-path` will display the path to _a clone_ of your
     `init.lua`. This is not the path used by the Neovim wrapper, but an
     identical clone.

modules/default.nix

@@ -7,11 +7,10 @@ inputs: {
   extraModules ? [],
 }: let
   inherit (pkgs) vimPlugins;
-  inherit (pkgs.vimUtils) buildVimPlugin;
   inherit (lib.strings) isString toString;
   inherit (lib.lists) filter map concatLists;
-  inherit (lib.attrsets) recursiveUpdate getAttr;
-  inherit (lib.asserts) assertMsg;
+  inherit (lib.attrsets) recursiveUpdate;
+  inherit (builtins) baseNameOf;
 
   # import modules.nix with `check`, `pkgs` and `lib` as arguments
   # check can be disabled while calling this file is called
@@ -30,15 +29,34 @@ inputs: {
   # alias to the internal configuration
   vimOptions = module.config.vim;
 
+  luajit = vimOptions.package.lua;
+
   # build a vim plugin with the given name and arguments
   # if the plugin is nvim-treesitter, warn the user to use buildTreesitterPlug
   # instead
-  buildPlug = {pname, ...} @ attrs: let
-    src = getAttr ("plugin-" + pname) inputs;
+  buildPlug = attrs: let
+    src = inputs."plugin-${attrs.pname}";
   in
     pkgs.stdenvNoCC.mkDerivation ({
-        inherit src;
         version = src.shortRev or src.shortDirtyRev or "dirty";
+
+        inherit src;
+
+        nativeBuildInputs = with pkgs.vimUtils; [
+          luajit
+
+          vimCommandCheckHook
+          vimGenDocHook
+          neovimRequireCheckHook
+        ];
+        passthru.vimPlugin = true;
+
+        buildPhase = lib.optionalString vimOptions.byteCompileLua ''
+          runHook preBuild
+          find . -type f -name '*.lua' -exec luajit -bd -- {} {} \;
+          runHook postBuild
+        '';
+
         installPhase = ''
           runHook preInstall
 
@@ -50,41 +68,27 @@ inputs: {
       }
       // attrs);
 
-  noBuildPlug = {pname, ...} @ attrs: let
-    input = getAttr ("plugin-" + pname) inputs;
-  in
-    {
-      version = input.shortRev or input.shortDirtyRev or "dirty";
-      outPath = getAttr ("plugin-" + pname) inputs;
-    }
-    // attrs;
-
   buildTreesitterPlug = grammars: vimPlugins.nvim-treesitter.withPlugins (_: grammars);
 
+  pluginBuilders = {
+    nvim-treesitter = buildTreesitterPlug vimOptions.treesitter.grammars;
+    flutter-tools-patched =
+      buildPlug
+      {
+        pname = "flutter-tools";
+        patches = [../patches/flutter-tools.patch];
+      };
+  };
+
   buildConfigPlugins = plugins:
     map
-    (plug: (
-      if (isString plug)
-      then
-        (
-          if (plug == "nvim-treesitter")
-          then (buildTreesitterPlug vimOptions.treesitter.grammars)
-          else if (plug == "flutter-tools-patched")
-          then
-            (
-              buildPlug
-              {
-                pname = "flutter-tools";
-                patches = [../patches/flutter-tools.patch];
-              }
-            )
-          else noBuildPlug {pname = plug;}
-        )
-      else plug
-    ))
-    (filter
-      (f: f != null)
-      plugins);
+    (
+      plug:
+        if (isString plug)
+        then pluginBuilders.${plug} or (buildPlug {pname = plug;})
+        else plug
+    )
+    (filter (f: f != null) plugins);
 
   # built (or "normalized") plugins that are modified
   builtStartPlugins = buildConfigPlugins vimOptions.startPlugins;
@@ -100,6 +104,16 @@ inputs: {
   extraLuaPackages = ps: map (x: ps.${x}) vimOptions.luaPackages;
   extraPython3Packages = ps: map (x: ps.${x}) vimOptions.python3Packages;
 
+  luaConfig =
+    if vimOptions.byteCompileLua
+    then pkgs.runCommandLocal "init.lua" {text = vimOptions.builtLuaConfigRC;} "${luajit}/bin/luajit -bd -- - $out <<< \"$text\""
+    else pkgs.writeText "init.lua" vimOptions.builtLuaConfigRC;
+
+  extraLuaFiles =
+    if vimOptions.byteCompileLua
+    then map (file: pkgs.runCommandLocal (baseNameOf file) {} "${luajit}/bin/luajit -bd -- ${file} $out") vimOptions.extraLuaFiles
+    else vimOptions.extraLuaFiles;
+
   # Wrap the user's desired (unwrapped) Neovim package with arguments that'll be used to
   # generate a wrapped Neovim package.
   neovim-wrapped = inputs.mnw.lib.wrap pkgs {
@@ -107,27 +121,17 @@ inputs: {
     plugins = concatLists [builtStartPlugins builtOptPlugins];
     appName = "nvf";
     extraBinPath = vimOptions.extraPackages;
-    initLua = vimOptions.builtLuaConfigRC;
-    luaFiles = vimOptions.extraLuaFiles;
+    luaFiles = [luaConfig] ++ extraLuaFiles;
 
     inherit (vimOptions) viAlias vimAlias withRuby withNodeJs withPython3;
     inherit extraLuaPackages extraPython3Packages;
   };
 
+  dummyInit = pkgs.writeText "nvf-init.lua" vimOptions.builtLuaConfigRC;
   # Additional helper scripts for printing and displaying nvf configuration
   # in your commandline.
-  printConfig = pkgs.writers.writeDashBin "print-nvf-config" ''
-    cat << EOF
-      ${vimOptions.builtLuaConfigRC}
-    EOF
-  '';
-
-  printConfigPath = pkgs.writers.writeDashBin "print-nvf-config-path" ''
-    realpath ${pkgs.writeTextFile {
-      name = "nvf-init.lua";
-      text = vimOptions.builtLuaConfigRC;
-    }}
-  '';
+  printConfig = pkgs.writers.writeDashBin "nvf-print-config" "cat ${dummyInit}";
+  printConfigPath = pkgs.writers.writeDashBin "nvf-print-config-path" "echo -n ${dummyInit}";
 in {
   inherit (module) options config;
   inherit (module._module.args) pkgs;
@@ -137,7 +141,7 @@ in {
   neovim = pkgs.symlinkJoin {
     name = "nvf-with-helpers";
     paths = [neovim-wrapped printConfig printConfigPath];
-    postBuild = "echo helpers added";
+    postBuild = "echo Helpers added";
 
     meta = {
       description = "Wrapped version of Neovim with additional helper scripts";

modules/wrapper/rc/options.nix

@@ -23,6 +23,13 @@ in {
   ];
 
   options.vim = {
+    byteCompileLua = mkOption {
+      type = bool;
+      default = true;
+      example = false;
+      description = "Enable the pre-compilation of lua files using LuaJIT.";
+    };
+
     enableLuaLoader = mkEnableOption ''
       the experimental Lua module loader to speed up the start up process