Merge 8268f13bdd into 21fcace3ed

* flake: add lz.n and lzn-auto-require

* lazy: init module

* lzn-auto-require: add init lua code

* wrapper: fix opt plugin format

* lib.binds: add lz.n variant of bind functions

* telescope: lazy load

* nvim-tree: lazy load

* dapui: lazy load

* trouble: lazy load

* toggleterm: lazy load

* cheatsheet: lazy load

* diffview: lazy load

* icon-picker: lazy load

* leap: lazy load

* fidget: lazy load

* docs: add section on lazy plugins

* lazy: support lazy.enable=false

* comment-nvim: lazy load

* surround-nvim: lazy load

* neo-tree: lazy load

* fixup! lazy: init module

* dap: appease the nix gods (fix statix lint)

* flake.lock: fix merge mistake

* doc: update release note

* fixup! doc: update release note

* neo-tree: fix duplicate neo-tree install

* lazy: use attrsOf for lazy.plugins

* treewide: update lazy.plugins syntax

* docs: update lazy.plugins syntax

* lazy: cleanup

* Update docs/manual/hacking/additional-plugins.md

Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

* formatting nitpick

Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

* typo tee hee :3

Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

* typo tee hee :4

Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

* flake: update lz.n

* lazy: update lz.n plugin spec

* lazy: allow lines in place of str for lua code

* copilot: lazy load

* cmp: lazy load

this moves cmp itself to lazy.plugins but other plugins that call cmp
are not yet lazy so cmp is technically not yet lazy

* luasnip: lazy load

* flake: add rtp.nvim

* cmp: actually lazy load source

* fixup! cmp: actually lazy load source

* format

* docs: fix broken link

* cmp-nvim-lsp: lazy load

* lazy: allow key mode of str type

* cmp: install sourcess via cmp.sourcePlugins

* Update docs/manual/hacking/additional-plugins.md

Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

* lazy: refactor common var

* nvim-dap-ui: add setupOpts

* refactor: re-order plugin and lz.n configs

lazy: make lzn-auto-require togglable

* docs: update dag-entries

* trouble: remove redundant import

* lazy: remove unused module arg

* toggleterm: make lazygit keybind optional

* toggleterm: use toLuaObject for clarity

* surround: rework keymap config

* remove stale FIXME

* lsp: use cmp_nvim_lsp capabilities

* cmp: deduplicate attr key

* theme: ensure themes load before lazy plugins

* doc: update description of `theme` dag entry

* lsp: avoid loading cmp on startup

* doc: update configuration docs on custom plugins

* cmp: skip trigger_load if lazy disabled

* treesitter: remove redundant code

* lsp: mark hack as HACK

* comment: remove redundant plugin

* Squash merge v0.7 into feature/lzn

---------

Co-authored-by: raf <raf@notashelf.dev>
Co-authored-by: diniamo <55629891+diniamo@users.noreply.github.com>

configuration.nix

@@ -63,19 +63,18 @@ isMaximal: {
       dart.enable = isMaximal;
       bash.enable = isMaximal;
       r.enable = isMaximal;
+      haskell.enable = isMaximal;
       tailwind.enable = isMaximal;
       typst.enable = isMaximal;
-      clang = {
-        enable = isMaximal;
-        lsp.server = "clangd";
-      };
-
+      clang.enable = isMaximal;
       scala.enable = isMaximal;
       rust = {
         enable = isMaximal;
         crates.enable = isMaximal;
       };
       csharp.enable = isMaximal;
+      julia.enable = isMaximal;
+      vala.enable = isMaximal;
     };
 
     visuals = {

docs/manual/configuring/custom-plugins.md

@@ -20,6 +20,7 @@ custom plugins that you might have added to your configuration.
 
 ```{=include=} sections
 custom-plugins/configuring.md
-custom-plugins/new-method.md
-custom-plugins/old-method.md
+custom-plugins/lazy-method.md
+custom-plugins/non-lazy-method.md
+custom-plugins/legacy-method.md
 ```

docs/manual/configuring/custom-plugins/configuring.md

@@ -1,12 +1,32 @@
 # Configuring {#sec-configuring-plugins}
 
-Just making the plugin to your Neovim configuration available might not always
-be enough. In that case, you can write custom lua config using either
-`config.vim.extraPlugins` (which has the `setup` field) or
-`config.vim.luaConfigRC`. The first option uses an attribute set, which maps DAG
-section names to a custom type, which has the fields `package`, `after`,
-`setup`. They allow you to set the package of the plugin, the sections its setup
-code should be after (note that the `extraPlugins` option has its own DAG
+Just making the plugin to your Neovim configuration available might not always be enough. In that
+case, you can write custom lua config using either `config.vim.lazy.plugins.*.setupOpts`
+`config.vim.extraPlugins.*.setup` or `config.vim.luaConfigRC`. 
+
+The first option uses an extended version of `lz.n`'s PluginSpec. `setupModule` and `setupOpt` can
+be used if the plugin uses a `require('module').setup(...)` pattern. Otherwise, the `before` and
+`after` hooks should do what you need.
+
+```nix
+{
+  config.vim.lazy.plugins = {
+    aerial-nvim = {
+      # ^^^^^^^^^ this name should match the package.pname or package.name
+      package = aerial-nvim;
+
+      setupModule = "aerial";
+      setupOpts = {option_name = false;};
+
+      after = "print('aerial loaded')";
+    };
+  };
+}
+```
+
+The second option uses an attribute set, which maps DAG section names to a custom type, which has
+the fields `package`, `after`, `setup`. They allow you to set the package of the plugin, the
+sections its setup code should be after (note that the `extraPlugins` option has its own DAG
 scope), and the its setup code respectively. For example:
 
 ```nix
@@ -24,7 +44,7 @@ config.vim.extraPlugins = with pkgs.vimPlugins; {
 }
 ```
 
-The second option also uses an attribute set, but this one is resolved as a DAG
+The third option also uses an attribute set, but this one is resolved as a DAG
 directly. The attribute names denote the section names, and the values lua code.
 For example:
 

docs/manual/configuring/custom-plugins/lazy-method.md

@@ -0,0 +1,40 @@
+# Lazy Method {#sec-lazy-method}
+
+As of version **0.7**, we exposed an API for configuring lazy-loaded plugins via
+`lz.n` and `lzn-auto-require`.
+
+```nix
+{
+  config.vim.lazy.plugins = {
+    aerial = {
+      package = pkgs.vimPlugins.aerial-nvim;
+      setupModule = aerial;
+      setupOpts = {
+        option_name = true;
+      };
+      after = ''
+        -- custom lua code to run after plugin is loaded
+        print('aerial loaded')
+      '';
+
+      # Explicitly mark plugin as lazy. You don't need this if you define one of
+      # the trigger "events" below
+      lazy = true;
+
+      # load on command
+      cmd = ["AerialOpen"];
+
+      # load on event
+      event = ["BufEnter"];
+
+      # load on keymap
+      keys = [
+        {
+          key = "<leader>a";
+          action = ":AerialToggle<CR>";
+        }
+      ];
+    };
+  };
+}
+```

docs/manual/configuring/custom-plugins/legacy-method.md

@@ -1,4 +1,4 @@
-# Old Method {#sec-old-method}
+# Legacy Method {#sec-legacy-method}
 
 Prior to version 0.5, the method of adding new plugins was adding the plugin
 package to `vim.startPlugins` and add its configuration as a DAG under one of

docs/manual/configuring/custom-plugins/non-lazy-method.md

@@ -1,4 +1,4 @@
-# New Method {#sec-new-method}
+# Non-lazy Method {#sec-non-lazy-method}
 
 As of version **0.5**, we have a more extensive API for configuring plugins,
 under `vim.extraPlugins`. Instead of using DAGs exposed by the library, you may

docs/manual/configuring/dag-entries.md

@@ -12,12 +12,14 @@ entries in nvf:
 2. `globalsScript` - used to set globals defined in `vim.globals`
 3. `basic` - used to set basic configuration options
 4. `optionsScript` - used to set options defined in `vim.o`
-5. `theme` (this is simply placed before `pluginConfigs`, meaning that
-   surrounding entries don't depend on it) - used to set up the theme, which has
-   to be done before other plugins
-6. `pluginConfigs` - the result of the nested `vim.pluginRC` (internal option,
+5. `theme` (this is simply placed before `pluginConfigs` and `lazyConfigs`, meaning that
+   surrounding entries don't depend on it) - used to set up the theme, which has to be done before
+   other plugins
+6. `lazyConfigs` - `lz.n` and `lzn-auto-require` configs. If `vim.lazy.enable`
+   is false, this will contain each plugin's config instead.
+7. `pluginConfigs` - the result of the nested `vim.pluginRC` (internal option,
    see the [Custom Plugins](/index.xhtml#ch-custom-plugins) page for adding your
    own plugins) DAG, used to set up internal plugins
-7. `extraPluginConfigs` - the result of `vim.extraPlugins`, which is not a
+8. `extraPluginConfigs` - the result of `vim.extraPlugins`, which is not a
    direct DAG, but is converted to, and resolved as one internally
-8. `mappings` - the result of `vim.maps`
+9. `mappings` - the result of `vim.maps`

docs/manual/hacking/additional-plugins.md

@@ -124,3 +124,61 @@ vim.your-plugin.setupOpts = {
   '';
 }
 ```
+
+## Lazy plugins {#sec-lazy-plugins}
+
+If the plugin can be lazy-loaded, `vim.lazy.plugins` should be used to add it. Lazy
+plugins are managed by `lz.n`.
+
+```nix
+# in modules/.../your-plugin/config.nix
+{lib, config, ...}:
+let
+  cfg = config.vim.your-plugin;
+in {
+  vim.lazy.plugins.your-plugin = {
+    # instead of vim.startPlugins, use this:
+    package = "your-plugin";
+
+    # if your plugin uses the `require('your-plugin').setup{...}` pattern
+    setupModule = "your-plugin";
+    inherit (cfg) setupOpts;
+
+    # events that trigger this plugin to be loaded
+    event = ["DirChanged"];
+    cmd = ["YourPluginCommand"];
+
+    # keymaps
+    keys = [
+      # we'll cover this in detail in the keymaps section
+      {
+        key = "<leader>d";
+        mode = "n";
+        action = ":YourPluginCommand";
+      }
+    ];
+  };
+;
+}
+```
+
+This results in the following lua code:
+```lua
+require('lz.n').load({
+  {
+    "name-of-your-plugin",
+    after = function()
+      require('your-plugin').setup({--[[ your setupOpts ]]})
+    end,
+
+    event = {"DirChanged"},
+    cmd = {"YourPluginCommand"},
+    keys = {
+      {"<leader>d", ":YourPluginCommand", mode = {"n"}},
+    },
+  }
+})
+```
+
+A full list of options can be found
+[here](https://notashelf.github.io/nvf/options.html#opt-vim.lazy.plugins

docs/release-notes/rl-0.7.md

@@ -123,6 +123,10 @@ To migrate to `nixfmt`, simply change `vim.languages.nix.format.type` to
   recommended to go through rustacean.nvim's README to take a closer look at its
   features and usage
 
+- Add [lz.n] support and lazy-load some builtin plugins.
+
+[lz.n]: https://github.com/mrcjkb/lz.n
+
 [jacekpoz](https://jacekpoz.pl):
 
 [ocaml-lsp]: https://github.com/ocaml/ocaml-lsp
@@ -192,6 +196,10 @@ To migrate to `nixfmt`, simply change `vim.languages.nix.format.type` to
 - Add C# support under `vim.languages.csharp`, with support for both
   omnisharp-roslyn and csharp-language-server.
 
+- Add Julia support under `vim.languages.julia`. Note that the entirety of Julia
+  is bundled with nvf, if you enable the module, since there is no way to
+  provide only the LSP server.
+
 [Neovim documentation on `vim.cmd`]: https://neovim.io/doc/user/lua.html#vim.cmd()
 
 - Make Neovim's configuration file entirely Lua based. This comes with a few
@@ -288,6 +296,7 @@ To migrate to `nixfmt`, simply change `vim.languages.nix.format.type` to
 - Add LSP, diagnostics, formatter and Treesitter support for Kotlin under
   `vim.languages.kotlin`
 - changed default keybinds for leap.nvim to avoid altering expected behavior
+- Add LSP, formatter and Treesitter support for Vala under `vim.languages.vala`
 
 [Bloxx12](https://github.com/Bloxx12)
 

flake.lock

@@ -892,6 +892,39 @@
         "type": "github"
       }
     },
+    "plugin-lz-n": {
+      "flake": false,
+      "locked": {
+        "lastModified": 1729525284,
+        "narHash": "sha256-fk+ejqcqqOQz3q4D3VB2Q+U/6wCpCDk1tiDMp2YrPNE=",
+        "owner": "nvim-neorocks",
+        "repo": "lz.n",
+        "rev": "ffd9991400ba7137f4fa8560ff50bccd7f8fb3ee",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nvim-neorocks",
+        "repo": "lz.n",
+        "type": "github"
+      }
+    },
+    "plugin-lzn-auto-require": {
+      "flake": false,
+      "locked": {
+        "lastModified": 1727636949,
+        "narHash": "sha256-BAOzN+XOrFAJwHmsF8JtZ2EyjP9283FD/I2TbFqGSEw=",
+        "owner": "horriblename",
+        "repo": "lzn-auto-require",
+        "rev": "55ecd60831dac8c01d6f3dcb63a30a63a1690eb8",
+        "type": "github"
+      },
+      "original": {
+        "owner": "horriblename",
+        "ref": "require-rewrite",
+        "repo": "lzn-auto-require",
+        "type": "github"
+      }
+    },
     "plugin-mind-nvim": {
       "flake": false,
       "locked": {
@@ -1629,6 +1662,22 @@
         "type": "github"
       }
     },
+    "plugin-rtp-nvim": {
+      "flake": false,
+      "locked": {
+        "lastModified": 1724409589,
+        "narHash": "sha256-lmJbiD7I7MTEEpukESs67uAmLyn+p66hrUKLbEHp0Kw=",
+        "owner": "nvim-neorocks",
+        "repo": "rtp.nvim",
+        "rev": "494ddfc888bb466555d90ace731856de1320fe45",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nvim-neorocks",
+        "repo": "rtp.nvim",
+        "type": "github"
+      }
+    },
     "plugin-rustaceanvim": {
       "flake": false,
       "locked": {
@@ -1991,6 +2040,8 @@
         "plugin-lua-utils-nvim": "plugin-lua-utils-nvim",
         "plugin-lualine": "plugin-lualine",
         "plugin-luasnip": "plugin-luasnip",
+        "plugin-lz-n": "plugin-lz-n",
+        "plugin-lzn-auto-require": "plugin-lzn-auto-require",
         "plugin-mind-nvim": "plugin-mind-nvim",
         "plugin-minimap-vim": "plugin-minimap-vim",
         "plugin-modes-nvim": "plugin-modes-nvim",
@@ -2037,6 +2088,7 @@
         "plugin-project-nvim": "plugin-project-nvim",
         "plugin-registers": "plugin-registers",
         "plugin-rose-pine": "plugin-rose-pine",
+        "plugin-rtp-nvim": "plugin-rtp-nvim",
         "plugin-rustaceanvim": "plugin-rustaceanvim",
         "plugin-scrollbar-nvim": "plugin-scrollbar-nvim",
         "plugin-smartcolumn": "plugin-smartcolumn",

flake.nix

@@ -113,6 +113,22 @@
     };
 
     ## Plugins
+    # Lazy loading
+    plugin-lz-n = {
+      url = "github:nvim-neorocks/lz.n";
+      flake = false;
+    };
+
+    plugin-lzn-auto-require = {
+      url = "github:horriblename/lzn-auto-require/require-rewrite";
+      flake = false;
+    };
+
+    plugin-rtp-nvim = {
+      url = "github:nvim-neorocks/rtp.nvim";
+      flake = false;
+    };
+
     # LSP plugins
     plugin-nvim-lspconfig = {
       url = "github:neovim/nvim-lspconfig";

lib/binds.nix

@@ -67,6 +67,30 @@
       mkLuaBinding binding.value action binding.description;
 
     pushDownDefault = attr: mapAttrs (_: mkDefault) attr;
+
+    mkLznBinding = mode: key: action: desc: {
+      inherit mode desc key action;
+    };
+
+    mkLznExprBinding = mode: key: action: desc: {
+      inherit mode desc key action;
+      lua = true;
+      silent = true;
+      expr = true;
+    };
+
+    mkSetLznBinding = binding: action: {
+      inherit action;
+      key = binding.value;
+      desc = binding.description;
+    };
+
+    mkSetLuaLznBinding = binding: action: {
+      inherit action;
+      key = binding.value;
+      lua = true;
+      desc = binding.description;
+    };
   };
 in
   binds

modules/default.nix

@@ -84,10 +84,7 @@
 
   # built (or "normalized") plugins that are modified
   builtStartPlugins = buildConfigPlugins vimOptions.startPlugins;
-  builtOptPlugins = map (package: {
-    plugin = package;
-    optional = true;
-  }) (buildConfigPlugins vimOptions.optPlugins);
+  builtOptPlugins = map (package: package // {optional = true;}) (buildConfigPlugins vimOptions.optPlugins);
 
   # additional Lua and Python3 packages, mapped to their respective functions
   # to conform to the format mnw expects. end user should

modules/modules.nix

@@ -50,6 +50,7 @@
       "build"
       "rc"
       "warnings"
+      "lazy"
     ];
 
     # Extra modules, such as deprecation warnings

modules/plugins/assistant/copilot/config.nix

@@ -4,11 +4,8 @@
   ...
 }: let
   inherit (builtins) toJSON;
-  inherit (lib.nvim.lua) toLuaObject;
-  inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.nvim.dag) entryAnywhere;
-  inherit (lib.lists) optionals;
-  inherit (lib.nvim.binds) mkLuaBinding;
+  inherit (lib.modules) mkIf;
+  inherit (lib.strings) optionalString;
 
   cfg = config.vim.assistant.copilot;
 
@@ -23,30 +20,52 @@
       end
     end
   '';
+
+  mkLuaKeymap = mode: key: action: desc: opts:
+    opts
+    // {
+      inherit mode key action desc;
+      lua = true;
+    };
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins =
-      [
-        "copilot-lua"
-        # cfg.copilotNodePackage
-      ]
-      ++ optionals cfg.cmp.enable [
-        "copilot-cmp"
+    vim = {
+      lazy.plugins = {
+        copilot-lua = {
+          package = "copilot-lua";
+          setupModule = "copilot";
+          inherit (cfg) setupOpts;
+          after = mkIf cfg.cmp.enable "require('copilot_cmp').setup()";
+
+          cmd = ["Copilot" "CopilotAuth" "CopilotDetach" "CopilotPanel" "CopilotStop"];
+          keys = [
+            (mkLuaKeymap ["n"] cfg.mappings.panel.accept (wrapPanelBinding ''require("copilot.panel").accept'' cfg.mappings.panel.accept) "[copilot] Accept suggestion" {})
+            (mkLuaKeymap ["n"] cfg.mappings.panel.jumpNext (wrapPanelBinding "require(\"copilot.panel\").jump_next" cfg.mappings.panel.jumpNext) "[copilot] Accept suggestion" {})
+            (mkLuaKeymap ["n"] cfg.mappings.panel.jumpPrev (wrapPanelBinding "require(\"copilot.panel\").jump_prev" cfg.mappings.panel.jumpPrev) "[copilot] Accept suggestion" {})
+            (mkLuaKeymap ["n"] cfg.mappings.panel.refresh (wrapPanelBinding "require(\"copilot.panel\").refresh" cfg.mappings.panel.refresh) "[copilot] Accept suggestion" {})
+            (mkLuaKeymap ["n"] cfg.mappings.panel.open (wrapPanelBinding ''
+                function() require("copilot.panel").open({ position = "${cfg.setupOpts.panel.layout.position}", ratio = ${toString cfg.setupOpts.panel.layout.ratio}, }) end
+              ''
+              cfg.mappings.panel.open) "[copilot] Accept suggestion" {})
+
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.accept "function() require('copilot.suggestion').accept() end" "[copilot] Accept suggestion" {})
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.acceptLine "function() require('copilot.suggestion').accept_line() end" "[copilot] Accept suggestion (line)" {})
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.acceptWord "function() require('copilot.suggestion').accept_word() end" "[copilot] Accept suggestion (word)" {})
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.dismiss "function() require('copilot.suggestion').dismiss() end" "[copilot] dismiss suggestion" {})
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.next "function() require('copilot.suggestion').next() end" "[copilot] next suggestion" {})
+            (mkLuaKeymap ["i"] cfg.mappings.suggestion.prev "function() require('copilot.suggestion').prev() end" "[copilot] previous suggestion" {})
           ];
+        };
+      };
 
-    vim.autocomplete.nvim-cmp.sources = {copilot = "[Copilot]";};
-
-    vim.pluginRC.copilot = entryAnywhere ''
-      require("copilot").setup(${toLuaObject cfg.setupOpts})
-
-      ${lib.optionalString cfg.cmp.enable ''
-        require("copilot_cmp").setup()
-      ''}
-    '';
+      autocomplete.nvim-cmp = {
+        sources = {copilot = "[Copilot]";};
+        sourcePlugins = ["copilot-cmp"];
+      };
 
       # Disable plugin handled keymaps.
       # Setting it here so that it doesn't show up in user docs
-    vim.assistant.copilot.setupOpts = {
+      assistant.copilot.setupOpts = {
         panel.keymap = {
           jump_prev = lib.mkDefault false;
           jump_next = lib.mkDefault false;
@@ -63,25 +82,6 @@ in {
           dismiss = lib.mkDefault false;
         };
       };
-
-    vim.maps.normal = mkMerge [
-      (mkLuaBinding cfg.mappings.panel.jumpPrev (wrapPanelBinding "require(\"copilot.panel\").jump_prev" cfg.mappings.panel.jumpPrev) "[copilot] Accept suggestion")
-      (mkLuaBinding cfg.mappings.panel.jumpNext (wrapPanelBinding "require(\"copilot.panel\").jump_next" cfg.mappings.panel.jumpNext) "[copilot] Accept suggestion")
-      (mkLuaBinding cfg.mappings.panel.accept (wrapPanelBinding ''require("copilot.panel").accept'' cfg.mappings.panel.accept) "[copilot] Accept suggestion")
-      (mkLuaBinding cfg.mappings.panel.refresh (wrapPanelBinding "require(\"copilot.panel\").refresh" cfg.mappings.panel.refresh) "[copilot] Accept suggestion")
-      (mkLuaBinding cfg.mappings.panel.open (wrapPanelBinding ''
-          function() require("copilot.panel").open({ position = "${cfg.setupOpts.panel.layout.position}", ratio = ${toString cfg.setupOpts.panel.layout.ratio}, }) end
-        ''
-        cfg.mappings.panel.open) "[copilot] Accept suggestion")
-    ];
-
-    vim.maps.insert = mkMerge [
-      (mkLuaBinding cfg.mappings.suggestion.accept "require(\"copilot.suggestion\").accept" "[copilot] Accept suggestion")
-      (mkLuaBinding cfg.mappings.suggestion.acceptLine "require(\"copilot.suggestion\").accept_line" "[copilot] Accept suggestion (line)")
-      (mkLuaBinding cfg.mappings.suggestion.acceptWord "require(\"copilot.suggestion\").accept_word" "[copilot] Accept suggestion (word)")
-      (mkLuaBinding cfg.mappings.suggestion.next "require(\"copilot.suggestion\").next" "[copilot] next suggestion")
-      (mkLuaBinding cfg.mappings.suggestion.prev "require(\"copilot.suggestion\").prev" "[copilot] previous suggestion")
-      (mkLuaBinding cfg.mappings.suggestion.dismiss "require(\"copilot.suggestion\").dismiss" "[copilot] dismiss suggestion")
-    ];
+    };
   };
 }

modules/plugins/comments/comment-nvim/comment-nvim.nix

@@ -1,6 +1,7 @@
 {lib, ...}: let
   inherit (lib.options) mkEnableOption;
   inherit (lib.nvim.binds) mkMappingOption;
+  inherit (lib.nvim.types) mkPluginSetupOption;
 in {
   options.vim.comments.comment-nvim = {
     enable = mkEnableOption "smart and powerful comment plugin for neovim comment-nvim";
@@ -15,5 +16,12 @@ in {
       toggleSelectedLine = mkMappingOption "Toggle selected comment" "gc";
       toggleSelectedBlock = mkMappingOption "Toggle selected block" "gb";
     };
+
+    setupOpts = mkPluginSetupOption "Comment-nvim" {
+      mappings = {
+        basic = mkEnableOption "basic mappings";
+        extra = mkEnableOption "extra mappings";
+      };
+    };
   };
 }

modules/plugins/comments/comment-nvim/config.nix

@@ -3,46 +3,38 @@
   lib,
   ...
 }: let
-  inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.nvim.binds) mkExprBinding mkBinding;
-  inherit (lib.nvim.dag) entryAnywhere;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.binds) mkLznExprBinding mkLznBinding;
 
   cfg = config.vim.comments.comment-nvim;
   self = import ./comment-nvim.nix {inherit lib;};
   inherit (self.options.vim.comments.comment-nvim) mappings;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = ["comment-nvim"];
-
-    vim.maps.normal = mkMerge [
-      (mkBinding cfg.mappings.toggleOpLeaderLine "<Plug>(comment_toggle_linewise)" mappings.toggleOpLeaderLine.description)
-      (mkBinding cfg.mappings.toggleOpLeaderBlock "<Plug>(comment_toggle_blockwise)" mappings.toggleOpLeaderBlock.description)
-
-      (mkExprBinding cfg.mappings.toggleCurrentLine ''
+    vim.lazy.plugins.comment-nvim = {
+      package = "comment-nvim";
+      setupModule = "Comment";
+      inherit (cfg) setupOpts;
+      keys = [
+        (mkLznBinding ["n"] cfg.mappings.toggleOpLeaderLine "<Plug>(comment_toggle_linewise)" mappings.toggleOpLeaderLine.description)
+        (mkLznBinding ["n"] cfg.mappings.toggleOpLeaderBlock "<Plug>(comment_toggle_blockwise)" mappings.toggleOpLeaderBlock.description)
+        (mkLznExprBinding ["n"] cfg.mappings.toggleCurrentLine ''
             function()
               return vim.api.nvim_get_vvar('count') == 0 and '<Plug>(comment_toggle_linewise_current)'
                       or '<Plug>(comment_toggle_linewise_count)'
             end
           ''
           mappings.toggleCurrentLine.description)
-      (mkExprBinding cfg.mappings.toggleCurrentBlock ''
+        (mkLznExprBinding ["n"] cfg.mappings.toggleCurrentBlock ''
             function()
               return vim.api.nvim_get_vvar('count') == 0 and '<Plug>(comment_toggle_blockwise_current)'
                       or '<Plug>(comment_toggle_blockwise_count)'
             end
           ''
           mappings.toggleCurrentBlock.description)
+        (mkLznBinding ["x"] cfg.mappings.toggleSelectedLine "<Plug>(comment_toggle_linewise_visual)" mappings.toggleSelectedLine.description)
+        (mkLznBinding ["x"] cfg.mappings.toggleSelectedBlock "<Plug>(comment_toggle_blockwise_visual)" mappings.toggleSelectedBlock.description)
       ];
-
-    vim.maps.visual = mkMerge [
-      (mkBinding cfg.mappings.toggleSelectedLine "<Plug>(comment_toggle_linewise_visual)" mappings.toggleSelectedLine.description)
-      (mkBinding cfg.mappings.toggleSelectedBlock "<Plug>(comment_toggle_blockwise_visual)" mappings.toggleSelectedBlock.description)
-    ];
-
-    vim.pluginRC.comment-nvim = entryAnywhere ''
-      require('Comment').setup({
-        mappings = { basic = false, extra = false, },
-      })
-    '';
+    };
   };
 }

modules/plugins/completion/nvim-cmp/config.nix

@@ -3,32 +3,68 @@
   config,
   ...
 }: let
-  inherit (lib.modules) mkIf;
+  inherit (lib.modules) mkIf mkMerge;
   inherit (lib.strings) optionalString;
   inherit (lib.generators) mkLuaInline;
-  inherit (lib.nvim.dag) entryAfter;
   inherit (lib.nvim.lua) toLuaObject;
-  inherit (builtins) attrNames;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+  inherit (builtins) attrNames typeOf tryEval concatStringsSep;
 
   cfg = config.vim.autocomplete.nvim-cmp;
   luasnipEnable = config.vim.snippets.luasnip.enable;
+  getPluginName = plugin:
+    if typeOf plugin == "string"
+    then plugin
+    else if (plugin ? pname && (tryEval plugin.pname).success)
+    then plugin.pname
+    else plugin.name;
   inherit (cfg) mappings;
 in {
   config = mkIf cfg.enable {
     vim = {
-      startPlugins = [
-        "nvim-cmp"
-        "cmp-buffer"
-        "cmp-path"
+      startPlugins = ["rtp-nvim"];
+      lazy.plugins = mkMerge [
+        (mapListToAttrs (package: {
+            name = getPluginName package;
+            value = {
+              inherit package;
+              lazy = true;
+              after = ''
+                local path = vim.fn.globpath(vim.o.packpath, 'pack/*/opt/${getPluginName package}')
+                require("rtp_nvim").source_after_plugin_dir(path)
+              '';
+            };
+          })
+          cfg.sourcePlugins)
+        {
+          nvim-cmp = {
+            package = "nvim-cmp";
+            after = ''
+              ${optionalString luasnipEnable "local luasnip = require('luasnip')"}
+              local cmp = require("cmp")
+              cmp.setup(${toLuaObject cfg.setupOpts})
+
+              ${optionalString config.vim.lazy.enable
+                (concatStringsSep "\n" (map
+                  (package: "require('lz.n').trigger_load(${toLuaObject (getPluginName package)})")
+                  cfg.sourcePlugins))}
+            '';
+
+            event = ["InsertEnter" "CmdlineEnter"];
+          };
+        }
       ];
 
-      autocomplete.nvim-cmp.sources = {
+      autocomplete.nvim-cmp = {
+        sources = {
           nvim-cmp = null;
           buffer = "[Buffer]";
           path = "[Path]";
         };
 
-      autocomplete.nvim-cmp.setupOpts = {
+        sourcePlugins = ["cmp-buffer" "cmp-path"];
+
+        setupOpts = {
           sources = map (s: {name = s;}) (attrNames cfg.sources);
 
           # TODO: try to get nvim-cmp to follow global border style
@@ -38,16 +74,9 @@ in {
           };
 
           formatting.format = cfg.format;
-      };
-
-      pluginRC.nvim-cmp = mkIf cfg.enable (entryAfter ["autopairs" "luasnip"] ''
-        ${optionalString luasnipEnable "local luasnip = require('luasnip')"}
-        local cmp = require("cmp")
-        cmp.setup(${toLuaObject cfg.setupOpts})
-      '');
 
           # `cmp` and `luasnip` are defined above, in the `nvim-cmp` section
-      autocomplete.nvim-cmp.setupOpts.mapping = {
+          mapping = {
             ${mappings.complete} = mkLuaInline "cmp.mapping.complete()";
             ${mappings.close} = mkLuaInline "cmp.mapping.abort()";
             ${mappings.scrollDocsUp} = mkLuaInline "cmp.mapping.scroll_docs(-4)";
@@ -91,4 +120,6 @@ in {
           };
         };
       };
+    };
+  };
 }

modules/plugins/completion/nvim-cmp/nvim-cmp.nix

@@ -4,10 +4,10 @@
   ...
 }: let
   inherit (lib.options) mkEnableOption mkOption literalExpression literalMD;
-  inherit (lib.types) str attrsOf nullOr either;
+  inherit (lib.types) str attrsOf nullOr either listOf;
   inherit (lib.generators) mkLuaInline;
   inherit (lib.nvim.binds) mkMappingOption;
-  inherit (lib.nvim.types) mkPluginSetupOption luaInline mergelessListOf;
+  inherit (lib.nvim.types) mkPluginSetupOption luaInline mergelessListOf pluginType;
   inherit (lib.nvim.lua) toLuaObject;
   inherit (builtins) isString;
 
@@ -99,5 +99,11 @@ in {
         }
       '';
     };
+
+    sourcePlugins = mkOption {
+      type = listOf pluginType;
+      default = [];
+      description = "List of source plugins used by nvim-cmp.";
+    };
   };
 }

modules/plugins/debugger/nvim-dap/config.nix

@@ -6,7 +6,7 @@
   inherit (lib.strings) optionalString;
   inherit (lib.modules) mkIf mkMerge;
   inherit (lib.attrsets) mapAttrs;
-  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetLuaBinding;
+  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetLuaBinding mkSetLuaLznBinding;
   inherit (lib.nvim.dag) entryAnywhere entryAfter;
 
   cfg = config.vim.debugger.nvim-dap;
@@ -52,24 +52,31 @@ in {
     })
     (mkIf (cfg.enable && cfg.ui.enable) {
       vim = {
-        startPlugins = ["nvim-dap-ui" "nvim-nio"];
+        startPlugins = ["nvim-nio"];
 
-        pluginRC.nvim-dap-ui = entryAfter ["nvim-dap"] (''
-            local dapui = require("dapui")
-            dapui.setup()
-          ''
-          + optionalString cfg.ui.autoStart ''
+        lazy.plugins.nvim-dap-ui = {
+          package = "nvim-dap-ui";
+          setupModule = "dapui";
+          inherit (cfg.ui) setupOpts;
+
+          keys = [
+            (mkSetLuaLznBinding mappings.toggleDapUI "function() require('dapui').toggle() end")
+          ];
+        };
+
+        pluginRC.nvim-dap-ui = entryAfter ["nvim-dap"] (
+          optionalString cfg.ui.autoStart ''
             dap.listeners.after.event_initialized["dapui_config"] = function()
-              dapui.open()
+              require("dapui").open()
             end
             dap.listeners.before.event_terminated["dapui_config"] = function()
-              dapui.close()
+              require("dapui").close()
             end
             dap.listeners.before.event_exited["dapui_config"] = function()
-              dapui.close()
+              require("dapui").close()
             end
-          '');
-        maps.normal = mkSetLuaBinding mappings.toggleDapUI "require('dapui').toggle";
+          ''
+        );
       };
     })
   ];

modules/plugins/debugger/nvim-dap/nvim-dap.nix

@@ -2,12 +2,16 @@
   inherit (lib.options) mkEnableOption mkOption;
   inherit (lib.types) bool attrsOf str;
   inherit (lib.nvim.binds) mkMappingOption;
+  inherit (lib.nvim.types) mkPluginSetupOption;
 in {
   options.vim.debugger.nvim-dap = {
     enable = mkEnableOption "debugging via nvim-dap";
 
     ui = {
       enable = mkEnableOption "UI extension for nvim-dap";
+
+      setupOpts = mkPluginSetupOption "nvim-dap-ui" {};
+
       autoStart = mkOption {
         type = bool;
         default = true;

modules/plugins/filetree/neo-tree/config.nix

@@ -4,8 +4,6 @@
   ...
 }: let
   inherit (lib.modules) mkIf;
-  inherit (lib.nvim.dag) entryAnywhere;
-  inherit (lib.nvim.lua) toLuaObject;
 
   cfg = config.vim.filetree.neo-tree;
 in {
@@ -16,15 +14,17 @@ in {
         "plenary-nvim" # commons library
         "image-nvim" # optional for image previews
         "nui-nvim" # ui library
-        # neotree
-        "neo-tree-nvim"
       ];
 
-      visuals.nvimWebDevicons.enable = true;
+      lazy.plugins.neo-tree-nvim = {
+        package = "neo-tree-nvim";
+        setupModule = "neo-tree";
+        inherit (cfg) setupOpts;
 
-      pluginRC.neo-tree = entryAnywhere ''
-        require("neo-tree").setup(${toLuaObject cfg.setupOpts})
-      '';
+        cmd = ["Neotree"];
+      };
+
+      visuals.nvimWebDevicons.enable = true;
     };
   };
 }

modules/plugins/filetree/nvimtree/config.nix

@@ -5,10 +5,9 @@
   ...
 }: let
   inherit (lib.strings) optionalString;
-  inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.nvim.binds) mkBinding;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.binds) mkLznBinding;
   inherit (lib.nvim.dag) entryAnywhere;
-  inherit (lib.nvim.lua) toLuaObject;
   inherit (lib.nvim.binds) pushDownDefault;
 
   cfg = config.vim.filetree.nvimTree;
@@ -16,20 +15,25 @@
   inherit (self.options.vim.filetree.nvimTree) mappings;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = ["nvim-tree-lua"];
-
-    vim.maps.normal = mkMerge [
-      (mkBinding cfg.mappings.toggle ":NvimTreeToggle<cr>" mappings.toggle.description)
-      (mkBinding cfg.mappings.refresh ":NvimTreeRefresh<cr>" mappings.refresh.description)
-      (mkBinding cfg.mappings.findFile ":NvimTreeFindFile<cr>" mappings.findFile.description)
-      (mkBinding cfg.mappings.focus ":NvimTreeFocus<cr>" mappings.focus.description)
-    ];
-
-    vim.binds.whichKey.register = pushDownDefault {
+    vim = {
+      binds.whichKey.register = pushDownDefault {
         "<leader>t" = "+NvimTree";
       };
 
-    vim.pluginRC.nvimtreelua = entryAnywhere ''
+      lazy.plugins.nvim-tree-lua = {
+        package = "nvim-tree-lua";
+        setupModule = "nvim-tree";
+        inherit (cfg) setupOpts;
+        cmd = ["NvimTreeClipboard" "NvimTreeClose" "NvimTreeCollapse" "NvimTreeCollapseKeepBuffers" "NvimTreeFindFile" "NvimTreeFindFileToggle" "NvimTreeFocus" "NvimTreeHiTest" "NvimTreeOpen" "NvimTreeRefresh" "NvimTreeResize" "NvimTreeToggle"];
+        keys = [
+          (mkLznBinding ["n"] cfg.mappings.toggle ":NvimTreeToggle<cr>" mappings.toggle.description)
+          (mkLznBinding ["n"] cfg.mappings.refresh ":NvimTreeRefresh<cr>" mappings.refresh.description)
+          (mkLznBinding ["n"] cfg.mappings.findFile ":NvimTreeFindFile<cr>" mappings.findFile.description)
+          (mkLznBinding ["n"] cfg.mappings.focus ":NvimTreeFocus<cr>" mappings.focus.description)
+        ];
+      };
+
+      pluginRC.nvimtreelua = entryAnywhere ''
         ${
           optionalString cfg.setupOpts.disable_netrw ''
             -- disable netrew completely
@@ -38,10 +42,9 @@ in {
           ''
         }
 
-      require'nvim-tree'.setup(${toLuaObject cfg.setupOpts})
-
         ${
           optionalString cfg.openOnSetup ''
+            ${optionalString config.vim.lazy.enable ''require('lz.n').trigger_load("nvim-tree-lua")''}
             -- autostart behaviour
             -- Open on startup has been deprecated
             -- see https://github.com/nvim-tree/nvim-tree.lua/wiki/Open-At-Startup
@@ -81,4 +84,5 @@ in {
         }
       '';
     };
+  };
 }

modules/plugins/languages/default.nix

@@ -9,11 +9,13 @@ in {
     ./elixir.nix
     ./go.nix
     ./kotlin.nix
+    ./haskell.nix
     ./html.nix
     ./java.nix
     ./lua.nix
     ./markdown.nix
     ./nim.nix
+    ./vala.nix
     ./nix.nix
     ./ocaml.nix
     ./php.nix
@@ -29,6 +31,7 @@ in {
     ./typst.nix
     ./zig.nix
     ./csharp.nix
+    ./julia.nix
   ];
 
   options.vim.languages = {

modules/plugins/languages/haskell.nix

@@ -0,0 +1,49 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) package;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.haskell;
+in {
+  options.vim.languages.haskell = {
+    enable = mkEnableOption "Haskell support";
+
+    treesitter = {
+      enable = mkEnableOption "Haskell treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "haskell";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Haskell LSP support (haskell-language-server)" // {default = config.vim.languages.enableLSP;};
+
+      package = mkOption {
+        description = "haskell-language-server package";
+        type = package;
+        default = pkgs.haskell-language-server;
+      };
+    };
+  };
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.hls = ''
+        lspconfig.hls.setup {
+          capabilities = capabilities,
+          on_attach = default_on_attach,
+          cmd = {"${cfg.lsp.package}/bin/haskell-language-server"},
+        }
+      '';
+    })
+  ]);
+}

modules/plugins/languages/julia.nix

@@ -0,0 +1,126 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (builtins) attrNames isList;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) either listOf package str enum bool nullOr;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.strings) optionalString;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.lua) expToLua;
+
+  defaultServer = "julials";
+  servers = {
+    julials = {
+      package = pkgs.julia.withPackages ["LanguageServer"];
+      internalFormatter = true;
+      lspConfig = ''
+        lspconfig.julials.setup {
+          capabilities = capabilities,
+          on_attach = default_on_attach,
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else ''
+            {
+              "${optionalString (cfg.lsp.package != null) "${cfg.lsp.package}/bin/"}julia",
+              "--startup-file=no",
+              "--history-file=no",
+              "--eval",
+              [[
+                using LanguageServer
+
+                depot_path = get(ENV, "JULIA_DEPOT_PATH", "")
+                project_path = let
+                    dirname(something(
+                        ## 1. Finds an explicitly set project (JULIA_PROJECT)
+                        Base.load_path_expand((
+                            p = get(ENV, "JULIA_PROJECT", nothing);
+                            p === nothing ? nothing : isempty(p) ? nothing : p
+                        )),
+                        ## 2. Look for a Project.toml file in the current working directory,
+                        ##    or parent directories, with $HOME as an upper boundary
+                        Base.current_project(),
+                        ## 3. First entry in the load path
+                        get(Base.load_path(), 1, nothing),
+                        ## 4. Fallback to default global environment,
+                        ##    this is more or less unreachable
+                        Base.load_path_expand("@v#.#"),
+                    ))
+                end
+                @info "Running language server" VERSION pwd() project_path depot_path
+                server = LanguageServer.LanguageServerInstance(stdin, stdout, project_path, depot_path)
+                server.runlinter = true
+                run(server)
+              ]]
+            }
+          ''
+        }
+        }
+      '';
+    };
+  };
+
+  cfg = config.vim.languages.julia;
+in {
+  options = {
+    vim.languages.julia = {
+      enable = mkEnableOption "Julia language support";
+
+      treesitter = {
+        enable = mkEnableOption "Julia treesitter" // {default = config.vim.languages.enableTreesitter;};
+        package = mkGrammarOption pkgs "julia";
+      };
+
+      lsp = {
+        enable = mkOption {
+          type = bool;
+          default = config.vim.languages.enableLSP;
+          description = ''
+            Whether to enable Julia LSP support.
+
+            ::: {.note}
+            The entirety of Julia is bundled with nvf, if you enable this
+            option, since there is no way to provide only the LSP server.
+
+            If you want to avoid that, you have to change
+            [](#opt-vim.languages.julia.lsp.package) to use the Julia binary
+            in {env}`PATH` (set it to `null`), and add the `LanguageServer` package to
+            Julia in your devshells.
+            :::
+          '';
+        };
+
+        server = mkOption {
+          type = enum (attrNames servers);
+          default = defaultServer;
+          description = "Julia LSP server to use";
+        };
+
+        package = mkOption {
+          description = ''
+            Julia LSP server package, `null` to use the Julia binary in {env}`PATH`, or
+            the command to run as a list of strings.
+          '';
+          type = nullOr (either package (listOf str));
+          default = servers.${cfg.lsp.server}.package;
+        };
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.julia-lsp = servers.${cfg.lsp.server}.lspConfig;
+    })
+  ]);
+}

modules/plugins/languages/vala.nix

@@ -0,0 +1,79 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.lists) isList;
+  inherit (lib.types) enum either listOf package str;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.lua) expToLua;
+
+  cfg = config.vim.languages.vala;
+
+  defaultServer = "vala_ls";
+  servers = {
+    vala_ls = {
+      package = pkgs.symlinkJoin {
+        name = "vala-language-server-wrapper";
+        paths = [pkgs.vala-language-server];
+        buildInputs = [pkgs.makeBinaryWrapper];
+        postBuild = ''
+          wrapProgram $out/bin/vala-language-server \
+            --prefix PATH : ${pkgs.uncrustify}/bin
+        '';
+      };
+      internalFormatter = true;
+      lspConfig = ''
+        lspconfig.vala_ls.setup {
+          capabilities = capabilities;
+          on_attach = default_on_attach;
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else ''{"${cfg.lsp.package}/bin/vala-language-server"}''
+        },
+        }
+      '';
+    };
+  };
+in {
+  options.vim.languages.vala = {
+    enable = mkEnableOption "Vala language support";
+
+    treesitter = {
+      enable = mkEnableOption "Vala treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "vala";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Vala LSP support" // {default = config.vim.languages.enableLSP;};
+      server = mkOption {
+        description = "Vala LSP server to use";
+        type = enum (attrNames servers);
+        default = defaultServer;
+      };
+
+      package = mkOption {
+        description = "Vala LSP server package, or the command to run as a list of strings";
+        type = either package (listOf str);
+        default = servers.${cfg.lsp.server}.package;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.vala_ls = servers.${cfg.lsp.server}.lspConfig;
+    })
+  ]);
+}

modules/plugins/lsp/config.nix

@@ -5,7 +5,6 @@
   ...
 }: let
   inherit (lib.modules) mkIf;
-  inherit (lib.lists) optional;
   inherit (lib.strings) optionalString;
   inherit (lib.trivial) boolToString;
   inherit (lib.nvim.binds) addDescriptionsToMappings;
@@ -23,9 +22,10 @@
 in {
   config = mkIf cfg.enable {
     vim = {
-      startPlugins = optional usingNvimCmp "cmp-nvim-lsp";
-
-      autocomplete.nvim-cmp.sources = {nvim_lsp = "[LSP]";};
+      autocomplete.nvim-cmp = {
+        sources = {nvim_lsp = "[LSP]";};
+        sourcePlugins = ["cmp-nvim-lsp"];
+      };
 
       pluginRC.lsp-setup = ''
         vim.g.formatsave = ${boolToString cfg.formatOnSave};
@@ -116,7 +116,60 @@ in {
         end
 
         local capabilities = vim.lsp.protocol.make_client_capabilities()
-        ${optionalString usingNvimCmp "capabilities = require('cmp_nvim_lsp').default_capabilities()"}
+        ${optionalString usingNvimCmp ''
+          -- HACK: copied from cmp-nvim-lsp. If we ever lazy load lspconfig we
+          -- should re-evaluate whether we can just use `default_capabilities`
+          capabilities = {
+            textDocument = {
+              completion = {
+                dynamicRegistration = false,
+                completionItem = {
+                  snippetSupport = true,
+                  commitCharactersSupport = true,
+                  deprecatedSupport = true,
+                  preselectSupport = true,
+                  tagSupport = {
+                    valueSet = {
+                      1, -- Deprecated
+                    }
+                  },
+                  insertReplaceSupport = true,
+                  resolveSupport = {
+                    properties = {
+                      "documentation",
+                      "detail",
+                      "additionalTextEdits",
+                      "sortText",
+                      "filterText",
+                      "insertText",
+                      "textEdit",
+                      "insertTextFormat",
+                      "insertTextMode",
+                    },
+                  },
+                  insertTextModeSupport = {
+                    valueSet = {
+                      1, -- asIs
+                      2, -- adjustIndentation
+                    }
+                  },
+                  labelDetailsSupport = true,
+                },
+                contextSupport = true,
+                insertTextMode = 1,
+                completionList = {
+                  itemDefaults = {
+                    'commitCharacters',
+                    'editRange',
+                    'insertTextFormat',
+                    'insertTextMode',
+                    'data',
+                  }
+                }
+              },
+            },
+          }
+        ''}
       '';
     };
   };

modules/plugins/lsp/trouble/config.nix

@@ -1,41 +1,40 @@
 {
   config,
   lib,
+  options,
   ...
 }: let
-  inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.nvim.dag) entryAnywhere;
-  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetBinding pushDownDefault;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetLznBinding pushDownDefault;
 
   cfg = config.vim.lsp;
 
-  self = import ./trouble.nix {inherit lib;};
-  mappingDefinitions = self.options.vim.lsp.trouble.mappings;
+  mappingDefinitions = options.vim.lsp.trouble.mappings;
   mappings = addDescriptionsToMappings cfg.trouble.mappings mappingDefinitions;
 in {
   config = mkIf (cfg.enable && cfg.trouble.enable) {
     vim = {
-      startPlugins = ["trouble"];
+      lazy.plugins.trouble = {
+        package = "trouble";
+        setupModule = "trouble";
+        inherit (cfg.trouble) setupOpts;
 
-      maps.normal = mkMerge [
-        (mkSetBinding mappings.toggle "<cmd>TroubleToggle<CR>")
-        (mkSetBinding mappings.workspaceDiagnostics "<cmd>TroubleToggle workspace_diagnostics<CR>")
-        (mkSetBinding mappings.documentDiagnostics "<cmd>TroubleToggle document_diagnostics<CR>")
-        (mkSetBinding mappings.lspReferences "<cmd>TroubleToggle lsp_references<CR>")
-        (mkSetBinding mappings.quickfix "<cmd>TroubleToggle quickfix<CR>")
-        (mkSetBinding mappings.locList "<cmd>TroubleToggle loclist<CR>")
+        cmd = "Trouble";
+        keys = [
+          (mkSetLznBinding mappings.toggle "<cmd>TroubleToggle<CR>")
+          (mkSetLznBinding mappings.workspaceDiagnostics "<cmd>TroubleToggle workspace_diagnostics<CR>")
+          (mkSetLznBinding mappings.documentDiagnostics "<cmd>TroubleToggle document_diagnostics<CR>")
+          (mkSetLznBinding mappings.lspReferences "<cmd>TroubleToggle lsp_references<CR>")
+          (mkSetLznBinding mappings.quickfix "<cmd>TroubleToggle quickfix<CR>")
+          (mkSetLznBinding mappings.locList "<cmd>TroubleToggle loclist<CR>")
         ];
+      };
 
       binds.whichKey.register = pushDownDefault {
         "<leader>l" = "Trouble";
         "<leader>x" = "+Trouble";
         "<leader>lw" = "Workspace";
       };
-
-      pluginRC.trouble = entryAnywhere ''
-        -- Enable trouble diagnostics viewer
-        require("trouble").setup {}
-      '';
     };
   };
 }

modules/plugins/lsp/trouble/trouble.nix

@@ -1,11 +1,14 @@
 {lib, ...}: let
   inherit (lib.options) mkEnableOption;
   inherit (lib.nvim.binds) mkMappingOption;
+  inherit (lib.nvim.types) mkPluginSetupOption;
 in {
   options.vim.lsp = {
     trouble = {
       enable = mkEnableOption "trouble diagnostics viewer";
 
+      setupOpts = mkPluginSetupOption "Trouble" {};
+
       mappings = {
         toggle = mkMappingOption "Toggle trouble [trouble]" "<leader>xx";
         workspaceDiagnostics = mkMappingOption "Workspace diagnostics [trouble]" "<leader>lwd";

modules/plugins/snippets/luasnip/config.nix

@@ -9,9 +9,18 @@
 in {
   config = mkIf cfg.enable {
     vim = {
-      startPlugins = ["luasnip" "cmp-luasnip"] ++ cfg.providers;
-      autocomplete.nvim-cmp.sources = {luasnip = "[LuaSnip]";};
-      pluginRC.luasnip = cfg.loaders;
+      lazy.plugins = {
+        luasnip = {
+          package = "luasnip";
+          lazy = true;
+          after = cfg.loaders;
+        };
+      };
+      startPlugins = cfg.providers;
+      autocomplete.nvim-cmp = {
+        sources = {luasnip = "[LuaSnip]";};
+        sourcePlugins = ["cmp-luasnip"];
+      };
     };
   };
 }

modules/plugins/terminal/toggleterm/config.nix

@@ -3,39 +3,31 @@
   lib,
   ...
 }: let
-  inherit (builtins) toJSON;
-  inherit (lib.lists) optionals;
-  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.strings) optionalString;
+  inherit (lib.lists) optional;
+  inherit (lib.modules) mkIf;
   inherit (lib.meta) getExe;
-  inherit (lib.nvim.binds) mkBinding;
-  inherit (lib.nvim.dag) entryAnywhere entryAfter;
+  inherit (lib.nvim.binds) mkLznBinding;
   inherit (lib.nvim.lua) toLuaObject;
 
   cfg = config.vim.terminal.toggleterm;
+  lazygitMapDesc = "Open lazygit [toggleterm]";
 in {
-  config = mkMerge [
-    (
-      mkIf cfg.enable {
+  config = mkIf cfg.enable {
     vim = {
-          startPlugins = [
-            "toggleterm-nvim"
-          ];
-
-          maps.normal = mkBinding cfg.mappings.open "<Cmd>execute v:count . \"ToggleTerm\"<CR>" "Toggle terminal";
-
-          pluginRC.toggleterm = entryAnywhere ''
-            require("toggleterm").setup(${toLuaObject cfg.setupOpts})
-          '';
+      lazy.plugins.toggleterm-nvim = {
+        package = "toggleterm-nvim";
+        cmd = ["ToggleTerm" "ToggleTermSendCurrentLine" "ToggleTermSendVisualLines" "ToggleTermSendVisualSelection" "ToggleTermSetName" "ToggleTermToggleAll"];
+        keys =
+          [(mkLznBinding ["n"] cfg.mappings.open "<Cmd>execute v:count . \"ToggleTerm\"<CR>" "Toggle terminal")]
+          ++ optional cfg.lazygit.enable {
+            key = cfg.lazygit.mappings.open;
+            desc = lazygitMapDesc;
           };
-      }
-    )
-    (
-      mkIf (cfg.enable && cfg.lazygit.enable)
-      {
-        vim.startPlugins = optionals (cfg.lazygit.package != null) [
-          cfg.lazygit.package
-        ];
-        vim.pluginRC.toggleterm-lazygit = entryAfter ["toggleterm"] ''
+
+        setupModule = "toggleterm";
+        inherit (cfg) setupOpts;
+        after = optionalString cfg.lazygit.enable ''
           local terminal = require 'toggleterm.terminal'
           local lazygit = terminal.Terminal:new({
             cmd = '${
@@ -50,9 +42,9 @@ in {
             end
           })
 
-          vim.keymap.set('n', ${toJSON cfg.lazygit.mappings.open}, function() lazygit:toggle() end, {silent = true, noremap = true, desc = 'Open lazygit [toggleterm]'})
+          vim.keymap.set('n', ${toLuaObject cfg.lazygit.mappings.open}, function() lazygit:toggle() end, {silent = true, noremap = true, desc = '${lazygitMapDesc}'})
         '';
-      }
-    )
-  ];
+      };
+    };
+  };
 }

modules/plugins/theme/theme.nix

@@ -66,7 +66,7 @@ in {
   config = mkIf cfg.enable {
     vim = {
       startPlugins = [cfg.name];
-      luaConfigRC.theme = entryBefore ["pluginConfigs"] ''
+      luaConfigRC.theme = entryBefore ["pluginConfigs" "lazyConfigs"] ''
         ${cfg.extraConfig}
         ${supportedThemes.${cfg.name}.setup {inherit (cfg) style transparent base16-colors;}}
       '';

modules/plugins/treesitter/config.nix

@@ -5,13 +5,12 @@
   ...
 }: let
   inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.lists) optional optionals;
+  inherit (lib.lists) optionals;
   inherit (lib.nvim.binds) mkSetBinding addDescriptionsToMappings;
   inherit (lib.nvim.lua) toLuaObject;
   inherit (lib.nvim.dag) entryBefore entryAfter;
 
   cfg = config.vim.treesitter;
-  usingNvimCmp = config.vim.autocomplete.nvim-cmp.enable;
 
   self = import ./treesitter.nix {inherit pkgs lib;};
   mappingDefinitions = self.options.vim.treesitter.mappings;
@@ -19,9 +18,13 @@
 in {
   config = mkIf cfg.enable {
     vim = {
-      startPlugins = ["nvim-treesitter"] ++ optional usingNvimCmp "cmp-treesitter";
+      startPlugins = ["nvim-treesitter"];
+
+      autocomplete.nvim-cmp = {
+        sources = {treesitter = "[Treesitter]";};
+        sourcePlugins = ["cmp-treesitter"];
+      };
 
-      autocomplete.nvim-cmp.sources = {treesitter = "[Treesitter]";};
       treesitter.grammars = optionals cfg.addDefaultGrammars cfg.defaultGrammars;
 
       maps = {

modules/plugins/utility/binds/cheatsheet/config.nix

@@ -4,15 +4,18 @@
   ...
 }: let
   inherit (lib.modules) mkIf;
-  inherit (lib.nvim.dag) entryAnywhere;
+  inherit (lib.strings) optionalString;
 
   cfg = config.vim.binds.cheatsheet;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = ["cheatsheet-nvim"];
+    vim.lazy.plugins.cheatsheet-nvim = {
+      package = "cheatsheet-nvim";
+      setupModule = "cheatsheet";
+      setupOpts = {};
+      cmd = ["Cheatsheet" "CheatsheetEdit"];
 
-    vim.pluginRC.cheaetsheet-nvim = entryAnywhere ''
-      require('cheatsheet').setup({})
-    '';
+      before = optionalString config.vim.lazy.enable "require('lz.n').trigger_load('telescope')";
+    };
   };
 }

modules/plugins/utility/diffview/config.nix

@@ -8,9 +8,14 @@
   cfg = config.vim.utility.diffview-nvim;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = [
-      "diffview-nvim"
-      "plenary-nvim"
-    ];
+    vim = {
+      startPlugins = ["plenary-nvim"];
+      lazy.plugins.diffview-nvim = {
+        package = "diffview-nvim";
+        cmd = ["DiffviewClose" "DiffviewFileHistory" "DiffviewFocusFiles" "DiffviewLog" "DiffviewOpen" "DiffviewRefresh" "DiffviewToggleFiles"];
+        setupModule = "diffview";
+        inherit (cfg) setupOpts;
+      };
+    };
   };
 }

modules/plugins/utility/diffview/diffview.nix

@@ -1,7 +1,9 @@
 {lib, ...}: let
   inherit (lib.options) mkEnableOption;
+  inherit (lib.nvim.types) mkPluginSetupOption;
 in {
   options.vim.utility.diffview-nvim = {
     enable = mkEnableOption "diffview-nvim: cycle through diffs for all modified files for any git rev";
+    setupOpts = mkPluginSetupOption "Fidget" {};
   };
 }

modules/plugins/utility/icon-picker/config.nix

@@ -4,20 +4,20 @@
   ...
 }: let
   inherit (lib.modules) mkIf;
-  inherit (lib.nvim.dag) entryAnywhere;
 
   cfg = config.vim.utility.icon-picker;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = [
-      "icon-picker-nvim"
-      "dressing-nvim"
-    ];
+    vim.startPlugins = ["dressing-nvim"];
 
-    vim.pluginRC.icon-picker = entryAnywhere ''
-      require("icon-picker").setup({
-        disable_legacy_commands = true
-      })
-    '';
+    vim.lazy.plugins.icon-picker-nvim = {
+      package = "icon-picker-nvim";
+      setupModule = "icon-picker";
+      setupOpts = {
+        disable_legacy_commands = true;
+      };
+
+      cmd = ["IconPickerInsert" "IconPickerNormal" "IconPickerYank"];
+    };
   };
 }

modules/plugins/utility/motion/leap/config.nix

@@ -3,43 +3,25 @@
   lib,
   ...
 }: let
-  inherit (lib.modules) mkIf mkMerge mkDefault;
-  inherit (lib.nvim.binds) mkBinding;
-  inherit (lib.nvim.dag) entryAnywhere;
+  inherit (lib.modules) mkIf mkDefault;
+  inherit (lib.nvim.binds) mkLznBinding;
 
   cfg = config.vim.utility.motion.leap;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = [
-      "leap-nvim"
-      "vim-repeat"
+    vim = {
+      startPlugins = ["vim-repeat"];
+      lazy.plugins.leap-nvim = {
+        package = "leap-nvim";
+        keys = [
+          (mkLznBinding ["n" "o" "x"] cfg.mappings.leapForwardTo "<Plug>(leap-forward-to)" "Leap forward to")
+          (mkLznBinding ["n" "o" "x"] cfg.mappings.leapBackwardTo "<Plug>(leap-backward-to)" "Leap backward to")
+          (mkLznBinding ["n" "o" "x"] cfg.mappings.leapForwardTill "<Plug>(leap-forward-till)" "Leap forward till")
+          (mkLznBinding ["n" "o" "x"] cfg.mappings.leapBackwardTill "<Plug>(leap-backward-till)" "Leap backward till")
+          (mkLznBinding ["n" "o" "x"] cfg.mappings.leapFromWindow "<Plug>(leap-from-window)" "Leap from window")
         ];
 
-    vim.maps.normal = mkMerge [
-      (mkBinding cfg.mappings.leapForwardTo "<Plug>(leap-forward-to)" "Leap forward to")
-      (mkBinding cfg.mappings.leapBackwardTo "<Plug>(leap-backward-to)" "Leap backward to")
-      (mkBinding cfg.mappings.leapFromWindow "<Plug>(leap-from-window)" "Leap from window")
-    ];
-
-    vim.maps.operator = mkMerge [
-      (mkBinding cfg.mappings.leapForwardTo "<Plug>(leap-forward-to)" "Leap forward to")
-      (mkBinding cfg.mappings.leapBackwardTo "<Plug>(leap-backward-to)" "Leap backward to")
-      (mkBinding cfg.mappings.leapForwardTill "<Plug>(leap-forward-till)" "Leap forward till")
-      (mkBinding cfg.mappings.leapBackwardTill "<Plug>(leap-backward-till)" "Leap backward till")
-      (mkBinding cfg.mappings.leapFromWindow "<Plug>(leap-from-window)" "Leap from window")
-    ];
-
-    vim.maps.visualOnly = mkMerge [
-      (mkBinding cfg.mappings.leapForwardTo "<Plug>(leap-forward-to)" "Leap forward to")
-      (mkBinding cfg.mappings.leapBackwardTo "<Plug>(leap-backward-to)" "Leap backward to")
-      (mkBinding cfg.mappings.leapForwardTill "<Plug>(leap-forward-till)" "Leap forward till")
-      (mkBinding cfg.mappings.leapBackwardTill "<Plug>(leap-backward-till)" "Leap backward till")
-      (mkBinding cfg.mappings.leapFromWindow "<Plug>(leap-from-window)" "Leap from window")
-    ];
-
-    vim.binds.whichKey.register."<leader>s" = mkDefault "+Leap";
-
-    vim.pluginRC.leap-nvim = entryAnywhere ''
+        after = ''
           require('leap').opts = {
             max_phase_one_targets = nil,
             highlight_unlabeled_phase_one_targets = false,
@@ -72,4 +54,8 @@ in {
           }
         '';
       };
+
+      binds.whichKey.register."<leader>s" = mkDefault "+Leap";
+    };
+  };
 }

modules/plugins/utility/surround/config.nix

@@ -8,24 +8,47 @@
   inherit (lib.nvim.lua) toLuaObject;
 
   cfg = config.vim.utility.surround;
+  mkLznKey = mode: key: {
+    inherit key mode;
+  };
 in {
   config = mkIf cfg.enable {
     vim = {
       startPlugins = ["nvim-surround"];
       pluginRC.surround = entryAnywhere "require('nvim-surround').setup(${toLuaObject cfg.setupOpts})";
 
-      utility.surround.setupOpts.keymaps = mkIf cfg.useVendoredKeybindings {
-        insert = "<C-g>z";
-        insert_line = "<C-g>Z";
-        normal = "gz";
-        normal_cur = "gZ";
-        normal_line = "gzz";
-        normal_cur_line = "gZZ";
-        visual = "gz";
-        visual_line = "gZ";
-        delete = "gzd";
-        change = "gzr";
-        change_line = "gZR";
+      lazy.plugins.nvim-surround = {
+        package = "nvim-surround";
+        setupModule = "nvim-surround";
+        inherit (cfg) setupOpts;
+
+        keys =
+          [
+            (mkLznKey ["i"] cfg.setupOpts.keymaps.insert)
+            (mkLznKey ["i"] cfg.setupOpts.keymaps.insert_line)
+            (mkLznKey ["x"] cfg.setupOpts.keymaps.visual)
+            (mkLznKey ["x"] cfg.setupOpts.keymaps.visual_line)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.normal)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.normal_cur)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.normal_line)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.normal_cur_line)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.delete)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.change)
+            (mkLznKey ["n"] cfg.setupOpts.keymaps.change_line)
+          ]
+          ++ map (mkLznKey ["n" "i" "v"]) [
+            "<Plug>(nvim-surround-insert)"
+            "<Plug>(nvim-surround-insert-line)"
+            "<Plug>(nvim-surround-normal)"
+            "<Plug>(nvim-surround-normal-cur)"
+            "<Plug>(nvim-surround-normal-line)"
+            "<Plug>(nvim-surround-normal-cur-line)"
+            "<Plug>(nvim-surround-visual)"
+            "<Plug>(nvim-surround-visual-line)"
+            "<Plug>(nvim-surround-delete)"
+            "<Plug>(nvim-surround-change)"
+            "<Plug>(nvim-surround-change-line)"
+          ];
       };
     };
   };

modules/plugins/utility/surround/surround.nix

@@ -1,7 +1,36 @@
-{lib, ...}: let
+{
+  lib,
+  config,
+  ...
+}: let
   inherit (lib.options) mkOption;
-  inherit (lib.types) bool;
+  inherit (lib.types) bool str;
   inherit (lib.nvim.types) mkPluginSetupOption;
+
+  cfg = config.vim.utility.surround;
+  vendoredKeybinds = {
+    insert = "<C-g>z";
+    insert_line = "<C-g>Z";
+    normal = "gz";
+    normal_cur = "gZ";
+    normal_line = "gzz";
+    normal_cur_line = "gZZ";
+    visual = "gz";
+    visual_line = "gZ";
+    delete = "gzd";
+    change = "gzr";
+    change_line = "gZR";
+  };
+
+  mkKeymapOption = name: default:
+    mkOption {
+      description = "keymap for ${name}";
+      type = str;
+      default =
+        if cfg.useVendoredKeybindings
+        then vendoredKeybinds.${name}
+        else default;
+    };
 in {
   options.vim.utility.surround = {
     enable = mkOption {
@@ -13,7 +42,21 @@ in {
         with nvim-leap.
       '';
     };
-    setupOpts = mkPluginSetupOption "nvim-surround" {};
+    setupOpts = mkPluginSetupOption "nvim-surround" {
+      keymaps = {
+        insert = mkKeymapOption "insert" "<C-g>s";
+        insert_line = mkKeymapOption "insert_line" "<C-g>S";
+        normal = mkKeymapOption "normal" "ys";
+        normal_cur = mkKeymapOption "normal_cur" "yss";
+        normal_line = mkKeymapOption "normal_line" "yS";
+        normal_cur_line = mkKeymapOption "normal_cur_line" "ySS";
+        visual = mkKeymapOption "visual" "S";
+        visual_line = mkKeymapOption "visual_line" "gS";
+        delete = mkKeymapOption "delete" "ds";
+        change = mkKeymapOption "change" "cs";
+        change_line = mkKeymapOption "change_line" "cS";
+      };
+    };
 
     useVendoredKeybindings = mkOption {
       type = bool;

modules/plugins/utility/telescope/config.nix

@@ -1,63 +1,72 @@
 {
+  options,
   config,
-  pkgs,
   lib,
   ...
 }: let
-  inherit (lib.modules) mkIf mkMerge;
-  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetBinding;
-  inherit (lib.nvim.dag) entryAnywhere;
-  inherit (lib.nvim.binds) pushDownDefault;
-  inherit (lib.nvim.lua) toLuaObject;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.binds) addDescriptionsToMappings;
+  inherit (lib.strings) optionalString;
+  inherit (lib.lists) optionals;
+  inherit (lib.nvim.binds) pushDownDefault mkSetLznBinding;
 
   cfg = config.vim.telescope;
-  self = import ./telescope.nix {inherit pkgs lib;};
-  mappingDefinitions = self.options.vim.telescope.mappings;
+  mappingDefinitions = options.vim.telescope.mappings;
 
   mappings = addDescriptionsToMappings cfg.mappings mappingDefinitions;
 in {
   config = mkIf cfg.enable {
     vim = {
-      startPlugins = [
-        "telescope"
-        "plenary-nvim"
-      ];
+      startPlugins = ["plenary-nvim"];
 
-      maps.normal = mkMerge [
-        (mkSetBinding mappings.findFiles "<cmd> Telescope find_files<CR>")
-        (mkSetBinding mappings.liveGrep "<cmd> Telescope live_grep<CR>")
-        (mkSetBinding mappings.buffers "<cmd> Telescope buffers<CR>")
-        (mkSetBinding mappings.helpTags "<cmd> Telescope help_tags<CR>")
-        (mkSetBinding mappings.open "<cmd> Telescope<CR>")
-        (mkSetBinding mappings.resume "<cmd> Telescope resume<CR>")
+      lazy.plugins.telescope = {
+        package = "telescope";
+        setupModule = "telescope";
+        inherit (cfg) setupOpts;
+        after = ''
+          local telescope = require("telescope")
+          ${optionalString config.vim.ui.noice.enable "telescope.load_extension('noice')"}
+          ${optionalString config.vim.notify.nvim-notify.enable "telescope.load_extension('notify')"}
+          ${optionalString config.vim.projects.project-nvim.enable "telescope.load_extension('projects')"}
+        '';
 
-        (mkSetBinding mappings.gitCommits "<cmd> Telescope git_commits<CR>")
-        (mkSetBinding mappings.gitBufferCommits "<cmd> Telescope git_bcommits<CR>")
-        (mkSetBinding mappings.gitBranches "<cmd> Telescope git_branches<CR>")
-        (mkSetBinding mappings.gitStatus "<cmd> Telescope git_status<CR>")
-        (mkSetBinding mappings.gitStash "<cmd> Telescope git_stash<CR>")
+        cmd = ["Telescope"];
 
-        (mkIf config.vim.lsp.enable (mkMerge [
-          (mkSetBinding mappings.lspDocumentSymbols "<cmd> Telescope lsp_document_symbols<CR>")
-          (mkSetBinding mappings.lspWorkspaceSymbols "<cmd> Telescope lsp_workspace_symbols<CR>")
+        keys =
+          [
+            (mkSetLznBinding mappings.findFiles "<cmd> Telescope find_files<CR>")
+            (mkSetLznBinding mappings.liveGrep "<cmd> Telescope live_grep<CR>")
+            (mkSetLznBinding mappings.buffers "<cmd> Telescope buffers<CR>")
+            (mkSetLznBinding mappings.helpTags "<cmd> Telescope help_tags<CR>")
+            (mkSetLznBinding mappings.open "<cmd> Telescope<CR>")
 
-          (mkSetBinding mappings.lspReferences "<cmd> Telescope lsp_references<CR>")
-          (mkSetBinding mappings.lspImplementations "<cmd> Telescope lsp_implementations<CR>")
-          (mkSetBinding mappings.lspDefinitions "<cmd> Telescope lsp_definitions<CR>")
-          (mkSetBinding mappings.lspTypeDefinitions "<cmd> Telescope lsp_type_definitions<CR>")
-          (mkSetBinding mappings.diagnostics "<cmd> Telescope diagnostics<CR>")
-        ]))
+            (mkSetLznBinding mappings.gitCommits "<cmd> Telescope git_commits<CR>")
+            (mkSetLznBinding mappings.gitBufferCommits "<cmd> Telescope git_bcommits<CR>")
+            (mkSetLznBinding mappings.gitBranches "<cmd> Telescope git_branches<CR>")
+            (mkSetLznBinding mappings.gitStatus "<cmd> Telescope git_status<CR>")
+            (mkSetLznBinding mappings.gitStash "<cmd> Telescope git_stash<CR>")
+          ]
+          ++ (optionals config.vim.lsp.enable [
+            (mkSetLznBinding mappings.lspDocumentSymbols "<cmd> Telescope lsp_document_symbols<CR>")
+            (mkSetLznBinding mappings.lspWorkspaceSymbols "<cmd> Telescope lsp_workspace_symbols<CR>")
 
-        (
-          mkIf config.vim.treesitter.enable
-          (mkSetBinding mappings.treesitter "<cmd> Telescope treesitter<CR>")
+            (mkSetLznBinding mappings.lspReferences "<cmd> Telescope lsp_references<CR>")
+            (mkSetLznBinding mappings.lspImplementations "<cmd> Telescope lsp_implementations<CR>")
+            (mkSetLznBinding mappings.lspDefinitions "<cmd> Telescope lsp_definitions<CR>")
+            (mkSetLznBinding mappings.lspTypeDefinitions "<cmd> Telescope lsp_type_definitions<CR>")
+            (mkSetLznBinding mappings.diagnostics "<cmd> Telescope diagnostics<CR>")
+          ])
+          ++ (
+            optionals config.vim.treesitter.enable [
+              (mkSetLznBinding mappings.treesitter "<cmd> Telescope treesitter<CR>")
+            ]
           )
-
-        (
-          mkIf config.vim.projects.project-nvim.enable
-          (mkSetBinding mappings.findProjects "<cmd> Telescope projects<CR>")
-        )
-      ];
+          ++ (
+            optionals config.vim.projects.project-nvim.enable [
+              (mkSetLznBinding mappings.findProjects "<cmd Telescope projects<CR>")
+            ]
+          );
+      };
 
       binds.whichKey.register = pushDownDefault {
         "<leader>f" = "+Telescope";
@@ -66,29 +75,6 @@ in {
         "<leader>fv" = "Telescope Git";
         "<leader>fvc" = "Commits";
       };
-
-      pluginRC.telescope = entryAnywhere ''
-        local telescope = require('telescope')
-        telescope.setup(${toLuaObject cfg.setupOpts})
-
-        ${
-          if config.vim.ui.noice.enable
-          then "telescope.load_extension('noice')"
-          else ""
-        }
-
-        ${
-          if config.vim.notify.nvim-notify.enable
-          then "telescope.load_extension('notify')"
-          else ""
-        }
-
-        ${
-          if config.vim.projects.project-nvim.enable
-          then "telescope.load_extension('projects')"
-          else ""
-        }
-      '';
     };
   };
 }

modules/plugins/visuals/fidget/config.nix

@@ -4,16 +4,15 @@
   ...
 }: let
   inherit (lib.modules) mkIf;
-  inherit (lib.nvim.lua) toLuaObject;
-  inherit (lib.nvim.dag) entryAnywhere;
 
   cfg = config.vim.visuals.fidget-nvim;
 in {
   config = mkIf cfg.enable {
-    vim.startPlugins = ["fidget-nvim"];
-
-    vim.pluginRC.fidget-nvim = entryAnywhere ''
-      require'fidget'.setup(${toLuaObject cfg.setupOpts})
-    '';
+    vim.lazy.plugins.fidget-nvim = {
+      package = "fidget-nvim";
+      setupModule = "fidget";
+      event = "LspAttach";
+      inherit (cfg) setupOpts;
+    };
   };
 }

modules/wrapper/lazy/config.nix

@@ -0,0 +1,108 @@
+{
+  lib,
+  config,
+  ...
+}: let
+  inherit (builtins) toJSON typeOf head length filter concatLists concatStringsSep;
+  inherit (lib.attrsets) mapAttrsToList;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.generators) mkLuaInline;
+  inherit (lib.strings) optionalString;
+  inherit (lib.nvim.lua) toLuaObject;
+  inherit (lib.nvim.dag) entryBefore entryAfter;
+  cfg = config.vim.lazy;
+
+  toLuaLznKeySpec = keySpec:
+    (removeAttrs keySpec ["key" "lua" "action"])
+    // {
+      "@1" = keySpec.key;
+      "@2" =
+        if keySpec.lua
+        then mkLuaInline keySpec.action
+        else keySpec.action;
+    };
+
+  toLuaLznSpec = name: spec:
+    (removeAttrs spec ["package" "setupModule" "setupOpts" "keys"])
+    // {
+      "@1" = name;
+      before =
+        if spec.before != null
+        then
+          mkLuaInline ''
+            function()
+              ${spec.before}
+            end
+          ''
+        else null;
+
+      after =
+        if spec.setupModule == null && spec.after == null
+        then null
+        else
+          mkLuaInline ''
+            function()
+              ${
+              optionalString (spec.setupModule != null)
+              "require(${toJSON spec.setupModule}).setup(${toLuaObject spec.setupOpts})"
+            }
+              ${optionalString (spec.after != null) spec.after}
+            end
+          '';
+
+      keys =
+        if typeOf spec.keys == "list" && length spec.keys > 0 && typeOf (head spec.keys) == "set"
+        then map toLuaLznKeySpec (filter (keySpec: keySpec.key != null) spec.keys)
+        # empty list or str or (listOf str)
+        else spec.keys;
+    };
+  lznSpecs = mapAttrsToList toLuaLznSpec cfg.plugins;
+
+  pluginPackages = mapAttrsToList (_: plugin: plugin.package) cfg.plugins;
+
+  specToNotLazyConfig = _: spec: ''
+    do
+      ${optionalString (spec.before != null) spec.before}
+      ${optionalString (spec.setupModule != null)
+      "require(${toJSON spec.setupModule}).setup(${toLuaObject spec.setupOpts})"}
+      ${optionalString (spec.after != null) spec.after}
+    end
+  '';
+
+  specToKeymaps = _: spec:
+    if typeOf spec.keys == "list"
+    then map (x: removeAttrs x ["ft"]) (filter (lznKey: lznKey.action != null && lznKey.ft == null) spec.keys)
+    else if spec.keys == null || typeOf spec.keys == "string"
+    then []
+    else [spec.keys];
+
+  notLazyConfig =
+    concatStringsSep "\n"
+    (mapAttrsToList specToNotLazyConfig cfg.plugins);
+
+  beforeAllJoined =
+    concatStringsSep "\n"
+    (filter (x: x != null) (mapAttrsToList (_: spec: spec.beforeAll) cfg.plugins));
+in {
+  config.vim = mkMerge [
+    (mkIf cfg.enable {
+      startPlugins = ["lz-n" "lzn-auto-require"];
+
+      optPlugins = pluginPackages;
+
+      lazy.builtLazyConfig = ''
+        require('lz.n').load(${toLuaObject lznSpecs})
+        ${optionalString cfg.enableLznAutoRequire "require('lzn-auto-require').enable()"}
+      '';
+    })
+
+    (mkIf (!cfg.enable) {
+      startPlugins = pluginPackages;
+      lazy.builtLazyConfig = ''
+        ${beforeAllJoined}
+        ${notLazyConfig}
+      '';
+      keymaps = concatLists (mapAttrsToList specToKeymaps cfg.plugins);
+    })
+  ];
+}

modules/wrapper/lazy/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./lazy.nix
+    ./config.nix
+  ];
+}

modules/wrapper/lazy/lazy.nix

@@ -0,0 +1,237 @@
+{lib, ...}: let
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.types) enum listOf submodule nullOr str bool int attrsOf anything either oneOf lines;
+  inherit (lib.nvim.types) pluginType;
+  inherit (lib.nvim.config) mkBool;
+
+  lznKeysSpec = submodule {
+    options = {
+      key = mkOption {
+        type = nullOr str;
+        description = "Key to bind to. If key is null this entry is ignored.";
+      };
+
+      action = mkOption {
+        type = nullOr str;
+        default = null;
+        description = "Action to trigger.";
+      };
+      lua = mkBool false ''
+        If true, `action` is considered to be lua code.
+        Thus, it will not be wrapped in `""`.
+      '';
+
+      desc = mkOption {
+        description = "Description of the key map";
+        type = nullOr str;
+        default = null;
+      };
+
+      ft = mkOption {
+        description = "TBD";
+        type = nullOr (listOf str);
+        default = null;
+      };
+
+      mode = mkOption {
+        description = "Modes to bind in";
+        type = either str (listOf str);
+        default = ["n" "x" "s" "o"];
+      };
+
+      silent = mkBool true "Whether this mapping should be silent. Equivalent to adding <silent> to a map.";
+      nowait = mkBool false "Whether to wait for extra input on ambiguous mappings. Equivalent to adding <nowait> to a map.";
+      script = mkBool false "Equivalent to adding <script> to a map.";
+      expr = mkBool false "Means that the action is actually an expression. Equivalent to adding <expr> to a map.";
+      unique = mkBool false "Whether to fail if the map is already defined. Equivalent to adding <unique> to a map.";
+      noremap = mkBool true "Whether to use the 'noremap' variant of the command, ignoring any custom mappings on the defined action. It is highly advised to keep this on, which is the default.";
+    };
+  };
+
+  lznPluginType = submodule {
+    options = {
+      package = mkOption {
+        type = pluginType;
+        description = "Plugin package";
+      };
+
+      setupModule = mkOption {
+        type = nullOr str;
+        description = "Lua module to run setup function on.";
+        default = null;
+      };
+
+      setupOpts = mkOption {
+        type = submodule {freeformType = attrsOf anything;};
+        description = "Options to pass to the setup function";
+        default = {};
+      };
+
+      # lz.n options
+
+      enabled = mkOption {
+        type = nullOr (either bool str);
+        description = "When false, or if the lua function returns false, this plugin will not be included in the spec";
+        default = null;
+      };
+
+      beforeAll = mkOption {
+        type = nullOr lines;
+        description = "Lua code to run before any plugins are loaded. This will be wrapped in a function.";
+        default = null;
+      };
+
+      before = mkOption {
+        type = nullOr lines;
+        description = "Lua code to run before plugin is loaded. This will be wrapped in a function.";
+        default = null;
+      };
+
+      after = mkOption {
+        type = nullOr lines;
+        description = ''
+          Lua code to run after plugin is loaded. This will be wrapped in a function.
+
+          If [](#opt-vim.lazy.plugins._name_.setupModule) is provided, the setup will be ran before `after`.
+        '';
+        default = null;
+      };
+
+      event = mkOption {
+        description = "Lazy-load on event";
+        default = null;
+        type = let
+          event = submodule {
+            options = {
+              event = mkOption {
+                type = nullOr (either str (listOf str));
+                description = "Exact event name";
+                example = "BufEnter";
+              };
+              pattern = mkOption {
+                type = nullOr (either str (listOf str));
+                description = "Event pattern";
+                example = "BufEnter *.lua";
+              };
+            };
+          };
+        in
+          nullOr (oneOf [str (listOf str) event]);
+      };
+
+      cmd = mkOption {
+        description = "Lazy-load on command";
+        default = null;
+        type = nullOr (either str (listOf str));
+      };
+
+      ft = mkOption {
+        description = "Lazy-load on filetype";
+        default = null;
+        type = nullOr (either str (listOf str));
+      };
+
+      keys = mkOption {
+        description = "Lazy-load on key mapping";
+        default = null;
+        type = nullOr (oneOf [str (listOf lznKeysSpec) (listOf str)]);
+        example = ''
+          keys = [
+            {
+              mode = "n";
+              key = "<leader>s";
+              action = ":DapStepOver<cr>";
+              desc = "DAP Step Over";
+            }
+            {
+              mode = ["n", "x"];
+              key = "<leader>dc";
+              action = "function() require('dap').continue() end";
+              lua = true;
+              desc = "DAP Continue";
+            }
+          ]
+        '';
+      };
+
+      colorscheme = mkOption {
+        description = "Lazy-load on colorscheme.";
+        type = nullOr (either str (listOf str));
+        default = null;
+      };
+
+      lazy = mkBool false "Lazy-load manually, e.g. using `trigger_load`.";
+
+      priority = mkOption {
+        type = nullOr int;
+        description = "Only useful for stat plugins (not lazy-loaded) to force loading certain plugins first.";
+        default = null;
+      };
+
+      load = mkOption {
+        type = nullOr lines;
+        default = null;
+        description = ''
+          Lua code to override the `vim.g.lz_n.load()` function for a single plugin.
+
+          This will be wrapped in a function.
+        '';
+      };
+    };
+  };
+in {
+  options.vim.lazy = {
+    enable = mkEnableOption "plugin lazy-loading via lz.n and lzn-auto-require" // {default = true;};
+    loader = mkOption {
+      description = "Lazy loader to use";
+      type = enum ["lz.n"];
+      default = "lz.n";
+    };
+
+    plugins = mkOption {
+      default = [];
+      type = attrsOf lznPluginType;
+      description = ''
+        Plugins to lazy load.
+
+        The attribute key is used as the plugin name: for the default `vim.g.lz_n.load`
+        function this should be either the `package.pname` or `package.name`.
+      '';
+      example = ''
+        {
+          toggleterm-nvim = {
+            package = "toggleterm-nvim";
+            setupModule = "toggleterm";
+            setupOpts = cfg.setupOpts;
+
+            after = "require('toggleterm').do_something()";
+            cmd = ["ToggleTerm"];
+          };
+
+          $${pkgs.vimPlugins.vim-bbye.pname} = {
+            package = pkgs.vimPlugins.vim-bbye;
+            cmd = ["Bdelete" "Bwipeout"];
+          };
+        }
+      '';
+    };
+
+    enableLznAutoRequire = mkOption {
+      description = ''
+        Enable lzn-auto-require. Since builtin plugins rely on this, only turn
+        off for debugging.
+      '';
+      type = bool;
+      default = true;
+    };
+
+    builtLazyConfig = mkOption {
+      internal = true;
+      type = lines;
+      description = ''
+        The built config for lz.n, or if `vim.lazy.enable` is false, the
+        individual plugin configs.
+      '';
+    };
+  };
+}

modules/wrapper/rc/config.nix

@@ -5,7 +5,7 @@
 }: let
   inherit (builtins) map mapAttrs filter;
   inherit (lib.attrsets) mapAttrsToList;
-  inherit (lib.strings) concatLines concatMapStringsSep;
+  inherit (lib.strings) concatLines concatMapStringsSep optionalString;
   inherit (lib.trivial) showWarnings;
   inherit (lib.generators) mkLuaInline;
   inherit (lib.nvim.dag) entryAfter mkLuarcSection resolveDag entryAnywhere;
@@ -52,7 +52,8 @@ in {
         optionsScript = entryAfter ["basic"] (concatLines optionsScript);
 
         # Basic
-        pluginConfigs = entryAfter ["optionsScript"] pluginConfigs;
+        lazyConfigs = entryAfter ["optionsScript"] cfg.lazy.builtLazyConfig;
+        pluginConfigs = entryAfter ["lazyConfigs"] pluginConfigs;
         extraPluginConfigs = entryAfter ["pluginConfigs"] extraPluginConfigs;
         mappings = entryAfter ["extraPluginConfigs"] keymaps;
       };