Keymap/extra options (#1384)

* keymaps: fix unable to set noremap = false

Currently setting `vim.keymaps.*.noremap = false` has no effect.
Given that noremap is set by default, the only way to undo it is
to use `remap = true`. This commit adds `remap` as an internal option,
and derives its final value as the inverse of noremap.
This way, setting `noremap` to `false` now behaves as expected.

See https://neovim.io/doc/user/lua-guide.html#_creating-mappings

* keymaps/config: fix formatting

merge unnecessarily split attrset

* keymaps/options: remove unnecessary option

+ tweak related release notes entry

configuration.nix

@@ -92,6 +92,7 @@ isMaximal: {
       ruby.enable = false;
       fsharp.enable = false;
       just.enable = false;
+      make.enable = false;
       qml.enable = false;
       jinja.enable = false;
       tailwind.enable = false;

docs/manual/release-notes/rl-0.9.md

@@ -172,10 +172,17 @@
 
 - Added [`golangci-lint`](https://golangci-lint.run/) for more diagnostics.
 
+- Added Makefile support via `languages.make`.
+
 [vagahbond](https://github.com/vagahbond): [codewindow.nvim]:
 https://github.com/gorbit99/codewindow.nvim
 
 - Add [codewindow.nvim] plugin in `vim.assistant.codewindow` with `enable` and
   `setupOpts`
 
+[irobot](https://github.com/irobot):
+
+- Fix non-functional `vim.keymaps.*.noremap`. Now, setting it to false is
+  equivalent to `:lua vim.keymap.set(..., { remap = true })`
+
 <!-- vim: set textwidth=80: -->

modules/plugins/languages/default.nix

@@ -52,6 +52,7 @@ in {
     ./yaml.nix
     ./ruby.nix
     ./just.nix
+    ./make.nix
     ./xml.nix
 
     # This is now a hard deprecation.

modules/plugins/languages/make.nix

@@ -0,0 +1,93 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.meta) getExe;
+  inherit (lib.types) listOf enum;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.make;
+
+  defaultFormat = ["bake"];
+  formats = {
+    bake = {
+      command = "${pkgs.mbake}/bin/mbake";
+    };
+  };
+
+  defaultDiagnosticsProvider = ["checkmake"];
+  diagnosticsProviders = {
+    checkmake = {
+      config = {
+        cmd = getExe pkgs.checkmake;
+      };
+    };
+  };
+in {
+  options.vim.languages.make = {
+    enable = mkEnableOption "Make support";
+
+    treesitter = {
+      enable = mkEnableOption "Make treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "make";
+    };
+
+    format = {
+      enable = mkEnableOption "Make formatting" // {default = config.vim.languages.enableFormat;};
+      type = mkOption {
+        description = "make formatter to use";
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+      };
+    };
+
+    extraDiagnostics = {
+      enable = mkEnableOption "extra Make diagnostics" // {default = config.vim.languages.enableExtraDiagnostics;};
+      types = diagnostics {
+        langDesc = "Make";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.make = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.make = cfg.extraDiagnostics.types;
+        linters =
+          mkMerge (map (name: {${name} = diagnosticsProviders.${name}.config;})
+            cfg.extraDiagnostics.types);
+      };
+    })
+  ]);
+}

modules/wrapper/rc/config.nix

@@ -39,6 +39,7 @@ in {
 
     getOpts = keymap: {
       inherit (keymap) desc silent nowait script expr unique noremap;
+      remap = !keymap.noremap;
     };
 
     toLuaKeymap = bind: "vim.keymap.set(${toLuaObject bind.mode}, ${toLuaObject bind.key}, ${toLuaObject (getAction bind)}, ${toLuaObject (getOpts bind)})";