Merge ce9d7ee870 into 8ff50562d7

Terraform doesn't register hcl and doesn't offer good DX if manually set
for editing e.g. nomad HCL files.

Incl. reformat with alejandra

modules/plugins/languages/default.nix

@@ -8,6 +8,7 @@ in {
     ./css.nix
     ./elixir.nix
     ./go.nix
+    ./hcl.nix
     ./html.nix
     ./java.nix
     ./lua.nix

modules/plugins/languages/hcl.nix

@@ -0,0 +1,116 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) package bool enum;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.hcl;
+
+  defaultServer = "terraform-ls";
+  servers = {
+    terraform-ls = rec {
+      package = pkgs.terraform-ls;
+      lspConfig = ''
+        lspconfig.terraformls.setup {
+          capabilities = capabilities,
+          on_attach=default_on_attach,
+          cmd = {"${lib.getExe package}", "serve"},
+        }
+      '';
+    };
+  };
+
+  defaultFormat = "hclfmt";
+  formats = {
+    hclfmt = rec {
+      package = pkgs.hclfmt;
+      nullConfig = ''
+        table.insert(
+          ls_sources,
+          null_ls.builtins.formatting.hclfmt.with({
+            command = "${lib.getExe package}",
+          })
+        )
+      '';
+    };
+  };
+in {
+  options.vim.languages.hcl = {
+    enable = mkEnableOption "HCL support";
+
+    treesitter = {
+      enable = mkEnableOption "HCL treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "hcl";
+    };
+
+    lsp = {
+      enable = mkEnableOption "HCL LSP support (terraform-ls)" // {default = config.vim.languages.enableLSP;};
+      # TODO: (maybe, is it better?) it would be cooler to use vscode-extensions.hashicorp.hcl probably, shouldn't be too hard
+      package = mkOption {
+        description = "HCL language server package (terraform-ls)";
+        type = package;
+        default = servers.${defaultServer}.package;
+      };
+    };
+
+    format = {
+      enable = mkOption {
+        description = "Enable HCL formatting";
+        type = bool;
+        default = config.vim.languages.enableFormat;
+      };
+      type = mkOption {
+        description = "HCL formatter to use";
+        type = enum (attrNames formats);
+        default = defaultFormat;
+      };
+      package = mkOption {
+        description = "HCL formatter package";
+        type = package;
+        default = formats.${cfg.format.type}.package;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    {
+      vim.pluginRC.hcl = ''
+        vim.api.nvim_create_autocmd("FileType", {
+          pattern = "hcl",
+          callback = function(opts)
+            local bo = vim.bo[opts.buf]
+            bo.tabstop = 2
+            bo.shiftwidth = 2
+            bo.softtabstop = 2
+          end
+        })
+
+        local ft = require('Comment.ft')
+        ft
+          .set('hcl', '#%s')
+      '';
+    }
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources = lib.optionalAttrs (! config.vim.languages.terraform.lsp.enable) {
+        terraform-ls = servers.${cfg.lsp.server}.lspConfig;
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.lsp.null-ls.enable = true;
+      vim.lsp.null-ls.sources.hcl-format = formats.${cfg.format.type}.nullConfig;
+    })
+  ]);
+}

modules/plugins/utility/preview/markdown-preview/config.nix

@@ -4,9 +4,8 @@
   lib,
   ...
 }: let
-  inherit (lib.strings) stringLength concatMapStringsSep;
+  inherit (lib.strings) concatMapStringsSep;
   inherit (lib.modules) mkIf;
-
   cfg = config.vim.utility.preview.markdownPreview;
 in {
   config = mkIf cfg.enable {
@@ -19,8 +18,8 @@ in {
       mkdp_filetypes = [(concatMapStringsSep ", " (x: "'" + x + "'") cfg.filetypes)];
       mkdp_command_for_global = cfg.alwaysAllowPreview;
       mkdp_open_to_the_world = cfg.broadcastServer;
-      mkdp_open_ip = mkIf (stringLength cfg.customIP > 0) cfg.customIP;
-      mkdp_port = mkIf (stringLength cfg.customPort > 0) cfg.customPort;
+      mkdp_open_ip = cfg.customIP;
+      mkdp_port = cfg.customPort;
     };
   };
 }