ci: use repo name in editorconfig check

languages/fsharp: init

.github/workflows/check.yml

@@ -119,7 +119,7 @@ jobs:
           GITHUB_TOKEN: ${{ secrets.GITHUB_TOKEN }}
         run: |
           gh api \
-            repos/${{ github.repository }}/pulls/${{github.event.number}}/files --paginate \
+            repos/notashelf/nvf/pulls/${{github.event.number}}/files --paginate \
             | jq '.[] | select(.status != "removed") | .filename' \
             > "$HOME/changed_files"
 

configuration.nix

@@ -82,6 +82,7 @@ isMaximal: {
       elixir.enable = false;
       haskell.enable = false;
       ruby.enable = false;
+      fsharp.enable = false;
 
       tailwind.enable = false;
       svelte.enable = false;

docs/manual/configuring/languages.md

@@ -19,6 +19,7 @@ formatting to diagnostics. The following languages have sections under the
 - Go: [vim.languages.go.enable](#opt-vim.languages.go.enable)
 - Lua: [vim.languages.lua.enable](#opt-vim.languages.lua.enable)
 - PHP: [vim.languages.php.enable](#opt-vim.languages.php.enable)
+- F#: [vim.languages.fsharp.enable](#opt-vim.languages.fsharp.enable)
 
 Adding support for more languages, and improving support for existing ones are
 great places where you can contribute with a PR.

docs/release-notes/rl-0.8.md

@@ -276,3 +276,7 @@
 [rice-cracker-dev](https://github.com/rice-cracker-dev):
 
 - `eslint_d` now checks for configuration files to load.
+
+[Sc3l3t0n](https://github.com/Sc3l3t0n):
+
+- Add F# support under `vim.languages.fsharp`.

flake.lock

@@ -77,11 +77,11 @@
     },
     "nixpkgs": {
       "locked": {
-        "lastModified": 1741865919,
-        "narHash": "sha256-4thdbnP6dlbdq+qZWTsm4ffAwoS8Tiq1YResB+RP6WE=",
+        "lastModified": 1742923925,
+        "narHash": "sha256-biPjLws6FiBVUUDHEMFq5pUQL84Wf7PntPYdo3oKkFw=",
         "owner": "nixos",
         "repo": "nixpkgs",
-        "rev": "573c650e8a14b2faa0041645ab18aed7e60f0c9a",
+        "rev": "25d1b84f5c90632a623c48d83a2faf156451e6b1",
         "type": "github"
       },
       "original": {

modules/plugins/languages/default.nix

@@ -10,6 +10,7 @@ in {
     ./clang.nix
     ./css.nix
     ./elixir.nix
+    ./fsharp.nix
     ./gleam.nix
     ./go.nix
     ./hcl.nix

modules/plugins/languages/fsharp.nix

@@ -0,0 +1,109 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) either listOf package str enum;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.lists) isList;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.lua) expToLua;
+
+  defaultServer = "fsautocomplete";
+  servers = {
+    fsautocomplete = {
+      package = pkgs.fsautocomplete;
+      internalFormatter = false;
+      lspConfig = ''
+        lspconfig.fsautocomplete.setup {
+          capabilities = capabilities;
+          on_attach = default_on_attach;
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else "{'${cfg.lsp.package}/bin/fsautocomplete'}"
+        },
+        }
+      '';
+    };
+  };
+
+  defaultFormat = "fantomas";
+  formats = {
+    fantomas = {
+      package = pkgs.fantomas;
+      nullConfig = ''
+        table.insert(
+          ls_sources,
+          null_ls.builtins.formatting.fantomas.with({
+            command = "${cfg.format.package}/bin/fantomas",
+          })
+        )
+      '';
+    };
+  };
+
+  cfg = config.vim.languages.fsharp;
+in {
+  options = {
+    vim.languages.fsharp = {
+      enable = mkEnableOption "F# language support";
+
+      treesitter = {
+        enable = mkEnableOption "F# treesitter" // {default = config.vim.languages.enableTreesitter;};
+        package = mkGrammarOption pkgs "fsharp";
+      };
+
+      lsp = {
+        enable = mkEnableOption "F# LSP support" // {default = config.vim.languages.enableLSP;};
+        server = mkOption {
+          type = enum (attrNames servers);
+          default = defaultServer;
+          description = "F# LSP server to use";
+        };
+
+        package = mkOption {
+          type = either package (listOf str);
+          default = servers.${cfg.lsp.server}.package;
+          example = ''[lib.getExe pkgs.fsautocomplete "--state-directory" "~/.cache/fsautocomplete"]'';
+          description = "F# LSP server package, or the command to run as a list of strings";
+        };
+      };
+      format = {
+        enable = mkEnableOption "F# formatting" // {default = config.vim.languages.enableFormat;};
+
+        type = mkOption {
+          type = enum (attrNames formats);
+          default = defaultFormat;
+          description = "F# formatter to use";
+        };
+
+        package = mkOption {
+          type = package;
+          default = formats.${cfg.format.type}.package;
+          description = "F# formatter package";
+        };
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.fsharp-lsp = servers.${cfg.lsp.server}.lspConfig;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.lsp.null-ls.enable = true;
+      vim.lsp.null-ls.sources.fsharp-format = formats.${cfg.format.type}.nullConfig;
+    })
+  ]);
+}