diff --git a/configuration.nix b/configuration.nix
index 9cce777a..725bad96 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -74,6 +74,7 @@ isMaximal: {
       };
       toml.enable = isMaximal;
       xml.enable = isMaximal;
+      docker.enable = isMaximal;
 
       # Language modules that are not as common.
       arduino.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 4a322868..019a269d 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -186,6 +186,10 @@
 - Added [Selenen](https://github.com/kampfkarren/selene) for more diagnostics in
   `languages.lua`.
 
+- Added `languages.docker` for Docker and Docker-Compose support. Thanks to
+  [poseidon-rises](https://github.com/poseidon-rises) for creating most of it in
+  [!1104](https://github.com/NotAShelf/nvf/pull/1104).
+
 - Added [`mdformat`](https://mdformat.rtfd.io/) support to `languages.markdown`
   with the extensions for [GFM](https://github.github.com/gfm/),
   [front matter](https://www.markdownlang.com/advanced/frontmatter.html) and
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 1cdead76..468d4c37 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -57,6 +57,7 @@ in {
     ./just.nix
     ./make.nix
     ./xml.nix
+    ./docker.nix
 
     # This is now a hard deprecation.
     (mkRenamedOptionModule ["vim" "languages" "enableLSP"] ["vim" "lsp" "enable"])
diff --git a/modules/plugins/languages/docker.nix b/modules/plugins/languages/docker.nix
new file mode 100644
index 00000000..d38a37e8
--- /dev/null
+++ b/modules/plugins/languages/docker.nix
@@ -0,0 +1,156 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum package listOf;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.docker;
+
+  defaultServers = ["docker-language-server"];
+  servers = {
+    docker-language-server = {
+      cmd = [
+        (getExe pkgs.docker-language-server)
+        "start"
+        "--stdio"
+      ];
+      filetypes = [
+        "dockerfile"
+        "dockercompose"
+      ];
+      root_markers = [
+        ".git"
+        "Dockerfile"
+        "docker-compose.yaml"
+        "docker-compose.yml"
+        "compose.yaml"
+        "compose.yml"
+        "docker-bake.json"
+        "docker-bake.hcl"
+      ];
+    };
+  };
+
+  defaultFormat = ["dockerfmt"];
+  formats = {
+    dockerfmt = {
+      command = getExe pkgs.dockerfmt;
+    };
+  };
+
+  defaultDiagnosticsProvider = ["hadolint"];
+  diagnosticsProviders = {
+    hadolint = {
+      config.cmd = getExe (
+        pkgs.writeShellApplication {
+          name = "hadolint";
+          runtimeInputs = [pkgs.hadolint];
+          text = "hadolint -";
+        }
+      );
+    };
+  };
+in {
+  options.vim.languages.docker = {
+    enable = mkEnableOption "Docker language support";
+    treesitter = {
+      enable = mkEnableOption "Docker treesitter support";
+      package = mkGrammarOption pkgs "dockerfile";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Docker LSP support"
+        // {
+          default = config.vim.lsp.enable;
+        };
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Docker LSP server to use";
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "Dockerfile formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+        };
+
+      type = mkOption {
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+        description = "Dockerfile formatter to use";
+      };
+    };
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra Dockerfile diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+        };
+
+      types = diagnostics {
+        langDesc = "Dockerfile";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.dockerfile = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.dockerfile = cfg.extraDiagnostics.types;
+        linters = mkMerge (
+          map (name: {
+            ${name} = diagnosticsProviders.${name}.config;
+          })
+          cfg.extraDiagnostics.types
+        );
+      };
+    })
+  ];
+}