feat: apply new module format to nvimtree

modules/filetree/nvimtree-lua/config.nix

@@ -0,0 +1,131 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+with lib;
+with builtins; let
+  cfg = config.vim.filetree.nvimTreeLua;
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins = ["nvim-tree-lua"];
+
+    vim.nnoremap = {
+      "<C-n>" = ":NvimTreeToggle<CR>";
+      "<leader>tr" = ":NvimTreeRefresh<CR>";
+      "<leader>tg" = ":NvimTreeFindFile<CR>";
+      "<leader>tf" = ":NvimTreeFocus<CR>";
+    };
+
+    vim.luaConfigRC.nvimtreelua = nvim.dag.entryAnywhere ''
+        local function open_nvim_tree(data)
+            local IGNORED_FT = {
+                "markdown",
+            }
+
+            -- buffer is a real file on the disk
+            local real_file = vim.fn.filereadable(data.file) == 1
+
+            -- buffer is a [No Name]
+             local no_name = data.file == "" and vim.bo[data.buf].buftype == ""
+
+            -- &ft
+            local filetype = vim.bo[data.buf].ft
+
+            -- only files please
+            if not real_file and not no_name then
+                return
+            end
+
+            -- skip ignored filetypes
+            if vim.tbl_contains(IGNORED_FT, filetype) then
+                return
+            end
+
+            -- open the tree but don't focus it
+            require("nvim-tree.api").tree.toggle({ focus = false })
+        end
+
+        -- Open on startup has been deprecated
+        -- see https://github.com/nvim-tree/nvim-tree.lua/wiki/Open-At-Startup
+        -- use a nix eval to dynamically insert the open on startup function
+        ${
+        # FIXME: this function is actually obslete due to the existence of the dashboard, I need to find an alternative logic
+        if (cfg.openOnSetup)
+        then ''
+          vim.api.nvim_create_autocmd({ "VimEnter" }, { callback = open_nvim_tree })
+        ''
+        else ""
+      }
+
+      require'nvim-tree'.setup({
+        sort_by = ${"'" + cfg.sortBy + "'"},
+        disable_netrw = ${boolToString cfg.disableNetRW},
+        hijack_netrw = ${boolToString cfg.hijackNetRW},
+        hijack_cursor = ${boolToString cfg.hijackCursor},
+        open_on_tab = ${boolToString cfg.openTreeOnNewTab},
+        sync_root_with_cwd = ${boolToString cfg.syncRootWithCwd},
+        update_focused_file = {
+          enable = ${boolToString cfg.updateFocusedFile.enable},
+          update_cwd = ${boolToString cfg.updateFocusedFile.update_cwd},
+        },
+
+        view  = {
+          width = ${toString cfg.view.width},
+          side = ${"'" + cfg.view.side + "'"},
+          adaptive_size = ${boolToString cfg.view.adaptiveSize},
+          hide_root_folder = ${boolToString cfg.view.hideRootFolder},
+        },
+        git = {
+          enable = ${boolToString cfg.git.enable},
+          ignore = ${boolToString cfg.git.ignore},
+        },
+
+        filesystem_watchers = {
+          enable = ${boolToString cfg.filesystemWatchers.enable},
+        },
+
+        actions = {
+          open_file = {
+            quit_on_open = ${boolToString cfg.actions.openFile.quitOnOpen},
+            resize_window = ${boolToString cfg.actions.openFile.resizeWindow},
+            window_picker = {
+                enable = ${boolToString cfg.actions.openFile.windowPicker.enable},
+                chars = ${toString cfg.actions.openFile.windowPicker.chars},
+            },
+          },
+          expand_all = {
+            exclude = {
+              ${builtins.concatStringsSep "\n" (builtins.map (s: "\"" + s + "\",") cfg.actions.expandAll.exclude)}
+            },
+          }
+        },
+
+        renderer = {
+          highlight_git = ${boolToString cfg.renderer.higlightGit},
+          highlight_opened_files = ${"'" + cfg.renderer.highlightOpenedFiles + "'"},
+          indent_markers = {
+            enable = ${boolToString cfg.renderer.indentMarkers},
+          },
+          -- TODO: those two
+          add_trailing = ${boolToString cfg.renderer.trailingSlash},
+          group_empty = ${boolToString cfg.renderer.groupEmptyFolders},
+        },
+
+        system_open = {
+          cmd = ${"'" + cfg.systemOpenCmd + "'"},
+        },
+        diagnostics = {
+          enable = ${boolToString cfg.lspDiagnostics},
+        },
+        filters = {
+          dotfiles = ${boolToString cfg.hideDotFiles},
+          custom = {
+            ${builtins.concatStringsSep "\n" (builtins.map (s: "\"" + s + "\",") cfg.hideFiles)}
+          },
+        },
+      })
+    '';
+  };
+}

modules/filetree/nvimtree-lua/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./config.nix
+    ./nvimtree-lua.nix
+  ];
+}

modules/filetree/nvimtree-lua/nvimtree-lua.nix

@@ -0,0 +1,417 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+with lib;
+with builtins; let
+  cfg = config.vim.filetree.nvimTreeLua;
+in {
+  options.vim.filetree.nvimTreeLua = {
+    enable = mkOption {
+      type = types.bool;
+      default = false;
+      description = "Enable nvim-tree-lua";
+    };
+
+    sortBy = mkOption {
+      default = "name";
+      description = "Sort by name or extension";
+      type = types.enum ["name" "extension" "modification_time" "case_sensitive"];
+    };
+
+    treeSide = mkOption {
+      default = "left";
+      description = "Side the tree will appear on left or right";
+      type = types.enum ["left" "right"];
+    };
+
+    treeWidth = mkOption {
+      default = 25;
+      description = "Width of the tree in charecters";
+      type = types.int;
+    };
+
+    hideFiles = mkOption {
+      default = [".git" "node_modules" ".cache"];
+      description = "Files to hide in the file view by default.";
+      type = with types; listOf str;
+    };
+
+    hideIgnoredGitFiles = mkOption {
+      default = false;
+      description = "Hide files ignored by git";
+      type = types.bool;
+    };
+
+    openOnSetup = mkOption {
+      default = true;
+      description = "Open when vim is started on a directory";
+      type = types.bool;
+    };
+
+    closeOnLastWindow = mkOption {
+      default = true;
+      description = "Close when tree is last window open";
+      type = types.bool;
+    };
+
+    ignoreFileTypes = mkOption {
+      default = [];
+      description = "Ignore file types";
+      type = with types; listOf str;
+    };
+
+    followBufferFile = mkOption {
+      default = true;
+      description = "Follow file that is in current buffer on tree";
+      type = types.bool;
+    };
+
+    indentMarkers = mkOption {
+      default = true;
+      description = "Show indent markers";
+      type = types.bool;
+    };
+
+    hideDotFiles = mkOption {
+      default = false;
+      description = "Hide dotfiles";
+      type = types.bool;
+    };
+
+    openTreeOnNewTab = mkOption {
+      default = false;
+      description = "Opens the tree view when opening a new tab";
+      type = types.bool;
+    };
+
+    disableNetRW = mkOption {
+      default = false;
+      description = "Disables netrw and replaces it with tree";
+      type = types.bool;
+    };
+
+    hijackNetRW = mkOption {
+      default = true;
+      description = "Prevents netrw from automatically opening when opening directories";
+      type = types.bool;
+    };
+
+    trailingSlash = mkOption {
+      default = true;
+      description = "Add a trailing slash to all folders";
+      type = types.bool;
+    };
+
+    groupEmptyFolders = mkOption {
+      default = true;
+      description = "Compact empty folders trees into a single item";
+      type = types.bool;
+    };
+
+    lspDiagnostics = mkOption {
+      default = true;
+      description = "Shows lsp diagnostics in the tree";
+      type = types.bool;
+    };
+
+    systemOpenCmd = mkOption {
+      default = "${pkgs.xdg-utils}/bin/xdg-open";
+      description = "The command used to open a file with the associated default program";
+      type = types.str;
+    };
+
+    updateCwd = mkOption {
+      # updateCwd has been deprecated in favor of syncRootWithCwd
+      # this option is kept for backwards compatibility
+      default = true;
+      description = "Updates the tree when changing nvim's directory (DirChanged event).";
+      type = types.bool;
+    };
+
+    ignore_ft_on_setup = mkOption {
+      default = [];
+      description = "Ignore file types on setup";
+      type = with types; listOf str;
+    };
+
+    hijackCursor = mkOption {
+      default = false;
+      description = "Hijack the cursor in the tree to put it at the start of the filename";
+      type = types.bool;
+    };
+
+    hijackUnnamedBufferWhenOpening = mkOption {
+      default = false;
+      description = "Open nvimtree in place of the unnamed buffer if it's empty.";
+      type = types.bool;
+    };
+
+    syncRootWithCwd = mkOption {
+      default = true;
+      description = "Changes the tree root directory on `DirChanged` and refreshes the tree";
+      type = types.bool;
+    };
+
+    updateFocusedFile = mkOption {
+      default = {
+        enable = true;
+        update_cwd = true;
+      };
+      description = "Updates the tree when changing nvim's directory (DirChanged event).";
+      type = with types; attrsOf (either bool (attrsOf bool));
+    };
+
+    view = {
+      adaptiveSize = mkOption {
+        default = true;
+        description = "Resize the tree when the window is resized";
+        type = types.bool;
+      };
+      side = mkOption {
+        default = "left";
+        description = "Side the tree will appear on left or right";
+        type = types.enum ["left" "right"];
+      };
+      width = mkOption {
+        default = 35;
+        description = "Width of the tree in charecters";
+        type = types.int;
+      };
+
+      hideRootFolder = mkOption {
+        default = false;
+        description = "Hide the root folder";
+        type = types.bool;
+      };
+    };
+
+    git = {
+      enable = mkEnableOption "Git integration";
+      ignore = mkOption {
+        default = true;
+        description = "Ignore files in git";
+        type = types.bool;
+      };
+    };
+
+    filesystemWatchers = {
+      enable = mkOption {
+        default = true;
+        description = "Enable filesystem watchers";
+        type = types.bool;
+      };
+    };
+
+    actions = {
+      openFile = {
+        resizeWindow = mkOption {
+          default = true;
+          description = "Resize the tree when opening a file";
+          type = types.bool;
+        };
+        quitOnOpen = mkOption {
+          default = false;
+          description = "Quit the tree when opening a file";
+          type = types.bool;
+        };
+        windowPicker = {
+          enable = mkEnableOption "Window picker";
+
+          chars = mkOption {
+            default = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890";
+            description = "A string of chars used as identifiers by the window picker";
+            type = types.str;
+          };
+
+          /*
+          # FIXME: Can't get this to place the list items in a lua table
+          exclude = {
+            fileType = mkOption {
+              default = ["notify" "packer" "qf" "diff" "fugitive" "fugitiveblame"];
+              description = "File types to exclude from window picker";
+              type = with types; listOf str;
+            };
+            buftype = mkOption {
+              default = ["nofile" "terminal" "help"];
+              description = "Buffer types to exclude from window picker";
+              type = with types; listOf str;
+            };
+          };
+          */
+        };
+      };
+      expandAll = {
+        exclude = mkOption {
+          default = [];
+          description = "Exclude files from expand all";
+          type = with types; listOf str;
+        };
+      };
+    };
+
+    renderer = {
+      higlightGit = mkOption {
+        default = false;
+        description = "Highlight git related files";
+        type = types.bool;
+      };
+
+      highlightOpenedFiles = mkOption {
+        default = "none";
+        description = "Highlight opened files";
+        type = types.enum ["none" "icon" "name" "all"];
+      };
+
+      indentMarkers = mkOption {
+        default = false;
+        description = "Show indent markers";
+        type = types.bool;
+      };
+
+      showHiddenFiles = mkOption {
+        default = true;
+        description = "Show hidden files";
+        type = types.bool;
+      };
+
+      trailingSlash = mkOption {
+        default = false;
+        description = "Add a trailing slash to all folders";
+        type = types.bool;
+      };
+
+      showParentFolder = mkOption {
+        default = false;
+        description = "Show parent folder";
+        type = types.bool;
+      };
+
+      groupEmptyFolders = mkOption {
+        default = false;
+        description = "Compact empty folders trees into a single item";
+        type = types.bool;
+      };
+
+      icons = {
+        show = {
+          file = mkOption {
+            default = true;
+            description = "Show file icons";
+            type = types.bool;
+          };
+          folder = mkOption {
+            default = true;
+            description = "Show folder icons";
+            type = types.bool;
+          };
+          folderArrow = mkOption {
+            default = true;
+            description = "Show folder arrow icons";
+            type = types.bool;
+          };
+          git = mkOption {
+            default = false;
+            description = "Show git icons";
+            type = types.bool;
+          };
+        };
+        glyphs = {
+          default = mkOption {
+            default = "";
+            description = "Default icon";
+            type = types.str;
+          };
+          symlink = mkOption {
+            default = "";
+            description = "Symlink icon";
+            type = types.str;
+          };
+
+          folder = {
+            default = mkOption {
+              default = "";
+              description = "Default folder icon";
+              type = types.str;
+            };
+            open = mkOption {
+              default = "";
+              description = "Open folder icon";
+              type = types.str;
+            };
+            empty = mkOption {
+              default = "";
+              description = "Empty folder icon";
+              type = types.str;
+            };
+            emptyOpen = mkOption {
+              default = "";
+              description = "Empty open folder icon";
+              type = types.str;
+            };
+            symlink = mkOption {
+              default = "";
+              description = "Symlink folder icon";
+              type = types.str;
+            };
+            symlinkOpen = mkOption {
+              default = "";
+              description = "Symlink open folder icon";
+              type = types.str;
+            };
+            arrowOpen = mkOption {
+              default = "";
+              description = "Open folder arrow icon";
+              type = types.str;
+            };
+            arrowClosed = mkOption {
+              default = "";
+              description = "Closed folder arrow icon";
+              type = types.str;
+            };
+          };
+
+          git = {
+            unstaged = mkOption {
+              default = "✗";
+              description = "Unstaged git icon";
+              type = types.str;
+            };
+            staged = mkOption {
+              default = "✓";
+              description = "Staged git icon";
+              type = types.str;
+            };
+            unmerged = mkOption {
+              default = "";
+              description = "Unmerged git icon";
+              type = types.str;
+            };
+            renamed = mkOption {
+              default = "➜";
+              description = "Renamed git icon";
+              type = types.str;
+            };
+            untracked = mkOption {
+              default = "★";
+              description = "Untracked git icon";
+              type = types.str;
+            };
+            deleted = mkOption {
+              default = "";
+              description = "Deleted git icon";
+              type = types.str;
+            };
+            ignored = mkOption {
+              default = "◌";
+              description = "Ignored git icon";
+              type = types.str;
+            };
+          };
+        };
+      };
+    };
+  };
+}