visuals: move nvim-cursorline to its own module; switch to setupOpts

modules/plugins/visuals/nvim-cursorline/config.nix

@@ -0,0 +1,21 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.lua) toLuaObject;
+  inherit (lib.nvim.dag) entryAnywhere;
+
+  cfg = config.vim.visuals.cursorline;
+in {
+  config = mkIf cfg.enable {
+    vim = {
+      startPlugins = ["nvim-cursorline"];
+
+      pluginRC.cursorline = entryAnywhere ''
+        require("nvim-cursorline").setup(${toLuaObject cfg.setupOpts})
+      '';
+    };
+  };
+}

modules/plugins/visuals/nvim-cursorline/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./config.nix
+    ./nvim-cursorline.nix
+  ];
+}

modules/plugins/visuals/nvim-cursorline/nvim-cursorline.nix

@@ -0,0 +1,49 @@
+{lib, ...}: let
+  inherit (lib.modules) mkRenamedOptionModule mkRemovedOptionModule;
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.types) int bool;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+in {
+  imports = [
+    (mkRenamedOptionModule ["vim" "visuals" "cursorline" "lineTimeout"] ["vim" "visuals" "cursorline" "setupOpts" "line_timeout"])
+    (mkRemovedOptionModule ["vim" "visuals" "cursorline" "lineNumbersOnly"] ''
+      `vim.visuals.cursorline.lineNumbersOnly` has been removed. Use `vim.visuals.cursorline.number` instead.
+    '')
+  ];
+
+  options.vim.visuals.cursorline = {
+    enable = mkEnableOption "cursor word and line highlighting [nvim-cursorline]";
+    setupOpts = mkPluginSetupOption "cursorline" {
+      cursorline = {
+        enable = mkEnableOption "cursor line highlighting";
+        timeout = mkOption {
+          type = int;
+          default = 1000;
+        };
+
+        number = mkOption {
+          type = bool;
+          default = false;
+        };
+      };
+
+      cursorword = {
+        enable = mkEnableOption "cursor word highlighting";
+        timeout = mkOption {
+          type = int;
+          default = 1000;
+        };
+
+        min_length = mkOption {
+          type = int;
+          default = 3;
+        };
+
+        hl.underline = mkOption {
+          type = bool;
+          default = true;
+        };
+      };
+    };
+  };
+}