languages/env: init

configuration.nix

@@ -80,6 +80,7 @@ isMaximal: {
       xml.enable = isMaximal;
       tex.enable = isMaximal;
       docker.enable = isMaximal;
+      env.enable = isMaximal;
 
       # Language modules that are not as common.
       openscad.enable = false;

docs/manual/release-notes/rl-0.9.md

@@ -410,6 +410,8 @@
 
 - Add `languages.gettext`. This only provides highlighting.
 
+- Add `languages.env`. This provides extra filetype hooks and diagnostics.
+
 - Add `languages.openscad` using
   [`openscad-lsp`](https://github.com/Leathong/openscad-LSP). This currently
   relies on neovim builtin syntax for highlighting, and the lsp for formatting

modules/plugins/languages/default.nix

@@ -7,6 +7,7 @@ in {
     ./asm.nix
     ./astro.nix
     ./bash.nix
+    ./env.nix
     ./cue.nix
     ./dart.nix
     ./clang.nix

modules/plugins/languages/env.nix

@@ -0,0 +1,70 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption literalExpression;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.types) diagnostics;
+
+  cfg = config.vim.languages.env;
+
+  defaultDiagnosticsProvider = ["dotenv-linter"];
+  diagnosticsProviders = {
+    dotenv-linter = let
+      pkg = pkgs.dotenv-linter;
+    in {
+      package = pkg;
+      config = {
+        cmd = getExe pkg;
+      };
+    };
+  };
+in {
+  options.vim.languages.env = {
+    enable = mkEnableOption "Env language support";
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra Env diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+          defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
+        };
+      types = diagnostics {
+        langDesc = "Env";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    {
+      vim.autocmds = [
+        {
+          event = ["BufRead" "BufNewFile"];
+          pattern = [
+            # support common names like `dist.env`
+            "*.env"
+            # support weird env files names like symfony ones.
+            ".env.*"
+          ];
+          command = "set filetype=env";
+        }
+      ];
+    }
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.env = cfg.extraDiagnostics.types;
+        linters =
+          mkMerge (map (name: {${name} = diagnosticsProviders.${name}.config;})
+            cfg.extraDiagnostics.types);
+      };
+    })
+  ]);
+}