From 51c2132543ca520b5142eb9ce1bc694c39161dfe Mon Sep 17 00:00:00 2001
From: Poseidon <softwaredevelopment.stingray177@passinbox.com>
Date: Tue, 16 Sep 2025 14:41:52 -0500
Subject: [PATCH] languages/dockerfile: init

Add dockerfile support using docker-language-server, dockerfmt, and
hadolint.
---
 configuration.nix                        |   1 +
 docs/manual/release-notes/rl-0.9.md      |   9 ++
 modules/plugins/languages/default.nix    |   1 +
 modules/plugins/languages/dockerfile.nix | 159 +++++++++++++++++++++++
 4 files changed, 170 insertions(+)
 create mode 100644 modules/plugins/languages/dockerfile.nix

diff --git a/configuration.nix b/configuration.nix
index b9e3b8ec..ffc1a334 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -92,6 +92,7 @@ isMaximal: {
       fsharp.enable = false;
       just.enable = false;
       qml.enable = false;
+      dockerfile.enable = true;
 
       tailwind.enable = false;
       svelte.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index c38d2421..161d4a1c 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -144,3 +144,12 @@
 [Machshev](https://github.com/machshev):
 
 - Added `ruff` and `ty` LSP support for Python under `programs.python`.
+
+[Poseidon](https://github.com/poseidon-rises):
+
+[docker-language-server]: https://github.com/docker/docker-language-server
+[dockerfmt]: https://github.com/reteps/dockerfmt
+[hadolint]: https://github.com/hadolint/hadolint
+
+- Add dockerfile support using [docker-language-server], [dockerfmt], and
+  [hadolint].
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 9b0d241b..d5997607 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -11,6 +11,7 @@ in {
     ./clang.nix
     ./clojure.nix
     ./css.nix
+    ./dockerfile.nix
     ./elixir.nix
     ./fsharp.nix
     ./gleam.nix
diff --git a/modules/plugins/languages/dockerfile.nix b/modules/plugins/languages/dockerfile.nix
new file mode 100644
index 00000000..84129692
--- /dev/null
+++ b/modules/plugins/languages/dockerfile.nix
@@ -0,0 +1,159 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum package listOf;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.dockerfile;
+
+  defaultServers = ["docker-language-server"];
+  servers = {
+    docker-language-server = {
+      cmd = [
+        (getExe pkgs.docker-language-server)
+        "start"
+        "--stdio"
+      ];
+      filetypes = [
+        "dockerfile"
+        "yaml.docker-compose"
+      ];
+      root_markers = [
+        "Dockerfile"
+        "docker-compose.yaml"
+        "docker-compose.yml"
+        "compose.yaml"
+        "compose.yml"
+        "docker-bake.json"
+        "docker-bake.hcl"
+      ];
+    };
+  };
+
+  defaultFormat = ["dockerfmt"];
+  formats = {
+    dockerfmt = {
+      package = pkgs.dockerfmt;
+    };
+  };
+
+  defaultDiagnosticsProvider = ["hadolint"];
+  diagnosticsProviders = {
+    hadolint = {
+      config.cmd = getExe (
+        pkgs.writeShellApplication {
+          name = "hadolint";
+          runtimeInputs = [pkgs.hadolint];
+          text = "hadolint -";
+        }
+      );
+    };
+  };
+in {
+  options.vim.languages.dockerfile = {
+    enable = mkEnableOption "Dockerfile language support";
+    treesitter = {
+      enable = mkEnableOption "Dockerfile treesitter support";
+      package = mkGrammarOption pkgs "dockerfile";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Dockerfile LSP support"
+        // {
+          default = config.vim.lsp.enable;
+        };
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Dockerfile LSP server to use";
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "Dockerfile formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+        };
+
+      type = mkOption {
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+        description = "Dockerfile formatter to use";
+      };
+
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "Dockerfile formatter package";
+      };
+    };
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra Dockerfile diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+        };
+
+      types = diagnostics {
+        langDesc = "Dockerfile";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts.formatters_by_ft.dockerfile = [cfg.format.type];
+        setupOpts.formatters =
+          mapListToAttrs (name: {
+            inherit name;
+            value = formats.${name};
+          })
+          cfg.format.type;
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.dockerfile = cfg.extraDiagnostics.types;
+        linters = mkMerge (
+          map (name: {
+            ${name} = diagnosticsProviders.${name}.config;
+          })
+          cfg.extraDiagnostics.types
+        );
+      };
+    })
+  ];
+}