From c4e3a0881272fb0fa5ce1fdbb33273b90d59da94 Mon Sep 17 00:00:00 2001
From: Snoweuph <snow@euph.email>
Date: Sat, 18 Apr 2026 01:13:31 +0200
Subject: [PATCH] languages/scss: init

---
 configuration.nix                     |   1 +
 docs/manual/release-notes/rl-0.9.md   |   4 +
 modules/plugins/languages/css.nix     |   1 -
 modules/plugins/languages/default.nix |   1 +
 modules/plugins/languages/scss.nix    | 143 ++++++++++++++++++++++++++
 5 files changed, 149 insertions(+), 1 deletion(-)
 create mode 100644 modules/plugins/languages/scss.nix

diff --git a/configuration.nix b/configuration.nix
index 5cabc67b..f09dbfa0 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -60,6 +60,7 @@ isMaximal: {
       clang.enable = isMaximal;
       cmake.enable = isMaximal;
       css.enable = isMaximal;
+      scss.enable = isMaximal;
       html.enable = isMaximal;
       json.enable = isMaximal;
       sql.enable = isMaximal;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 98a8fc45..77af9825 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -108,6 +108,10 @@
   `languages.go.treesitter.gotmplPackage` to
   {option}`vim.languages.go.treesitter.gotmpl.package`
 
+- Split SCSS from `languages.css` into `languages.scss` and add extra tools for
+  SCSS/SASS. This also changes the default LSP to `some-sass-language-server`
+  for SCSS/SASS.
+
 [CaueAnjos](https://github.com/caueanjos)
 
 - Renamed `roslyn_ls` to `roslyn-ls`
diff --git a/modules/plugins/languages/css.nix b/modules/plugins/languages/css.nix
index 045dd6d5..33e3494d 100644
--- a/modules/plugins/languages/css.nix
+++ b/modules/plugins/languages/css.nix
@@ -91,7 +91,6 @@ in {
           filetypes = [
             "css"
             # TODO: split in their own modules
-            "scss"
             "less"
           ];
         });
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 97149614..368287a7 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -13,6 +13,7 @@ in {
     ./clojure.nix
     ./cmake.nix
     ./css.nix
+    ./scss.nix
     ./elixir.nix
     ./elm.nix
     ./fsharp.nix
diff --git a/modules/plugins/languages/scss.nix b/modules/plugins/languages/scss.nix
new file mode 100644
index 00000000..7bdfb463
--- /dev/null
+++ b/modules/plugins/languages/scss.nix
@@ -0,0 +1,143 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption literalExpression;
+  inherit (lib) genAttrs;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum listOf;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.scss;
+
+  defaultServer = ["some-sass-language-server"];
+  servers = ["some-sass-language-server" "vscode-css-language-server"];
+
+  defaultFormat = ["prettier"];
+  formats = {
+    prettier = {
+      command = getExe pkgs.prettier;
+    };
+
+    prettierd = {
+      command = getExe pkgs.prettierd;
+    };
+  };
+
+  defaultDiagnosticsProvider = ["stylelint"];
+  diagnosticsProviders = {
+    stylelint = {
+      config = {
+        cmd = getExe pkgs.stylelint;
+      };
+    };
+  };
+in {
+  options.vim.languages.scss = {
+    enable = mkEnableOption "SCSS/SASS language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "SCSS/SASS treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+          defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        };
+      package = mkGrammarOption pkgs "scss";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "SCSS/SASS LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+
+      servers = mkOption {
+        type = listOf (enum servers);
+        default = defaultServer;
+        description = "SCSS/SASS LSP server to use";
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "SCSS/SASS formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+          defaultText = literalExpression "config.vim.languages.enableFormat";
+        };
+      type = mkOption {
+        description = "SCSS/SASS formatter to use";
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+      };
+    };
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra SCSS/SASS diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+          defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
+        };
+      types = diagnostics {
+        langDesc = "SCSS";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp = {
+        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
+        servers = genAttrs cfg.lsp.servers (_: {
+          filetypes = [
+            "scss"
+            "sass"
+          ];
+        });
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.scss = cfg.format.type;
+          formatters_by_ft.sass = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.scss = cfg.extraDiagnostics.types;
+        linters_by_ft.sass = cfg.extraDiagnostics.types;
+        linters =
+          mkMerge (map (name: {${name} = diagnosticsProviders.${name}.config;})
+            cfg.extraDiagnostics.types);
+      };
+    })
+  ]);
+}