Merge 43fb640c2a into 8b98f07862

configuration.nix

@@ -91,6 +91,7 @@ isMaximal: {
       fsharp.enable = false;
       just.enable = false;
       qml.enable = false;
+      fish.enable = false;
 
       tailwind.enable = false;
       svelte.enable = false;

docs/release-notes/rl-0.8.md

@@ -507,6 +507,8 @@
 [qmk-nvim]: https://github.com/codethread/qmk.nvim
 [qmlls]: https://doc.qt.io/qt-6/qtqml-tooling-qmlls.html
 [qmlformat]: https://doc.qt.io/qt-6/qtqml-tooling-qmlformat.html
+[fish-lsp]: https://www.fish-lsp.dev/
+[fish_indent]: https://fishshell.com/docs/current/cmds/fish_indent.html 
 
 - Add [nvim-biscuits] support under `vim.utility.nvim-biscuits`.
 - Add just support under `vim.languages.just` using [just-lsp].
@@ -516,6 +518,8 @@
   [htmlHINT].
 - Add QMK support under `vim.utility.qmk-nvim` via [qmk-nvim].
 - Add QML support under `vim.languages.qml` using [qmlls] and [qmlformat].
+- Add Fish support inder `vim.languages.fish` using [fish-lsp] and
+  [fish_indent].
 
 [Morsicus](https://github.com/Morsicus):
 

modules/plugins/languages/default.nix

@@ -12,6 +12,7 @@ in {
     ./clojure.nix
     ./css.nix
     ./elixir.nix
+    ./fish.nix
     ./fsharp.nix
     ./gleam.nix
     ./go.nix

modules/plugins/languages/fish.nix

@@ -0,0 +1,97 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum package;
+  inherit (lib.nvim.types) mkGrammarOption singleOrListOf;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.fish;
+
+  defaultServers = ["fish-lsp"];
+  servers = {
+    fish-lsp = {
+      cmd = [(getExe pkgs.fish-lsp) "start"];
+      filetypes = ["fish"];
+      root_markers = ["config.fish" ".git"];
+    };
+  };
+
+  defaultFormat = "fish_indent";
+  formats = {
+    fish_indent = {
+      package = pkgs.writeShellApplication {
+        name = "fish_indent";
+        runtimeInputs = [pkgs.fish];
+        text = "fish_indent";
+      };
+    };
+  };
+in {
+  options.vim.languages.fish = {
+    enable = mkEnableOption "Fish language support";
+    treesitter = {
+      enable = mkEnableOption "Fish treesitter support" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "fish";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Fish LSP support" // {default = config.vim.lsp.enable;};
+      servers = mkOption {
+        type = singleOrListOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Fish LSP server to use";
+      };
+    };
+
+    format = {
+      enable = mkEnableOption "Fish formatting" // {default = config.vim.languages.enableFormat;};
+
+      type = mkOption {
+        type = enum (attrNames formats);
+        default = defaultFormat;
+        description = "Fish formatter to use";
+      };
+
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "Fish formatter package";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+
+    (mkIf (cfg.format.enable && !cfg.lsp.enable) {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts.formatters_by_ft.fish = [cfg.format.type];
+        setupOpts.formatters.${cfg.format.type} = {
+          command = getExe cfg.format.package;
+        };
+      };
+    })
+  ]);
+}