From bacaa87608b1896b2a7ff335068f6d640b4117f0 Mon Sep 17 00:00:00 2001
From: poz <poz@poz.pet>
Date: Wed, 18 Feb 2026 11:51:48 +0100
Subject: [PATCH] languages/glsl: init

---
 configuration.nix                     |  1 +
 docs/manual/release-notes/rl-0.9.md   |  2 +
 modules/plugins/languages/default.nix |  1 +
 modules/plugins/languages/glsl.nix    | 63 +++++++++++++++++++++++++++
 4 files changed, 67 insertions(+)
 create mode 100644 modules/plugins/languages/glsl.nix

diff --git a/configuration.nix b/configuration.nix
index e52f667d..cb0a2385 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -86,6 +86,7 @@ isMaximal: {
       scala.enable = false;
       r.enable = false;
       gleam.enable = false;
+      glsl.enable = false;
       dart.enable = false;
       ocaml.enable = false;
       elixir.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 5594fbe0..c275b0d3 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -245,8 +245,10 @@ https://github.com/gorbit99/codewindow.nvim
 
 [neocmakelsp]: https://github.com/neocmakelsp/neocmakelsp
 [arduino-language-server]: https://github.com/arduino/arduino-language-server
+[glsl_analyzer]: https://github.com/nolanderc/glsl_analyzer
 
 - Add CMake support with [neocmakelsp].
 - Add Arduino support with [arduino-language-server].
+- Add GLSL support with [glsl_analyzer].
 
 <!-- vim: set textwidth=80: -->
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index e1cc8062..1cdead76 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -16,6 +16,7 @@ in {
     ./elixir.nix
     ./fsharp.nix
     ./gleam.nix
+    ./glsl.nix
     ./go.nix
     ./hcl.nix
     ./helm.nix
diff --git a/modules/plugins/languages/glsl.nix b/modules/plugins/languages/glsl.nix
new file mode 100644
index 00000000..b555b008
--- /dev/null
+++ b/modules/plugins/languages/glsl.nix
@@ -0,0 +1,63 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) enum listOf;
+  inherit (lib.meta) getExe;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.glsl;
+
+  defaultServers = ["glsl_analyzer"];
+  servers = {
+    glsl_analyzer = {
+      enable = true;
+      cmd = [(getExe pkgs.glsl_analyzer)];
+      filetypes = ["glsl" "vert" "tesc" "tese" "frag" "geom" "comp"];
+      root_markers = [".git"];
+    };
+  };
+in {
+  options.vim.languages.glsl = {
+    enable = mkEnableOption "GLSL language support";
+
+    treesitter = {
+      enable = mkEnableOption "GLSL treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "glsl";
+    };
+
+    lsp = {
+      enable = mkEnableOption "GLSL LSP support" // {default = config.vim.lsp.enable;};
+
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "GLSL LSP server to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+  ]);
+}