diff --git a/configuration.nix b/configuration.nix
index b21b26aa..e5b9c65a 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -51,6 +51,7 @@ isMaximal: {
       css.enable = isMaximal;
       sql.enable = isMaximal;
       java.enable = isMaximal;
+      kotlin.enable = isMaximal;
       ts.enable = isMaximal;
       svelte.enable = isMaximal;
       go.enable = isMaximal;
diff --git a/docs/release-notes/rl-0.7.md b/docs/release-notes/rl-0.7.md
index 817c8290..e1ca4272 100644
--- a/docs/release-notes/rl-0.7.md
+++ b/docs/release-notes/rl-0.7.md
@@ -208,3 +208,4 @@ everyone.
 - Add LSP and Treesitter support for R under `vim.languages.R`.
 - Add Otter support under `vim.lsp.otter` and an assert to prevent conflict with
   ccc
+- Add LSP and Treesitter support for Kotlin under `vim.languages.kotlin`
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 28c1fd8f..b46d992c 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -8,6 +8,7 @@ in {
     ./css.nix
     ./elixir.nix
     ./go.nix
+    ./kotlin.nix
     ./html.nix
     ./java.nix
     ./lua.nix
diff --git a/modules/plugins/languages/kotlin.nix b/modules/plugins/languages/kotlin.nix
new file mode 100644
index 00000000..f40ff209
--- /dev/null
+++ b/modules/plugins/languages/kotlin.nix
@@ -0,0 +1,75 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) package;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.lists) isList;
+  inherit (lib.nvim.lua) expToLua;
+
+  cfg = config.vim.languages.kotlin;
+
+  # Creating a version of the LSP with access to the kotlin binary.
+  # This is necessary for the LSP to load the standard library
+  kotlinLspWithRuntime = pkgs.symlinkJoin {
+    name = "kotlin-language-server-with-runtime";
+    paths = [
+      pkgs.kotlin-language-server
+      pkgs.kotlin
+    ];
+    buildInputs = [pkgs.makeWrapper];
+    postBuild = ''
+      wrapProgram $out/bin/kotlin-language-server \
+        --prefix PATH : ${pkgs.lib.makeBinPath [pkgs.kotlin]}
+    '';
+  };
+in {
+  options.vim.languages.kotlin = {
+    enable = mkEnableOption "kotlin/HCL support";
+
+    treesitter = {
+      enable = mkEnableOption "kotlin treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "kotlin";
+    };
+
+    lsp = {
+      enable = mkEnableOption "kotlin LSP support (kotlin_language_server)" // {default = config.vim.languages.enableLSP;};
+
+      package = mkOption {
+        description = "kotlin_language_server package with Kotlin runtime";
+        type = package;
+        default = kotlinLspWithRuntime;
+      };
+    };
+  };
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.kotlin_language_server = ''
+        lspconfig.kotlin_language_server.setup {
+          capabilities = capabilities,
+          root_dir = lspconfig.util.root_pattern("main.kt", ".git"),
+          on_attach=default_on_attach,
+          init_options = {
+          -- speeds up the startup time for the LSP
+            storagePath = "vim.fn.stdpath('state') .. '/kotlin'",
+          },
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else ''{"${cfg.lsp.package}/bin/kotlin-language-server"}''
+        },
+        }
+      '';
+    })
+  ]);
+}