neorg: init (#413)

* neorg: init

* neorg: setupOpts work

* neorg: disable by default

* neorg: added changelog entry

* neorg: setupOpts setup correctly

* neorg: sane default for setupOpts

* neorg: changed description and removed reduntant treesitter activation

* neorg: added vim.treesitter.enable

* neorg: fixing capitalisation

* neorg: adding descriptions

* neorg: formatting

* neorg: added newline at the end of docs

modules/plugins/notes/default.nix

@@ -2,6 +2,7 @@
   imports = [
     ./obsidian
     ./orgmode
+    ./neorg
     ./mind-nvim
     ./todo-comments
   ];

modules/plugins/notes/neorg/config.nix

@@ -0,0 +1,41 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.dag) entryAnywhere;
+  inherit (lib.nvim.binds) pushDownDefault;
+  inherit (lib.nvim.lua) toLuaObject;
+
+  cfg = config.vim.notes.neorg;
+in {
+  config = mkIf cfg.enable (mkMerge [
+    {
+      vim = {
+        startPlugins = [
+          "lua-utils-nvim"
+          "nui-nvim"
+          "nvim-nio"
+          "pathlib-nvim"
+          "plenary-nvim"
+          "neorg"
+          "neorg-telescope"
+        ];
+
+        binds.whichKey.register = pushDownDefault {
+          "<leader>o" = "+Notes";
+        };
+
+        pluginRC.neorg = entryAnywhere ''
+          require('neorg').setup(${toLuaObject cfg.setupOpts})
+        '';
+      };
+    }
+
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.norgPackage];
+    })
+  ]);
+}

modules/plugins/notes/neorg/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./neorg.nix
+    ./config.nix
+  ];
+}

modules/plugins/notes/neorg/neorg.nix

@@ -0,0 +1,50 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) submodule listOf str;
+  inherit (lib.nvim.types) mkGrammarOption mkPluginSetupOption;
+in {
+  options.vim.notes.neorg = {
+    enable = mkEnableOption ''
+      Neorg: An intuitive note-taking and organization tool with a structured nested syntax.
+    '';
+
+    setupOpts = mkPluginSetupOption "Neorg" {
+      load = {
+        "core.defaults" = mkOption {
+          default = {};
+          description = ''
+            all of the most important modules that any user would want to have a "just works" experience
+          '';
+
+          type = submodule {
+            options = {
+              enable = mkEnableOption ''
+                all of the most important modules that any user would want to have a "just works" experience
+              '';
+              config = {
+                disable = mkOption {
+                  description = ''
+                    list of modules from to be disabled from core.defaults
+                  '';
+                  type = listOf str;
+                  default = [];
+                  example = ["core.autocommands" "core.itero"];
+                };
+              };
+            };
+          };
+        };
+      };
+    };
+
+    treesitter = {
+      enable = mkEnableOption "Neorg treesitter" // {default = config.vim.languages.enableTreesitter;};
+      norgPackage = mkGrammarOption pkgs "norg";
+    };
+  };
+}