languages/clojure: init

docs/release-notes/rl-0.8.md

@@ -407,3 +407,10 @@
 - Add [img-clip.nvim] plugin in `vim.utility.images.img-clip` with `enable` and
   `setupOpts`
 - Add `vim.utility.images.img-clip.enable = isMaximal` in configuration.nix
+
+[anil9](https://github.com/anil9):
+
+[clojure-lsp]: https://github.com/clojure-lsp/clojure-lsp
+[conjure]: https://github.com/Olical/conjure
+
+- Add Clojure support under `vim.languages.clojure` using [clojure-lsp] and [conjure].

modules/plugins/languages/clojure.nix

@@ -0,0 +1,56 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.meta) getExe;
+  inherit (lib.lists) isList;
+  inherit (lib.types) either listOf package str;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.lua) expToLua;
+
+  cfg = config.vim.languages.clojure;
+in {
+  options.vim.languages.clojure = {
+    enable = mkEnableOption "Clojure language support";
+
+    treesitter = {
+      enable = mkEnableOption "Clojure treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "clojure";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Clojure LSP support" // {default = config.vim.lsp.enable;};
+      package = mkOption {
+        description = "Clojure LSP";
+        type = either package (listOf str);
+        default = pkgs.clojure-lsp;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.clojure-lsp = ''
+        lspconfig.clojure_lsp.setup {
+          capabilities = capabilities;
+          on_attach = default_on_attach;
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else ''{"${getExe cfg.lsp.package}"}''
+        };
+        }
+      '';
+    })
+
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+  ]);
+}

modules/plugins/languages/default.nix

@@ -9,6 +9,7 @@ in {
     ./cue.nix
     ./dart.nix
     ./clang.nix
+    ./clojure.nix
     ./css.nix
     ./elixir.nix
     ./fsharp.nix