language/xml: syntax highlighting, formatting, lsp

configuration.nix

@@ -72,6 +72,7 @@ isMaximal: {
         extensions.crates-nvim.enable = isMaximal;
       };
       toml.enable = isMaximal;
+      xml.enable = isMaximal;
 
       # Language modules that are not as common.
       assembly.enable = false;

docs/manual/release-notes/rl-0.9.md

@@ -151,6 +151,8 @@
 - Added [Selenen](https://github.com/kampfkarren/selene) for more diagnostics in
   `languages.lua`.
 
+- Added XML syntax highlighting, LSP support and formatting
+
 [vagahbond](https://github.com/vagahbond): [codewindow.nvim]:
 https://github.com/gorbit99/codewindow.nvim
 

modules/plugins/languages/default.nix

@@ -50,6 +50,7 @@ in {
     ./yaml.nix
     ./ruby.nix
     ./just.nix
+    ./xml.nix
 
     # This is now a hard deprecation.
     (mkRenamedOptionModule ["vim" "languages" "enableLSP"] ["vim" "lsp" "enable"])

modules/plugins/languages/xml.nix

@@ -0,0 +1,62 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum listOf;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.xml;
+
+  defaultServers = ["lemminx"];
+  servers = {
+    lemminx = {
+      enable = true;
+      cmd = [
+        (getExe pkgs.lemminx)
+      ];
+      filetypes = ["xml"];
+      root_markers = [".git"];
+    };
+  };
+in {
+  options.vim.languages.xml = {
+    enable = mkEnableOption "XML language support";
+
+    treesitter = {
+      enable = mkEnableOption "XML treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "xml";
+    };
+
+    lsp = {
+      enable = mkEnableOption "XML LSP support" // {default = config.vim.lsp.enable;};
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "XML LSP server to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (name: {
+          inherit name;
+          value = servers.${name};
+        })
+        cfg.lsp.servers;
+    })
+  ]);
+}