treewide: begin restructuring the module tree

modules/plugins/ui/breadcrumbs/breadcrumbs.nix

@@ -0,0 +1,363 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.types) nullOr listOf enum bool str int;
+  inherit (lib.modules) mkRenamedOptionModule;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+  mkSimpleIconOption = default:
+    mkOption {
+      inherit default;
+      type = str;
+      description = "";
+    };
+in {
+  imports = let
+    renameSetupOpt = oldPath: newPath:
+      mkRenamedOptionModule
+      (["vim" "ui" "breadcrumbs" "navbuddy"] ++ oldPath)
+      (["vim" "ui" "breadcrumbs" "navbuddy" "setupOpts"] ++ newPath);
+  in [
+    (renameSetupOpt ["useDefaultMappings"] ["use_default_mappings"])
+    (renameSetupOpt ["window"] ["window"])
+    (renameSetupOpt ["nodeMarkers"] ["node_markers"])
+    (renameSetupOpt ["lsp" "autoAttach"] ["lsp" "auto_attach"])
+    (renameSetupOpt ["lsp" "preference"] ["lsp" "preference"])
+    (renameSetupOpt ["sourceBuffer" "followNode"] ["source_buffer" "follow_node"])
+    (renameSetupOpt ["sourceBuffer" "highlight"] ["source_buffer" "highlight"])
+    (renameSetupOpt ["sourceBuffer" "reorient"] ["source_buffer" "reorient"])
+    (renameSetupOpt ["sourceBuffer" "scrolloff"] ["source_buffer" "scrolloff"])
+    # TODO: every option under icon is renamed to first letter capitalized
+    (renameSetupOpt ["icon"] ["icon"])
+  ];
+
+  options.vim.ui.breadcrumbs = {
+    enable = mkEnableOption "breadcrumbs";
+    source = mkOption {
+      type = nullOr (enum ["nvim-navic"]); # TODO: lspsaga and dropbar
+      default = "nvim-navic";
+      description = ''
+        The source to be used for breadcrumbs component. Null means no breadcrumbs.
+      '';
+    };
+
+    # maybe this should be an option to *disable* alwaysRender optionally but oh well
+    # too late
+    alwaysRender = mkOption {
+      type = bool;
+      default = true;
+      description = "Whether to always display the breadcrumbs component on winbar (always renders winbar)";
+    };
+
+    navbuddy = {
+      enable = mkEnableOption "navbuddy LSP helper UI. Enabling this option automatically loads and enables nvim-navic";
+
+      mappings = {
+        close = mkOption {
+          type = str;
+          default = "<esc>";
+          description = "keybinding to close Navbuddy UI";
+        };
+
+        nextSibling = mkOption {
+          type = str;
+          default = "j";
+          description = "keybinding to navigate to the next sibling node";
+        };
+
+        previousSibling = mkOption {
+          type = str;
+          default = "k";
+          description = "keybinding to navigate to the previous sibling node";
+        };
+
+        parent = mkOption {
+          type = str;
+          default = "h";
+          description = "keybinding to navigate to the parent node";
+        };
+
+        children = mkOption {
+          type = str;
+          default = "l";
+          description = "keybinding to navigate to the child node";
+        };
+
+        root = mkOption {
+          type = str;
+          default = "0";
+          description = "keybinding to navigate to the root node";
+        };
+
+        visualName = mkOption {
+          type = str;
+          default = "v";
+          description = "visual selection of name";
+        };
+
+        visualScope = mkOption {
+          type = str;
+          default = "V";
+          description = "visual selection of scope";
+        };
+
+        yankName = mkOption {
+          type = str;
+          default = "y";
+          description = "yank the name to system clipboard";
+        };
+
+        yankScope = mkOption {
+          type = str;
+          default = "Y";
+          description = "yank the scope to system clipboard";
+        };
+
+        insertName = mkOption {
+          type = str;
+          default = "i";
+          description = "insert at start of name";
+        };
+
+        insertScope = mkOption {
+          type = str;
+          default = "I";
+          description = "insert at start of scope";
+        };
+
+        appendName = mkOption {
+          type = str;
+          default = "a";
+          description = "insert at end of name";
+        };
+
+        appendScope = mkOption {
+          type = str;
+          default = "A";
+          description = "insert at end of scope";
+        };
+
+        rename = mkOption {
+          type = str;
+          default = "r";
+          description = "rename the node";
+        };
+
+        delete = mkOption {
+          type = str;
+          default = "d";
+          description = "delete the node";
+        };
+
+        foldCreate = mkOption {
+          type = str;
+          default = "f";
+          description = "create a new fold";
+        };
+
+        foldDelete = mkOption {
+          type = str;
+          default = "F";
+          description = "delete the current fold";
+        };
+
+        comment = mkOption {
+          type = str;
+          default = "c";
+          description = "comment the node";
+        };
+
+        select = mkOption {
+          type = str;
+          default = "<enter>";
+          description = "goto selected symbol";
+        };
+
+        moveDown = mkOption {
+          type = str;
+          default = "J";
+          description = "move focused node down";
+        };
+
+        moveUp = mkOption {
+          type = str;
+          default = "K";
+          description = "move focused node up";
+        };
+
+        telescope = mkOption {
+          type = str;
+          default = "t";
+          description = "fuzzy finder at current level";
+        };
+
+        help = mkOption {
+          type = str;
+          default = "g?";
+          description = "open mapping help window";
+        };
+      };
+
+      setupOpts = mkPluginSetupOption "navbuddy" {
+        useDefaultMappings = mkOption {
+          type = bool;
+          default = true;
+          description = "use default Navbuddy keybindings (disables user-specified keybinds)";
+        };
+
+        window = {
+          # size = {}
+          # position = {}
+
+          border = mkOption {
+            # TODO: let this type accept a custom string
+            type = enum ["single" "rounded" "double" "solid" "none"];
+            default = config.vim.ui.borders.globalStyle;
+            description = "border style to use";
+          };
+
+          scrolloff = mkOption {
+            type = nullOr int;
+            default = null;
+            description = "Scrolloff value within navbuddy window";
+          };
+
+          sections = {
+            # left section
+            left = {
+              /*
+              size = mkOption {
+                type = nullOr (intBetween 0 100);
+                default = null;
+                description = "size of the left section of Navbuddy UI in percentage (0-100)";
+              };
+              */
+
+              border = mkOption {
+                # TODO: let this type accept a custom string
+                type = nullOr (enum ["single" "rounded" "double" "solid" "none"]);
+                default = config.vim.ui.borders.globalStyle;
+                description = "border style to use for the left section of Navbuddy UI";
+              };
+            };
+
+            # middle section
+            mid = {
+              /*
+              size = {
+                type = nullOr (intBetween 0 100);
+                default = null;
+                description = "size of the left section of Navbuddy UI in percentage (0-100)";
+              };
+              */
+
+              border = mkOption {
+                # TODO: let this type accept a custom string
+                type = nullOr (enum ["single" "rounded" "double" "solid" "none"]);
+                default = config.vim.ui.borders.globalStyle;
+                description = "border style to use for the middle section of Navbuddy UI";
+              };
+            };
+
+            # right section
+            # there is no size option for the right section, it fills the remaining space
+            right = {
+              border = mkOption {
+                # TODO: let this type accept a custom string
+                type = nullOr (enum ["single" "rounded" "double" "solid" "none"]);
+                default = config.vim.ui.borders.globalStyle;
+                description = "border style to use for the right section of Navbuddy UI";
+              };
+
+              preview = mkOption {
+                type = enum ["leaf" "always" "never"];
+                default = "leaf";
+                description = "display mode of the preview on the right section";
+              };
+            };
+          };
+        };
+
+        node_markers = {
+          enable = mkEnableOption "node markers";
+          icons = {
+            leaf = mkSimpleIconOption "  ";
+            leaf_selected = mkSimpleIconOption " → ";
+            branch = mkSimpleIconOption " ";
+          };
+        };
+
+        lsp = {
+          auto_attach = mkOption {
+            type = bool;
+            default = true;
+            description = "Whether to attach to LSP server manually";
+          };
+
+          preference = mkOption {
+            type = nullOr (listOf str);
+            default = null;
+            description = "list of lsp server names in order of preference";
+          };
+        };
+
+        source_buffer = {
+          followNode = mkOption {
+            type = bool;
+            default = true;
+            description = "keep the current node in focus on the source buffer";
+          };
+
+          highlight = mkOption {
+            type = bool;
+            default = true;
+            description = "highlight the currently focused node";
+          };
+
+          reorient = mkOption {
+            type = enum ["smart" "top" "mid" "none"];
+            default = "smart";
+            description = "reorient buffer after changing nodes";
+          };
+
+          scrolloff = mkOption {
+            type = nullOr int;
+            default = null;
+            description = "scrolloff value when navbuddy is open";
+          };
+        };
+
+        icons = {
+          File = mkSimpleIconOption "󰈙 ";
+          Module = mkSimpleIconOption " ";
+          Namespace = mkSimpleIconOption "󰌗 ";
+          Package = mkSimpleIconOption " ";
+          Class = mkSimpleIconOption "󰌗 ";
+          Property = mkSimpleIconOption " ";
+          Field = mkSimpleIconOption " ";
+          Constructor = mkSimpleIconOption " ";
+          Enum = mkSimpleIconOption "󰕘";
+          Interface = mkSimpleIconOption "󰕘";
+          Function = mkSimpleIconOption "󰊕 ";
+          Variable = mkSimpleIconOption "󰆧 ";
+          Constant = mkSimpleIconOption "󰏿 ";
+          String = mkSimpleIconOption " ";
+          Number = mkSimpleIconOption "󰎠 ";
+          Boolean = mkSimpleIconOption "◩ ";
+          Array = mkSimpleIconOption "󰅪 ";
+          Object = mkSimpleIconOption "󰅩 ";
+          Method = mkSimpleIconOption "󰆧 ";
+          Key = mkSimpleIconOption "󰌋 ";
+          Null = mkSimpleIconOption "󰟢 ";
+          EnumMember = mkSimpleIconOption "󰕘 ";
+          Struct = mkSimpleIconOption "󰌗 ";
+          Event = mkSimpleIconOption " ";
+          Operator = mkSimpleIconOption "󰆕 ";
+          TypeParameter = mkSimpleIconOption "󰊄 ";
+        };
+      };
+    };
+  };
+}

modules/plugins/ui/breadcrumbs/config.nix

@@ -0,0 +1,97 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.strings) optionalString;
+  inherit (lib.modules) mkIf;
+  inherit (lib.lists) optionals;
+  inherit (lib.nvim.dag) entryAfter;
+  inherit (lib.nvim.lua) toLuaObject;
+  inherit (lib.generators) mkLuaInline;
+
+  cfg = config.vim.ui.breadcrumbs;
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins =
+      [
+        "nvim-lspconfig"
+      ]
+      ++ optionals (cfg.source == "nvim-navic") [
+        "nvim-navic"
+      ]
+      ++ optionals (config.vim.lsp.lspsaga.enable && cfg.source == "lspsaga") [
+        "lspsaga"
+      ]
+      ++ optionals cfg.navbuddy.enable [
+        "nvim-navbuddy"
+        "nui-nvim"
+        "nvim-navic"
+      ];
+
+    vim.ui.breadcrumbs.navbuddy.setupOpts = {
+      mappings = {
+        ${cfg.navbuddy.mappings.close} = mkLuaInline "actions.close()";
+        ${cfg.navbuddy.mappings.nextSibling} = mkLuaInline "actions.next_sibling()";
+        ${cfg.navbuddy.mappings.previousSibling} = mkLuaInline "actions.previous_sibling()";
+        ${cfg.navbuddy.mappings.parent} = mkLuaInline "actions.parent()";
+        ${cfg.navbuddy.mappings.children} = mkLuaInline "actions.children()";
+        ${cfg.navbuddy.mappings.root} = mkLuaInline "actions.root()";
+
+        ${cfg.navbuddy.mappings.visualName} = mkLuaInline "actions.visual_name()";
+        ${cfg.navbuddy.mappings.visualScope} = mkLuaInline "actions.visual_scope()";
+
+        ${cfg.navbuddy.mappings.yankName} = mkLuaInline "actions.yank_name()";
+        ${cfg.navbuddy.mappings.yankScope} = mkLuaInline "actions.yank_scope()";
+
+        ${cfg.navbuddy.mappings.insertName} = mkLuaInline "actions.insert_name()";
+        ${cfg.navbuddy.mappings.insertScope} = mkLuaInline "actions.insert_scope()";
+
+        ${cfg.navbuddy.mappings.appendName} = mkLuaInline "actions.append_name()";
+        ${cfg.navbuddy.mappings.appendScope} = mkLuaInline "actions.append_scope()";
+
+        ${cfg.navbuddy.mappings.rename} = mkLuaInline "actions.rename()";
+
+        ${cfg.navbuddy.mappings.delete} = mkLuaInline "actions.delete()";
+
+        ${cfg.navbuddy.mappings.foldCreate} = mkLuaInline "actions.fold_create()";
+        ${cfg.navbuddy.mappings.foldDelete} = mkLuaInline "actions.fold_delete()";
+
+        ${cfg.navbuddy.mappings.comment} = mkLuaInline "actions.comment()";
+
+        ${cfg.navbuddy.mappings.select} = mkLuaInline "actions.select()";
+
+        ${cfg.navbuddy.mappings.moveDown} = mkLuaInline "actions.move_down()";
+        ${cfg.navbuddy.mappings.moveUp} = mkLuaInline "actions.move_up()";
+
+        ${cfg.navbuddy.mappings.telescope} = mkLuaInline ''
+          actions.telescope({
+            layout_strategy = "horizontal",
+            layout_config = {
+              height = 0.60,
+              width = 0.75,
+              prompt_position = "top",
+              preview_width = 0.50
+            },
+          })'';
+        ${cfg.navbuddy.mappings.help} = mkLuaInline "actions.help()";
+      };
+    };
+
+    vim.luaConfigRC.breadcrumbs = entryAfter ["lspconfig"] ''
+
+      ${optionalString (cfg.source == "nvim-navic") ''
+        local navic = require("nvim-navic")
+        require("nvim-navic").setup {
+          highlight = true
+        }
+      ''}
+
+      ${optionalString cfg.navbuddy.enable ''
+        local navbuddy = require("nvim-navbuddy")
+        local actions = require("nvim-navbuddy.actions")
+        navbuddy.setup ${toLuaObject cfg.navbuddy.setupOpts}
+      ''}
+    '';
+  };
+}

modules/plugins/ui/breadcrumbs/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./config.nix
+    ./breadcrumbs.nix
+  ];
+}