plugins/lsp: add code-actions module; add fastaction.nvim

modules/plugins/lsp/code-actions/default.nix

@@ -0,0 +1,10 @@
+{lib, ...}: let
+  inherit (lib.options) mkEnableOption;
+in {
+  imports = [
+    ./fastaction-nvim
+  ];
+  options.vim.lsp.code-actions = {
+    enable = mkEnableOption "code-actions. Setting this to `false` will disable all code action plugins.";
+  };
+}

modules/plugins/lsp/code-actions/fastaction-nvim/config.nix

@@ -0,0 +1,34 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.dag) entryAnywhere;
+  inherit (lib.nvim.lua) toLuaObject;
+  inherit (lib.nvim.binds) addDescriptionsToMappings mkSetLuaBinding;
+
+  cfg = config.vim.lsp.code-actions;
+  self = import ./fastaction-nvim.nix {inherit lib;};
+
+  mappingDefinitions = self.options.vim.lsp.code-actions.fastaction-nvim.mappings;
+  mappings = addDescriptionsToMappings cfg.fastaction-nvim.mappings mappingDefinitions;
+in {
+  config = mkIf (cfg.enable && cfg.fastaction-nvim.enable) {
+    vim = {
+      startPlugins = ["fastaction-nvim"];
+
+      maps = {
+        normal = mkMerge [
+          (mkSetLuaBinding mappings.code_action "require('fastaction').code_action")
+          (mkSetLuaBinding mappings.range_action "require('fastaction').range_code_action")
+        ];
+      };
+
+      pluginRC.fastaction-nvim = entryAnywhere ''
+        -- Enable trouble diagnostics viewer
+        require('fastaction').setup(${toLuaObject cfg.fastaction-nvim.setupOpts})
+      '';
+    };
+  };
+}

modules/plugins/lsp/code-actions/fastaction-nvim/fastaction-nvim.nix

@@ -0,0 +1,15 @@
+{lib, ...}: let
+  inherit (lib.options) mkEnableOption;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+  inherit (lib.nvim.binds) mkMappingOption;
+in {
+  options.vim.lsp.code-actions.fastaction-nvim = {
+    enable = mkEnableOption "code actions for Neovim via fastaction.nvim";
+    setupOpts = mkPluginSetupOption "fastaction-nvim" {};
+
+    mappings = {
+      code_action = mkMappingOption "Displays code action popup [Fastaction.nvim]" "<leader>cfa";
+      range_action = mkMappingOption " Displays code actions for visual range [Fastaction.nvim]" "<leader>cra";
+    };
+  };
+}

modules/plugins/lsp/default.nix

@@ -10,12 +10,14 @@
 
     # lsp plugins
     ./lspsaga
-    ./nvim-code-action-menu
     ./trouble
     ./lsp-signature
     ./lightbulb
     ./lspkind
     ./lsplines
     ./nvim-docs-view
+
+    # Code Actions
+    ./code-actions
   ];
 }