diff --git a/configuration.nix b/configuration.nix
index cc314288..59bfb47a 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -75,6 +75,7 @@ isMaximal: {
       # Language modules that are not as common.
       assembly.enable = false;
       astro.enable = false;
+      beancount.enable = false;
       nu.enable = false;
       csharp.enable = false;
       julia.enable = false;
diff --git a/docs/manual/release-notes/rl-0.8.md b/docs/manual/release-notes/rl-0.8.md
index 62f42638..7a87248f 100644
--- a/docs/manual/release-notes/rl-0.8.md
+++ b/docs/manual/release-notes/rl-0.8.md
@@ -560,8 +560,11 @@
 [gmvar](https://github.com/gmvar):
 
 [harper-ls]: https://github.com/Automattic/harper
+[beancount-language-server]: https://github.com/polarmutex/beancount-language-server
+[bean-format]: https://github.com/beancount/beancount
 
 - Add [harper-ls] to the `vim.lsp` module.
+- Add beancount support under `vim.languages.beancount` using [beancount-language-server] and [bean-format].
 
 [derethil](https://github.com/derethil):
 
diff --git a/modules/plugins/languages/beancount.nix b/modules/plugins/languages/beancount.nix
new file mode 100644
index 00000000..ac5d72df
--- /dev/null
+++ b/modules/plugins/languages/beancount.nix
@@ -0,0 +1,120 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.meta) getExe getExe';
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum package;
+  inherit (lib.nvim.types) mkGrammarOption deprecatedSingleOrListOf;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.beancount;
+
+  defaultServers = [ "beancount-language-server" ];
+  servers = {
+    beancount-language-server = {
+      rootmarkers = [ ".git" ];
+      filetypes = [
+        "beancount"
+        "bean"
+      ];
+      cmd = [
+        # Wrap the language server to ensure 'bean-check' and 'bean-format'
+        # from 'pkgs.beancount' are in the PATH when the server runs.
+        (getExe (
+          pkgs.symlinkJoin {
+            name = "beancount-language-server-wrapped";
+            paths = [ pkgs.beancount-language-server ];
+            meta.mainProgram = "beancount-language-server";
+            buildInputs = [ pkgs.makeBinaryWrapper ];
+            postBuild = ''
+              wrapProgram $out/bin/beancount-language-server \
+                --suffix PATH : ${pkgs.beancount}/bin
+                # suffix add to path to allow users beancount in PATH to take precedence.
+            '';
+          }
+        ))
+      ];
+    };
+  };
+
+  defaultFormat = "bean-format";
+  formats = {
+    bean-format = {
+      package = pkgs.beancount;
+    };
+  };
+in
+{
+  options.vim.languages.beancount = {
+    enable = mkEnableOption "Beancount language support";
+
+    treesitter = {
+      enable = mkEnableOption "Beancount treesitter support" // {
+        default = config.vim.languages.enableTreesitter;
+      };
+      package = mkGrammarOption pkgs "beancount";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Beancount LSP support" // {
+        default = config.vim.lsp.enable;
+      };
+
+      servers = mkOption {
+        type = deprecatedSingleOrListOf "vim.languages.beancount.lsp.servers" (enum (attrNames servers));
+        default = defaultServers;
+        description = "Beancount LSP server to use.";
+      };
+    };
+
+    format = {
+      enable = mkEnableOption "Beancount formatting" // {
+        default = config.vim.languages.enableFormat;
+      };
+
+      type = mkOption {
+        type = enum (attrNames formats);
+        default = defaultFormat;
+        description = "Beancount formatter to use";
+      };
+
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "Beancount formatter package";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [ cfg.treesitter.package ];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers = mapListToAttrs (n: {
+        name = n;
+        value = servers.${n};
+      }) cfg.lsp.servers;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.beancount = [ cfg.format.type ];
+          formatters.${cfg.format.type} = {
+            command = getExe' cfg.format.package cfg.format.type;
+          };
+        };
+      };
+    })
+  ]);
+}
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index fd45758f..cb2af59e 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -6,6 +6,7 @@ in {
     ./asm.nix
     ./astro.nix
     ./bash.nix
+    ./beancount.nix
     ./cue.nix
     ./dart.nix
     ./clang.nix