From 54afb6211cc3a3b67e9bab3369e04197cc6ced95 Mon Sep 17 00:00:00 2001
From: poz <poz@poz.pet>
Date: Wed, 18 Feb 2026 11:50:05 +0100
Subject: [PATCH] languages/arduino: init

---
 configuration.nix                     |  1 +
 docs/manual/release-notes/rl-0.9.md   |  2 +
 modules/plugins/languages/arduino.nix | 95 +++++++++++++++++++++++++++
 modules/plugins/languages/default.nix |  1 +
 4 files changed, 99 insertions(+)
 create mode 100644 modules/plugins/languages/arduino.nix

diff --git a/configuration.nix b/configuration.nix
index fd006949..e52f667d 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -76,6 +76,7 @@ isMaximal: {
       xml.enable = isMaximal;
 
       # Language modules that are not as common.
+      arduino.enable = false;
       assembly.enable = false;
       astro.enable = false;
       nu.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 83296c2b..5594fbe0 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -244,7 +244,9 @@ https://github.com/gorbit99/codewindow.nvim
 [poz](https://poz.pet):
 
 [neocmakelsp]: https://github.com/neocmakelsp/neocmakelsp
+[arduino-language-server]: https://github.com/arduino/arduino-language-server
 
 - Add CMake support with [neocmakelsp].
+- Add Arduino support with [arduino-language-server].
 
 <!-- vim: set textwidth=80: -->
diff --git a/modules/plugins/languages/arduino.nix b/modules/plugins/languages/arduino.nix
new file mode 100644
index 00000000..b22c6d9d
--- /dev/null
+++ b/modules/plugins/languages/arduino.nix
@@ -0,0 +1,95 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.generators) mkLuaInline;
+  inherit (lib.meta) getExe getExe';
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) enum listOf str;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.arduino;
+
+  defaultServers = ["arduino-language-server"];
+  servers = {
+    arduino-language-server = {
+      enable = true;
+      cmd =
+        [
+          (getExe pkgs.arduino-language-server)
+          "-clangd"
+          (getExe' pkgs.clang-tools "clangd")
+          "-cli"
+          (getExe pkgs.arduino-cli)
+          "-cli-config"
+          "$HOME/.arduino15/arduino-cli.yaml"
+        ]
+        ++ cfg.lsp.extraArgs;
+      filetypes = ["arduino"];
+      root_dir =
+        mkLuaInline
+        /*
+        lua
+        */
+        ''
+          function(bufnr, on_dir)
+            local fname = vim.api.nvim_buf_get_name(bufnr)
+            on_dir(util.root_pattern("*.ino")(fname))
+          end
+        '';
+      capabilities = {
+        textDocument = {
+          semanticTokens = mkLuaInline "vim.NIL";
+        };
+        workspace = {
+          semanticTokens = mkLuaInline "vim.NIL";
+        };
+      };
+    };
+  };
+in {
+  options.vim.languages.arduino = {
+    enable = mkEnableOption "Arduino support";
+
+    treesitter = {
+      enable = mkEnableOption "Arduino treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "arduino";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Arduino LSP support" // {default = config.vim.lsp.enable;};
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Arduino LSP servers to use";
+      };
+
+      extraArgs = mkOption {
+        type = listOf str;
+        default = [];
+        description = "Extra arguments passed to the Arduino LSP";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+  ]);
+}
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index fe608513..e1cc8062 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -3,6 +3,7 @@
   inherit (lib.nvim.languages) mkEnable;
 in {
   imports = [
+    ./arduino.nix
     ./asm.nix
     ./astro.nix
     ./bash.nix