Merge branch 'v0.7' into typos-and-friends

modules/plugins/languages/default.nix

@@ -9,6 +9,7 @@ in {
     ./css.nix
     ./elixir.nix
     ./go.nix
+    ./hcl.nix
     ./kotlin.nix
     ./html.nix
     ./java.nix
@@ -32,6 +33,7 @@ in {
     ./zig.nix
     ./csharp.nix
     ./julia.nix
+    ./nu.nix
   ];
 
   options.vim.languages = {

modules/plugins/languages/hcl.nix

@@ -0,0 +1,117 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) package bool enum;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.hcl;
+
+  defaultServer = "terraform-ls";
+  servers = {
+    terraform-ls = {
+      package = pkgs.terraform-ls;
+      lspConfig = ''
+        lspconfig.terraformls.setup {
+          capabilities = capabilities,
+          on_attach=default_on_attach,
+          cmd = {"${lib.getExe cfg.lsp.package}", "serve"},
+        }
+      '';
+    };
+  };
+
+  defaultFormat = "hclfmt";
+  formats = {
+    hclfmt = {
+      package = pkgs.hclfmt;
+      nullConfig = ''
+        table.insert(
+          ls_sources,
+          null_ls.builtins.formatting.hclfmt.with({
+            command = "${lib.getExe cfg.format.package}",
+          })
+        )
+      '';
+    };
+  };
+in {
+  options.vim.languages.hcl = {
+    enable = mkEnableOption "HCL support";
+
+    treesitter = {
+      enable = mkEnableOption "HCL treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "hcl";
+    };
+
+    lsp = {
+      enable = mkEnableOption "HCL LSP support (terraform-ls)" // {default = config.vim.languages.enableLSP;};
+      # TODO: (maybe, is it better?) it would be cooler to use vscode-extensions.hashicorp.hcl probably, shouldn't be too hard
+      package = mkOption {
+        type = package;
+        default = servers.${defaultServer}.package;
+        description = "HCL language server package (terraform-ls)";
+      };
+    };
+
+    format = {
+      enable = mkOption {
+        type = bool;
+        default = config.vim.languages.enableFormat;
+        description = "Enable HCL formatting";
+      };
+      type = mkOption {
+        type = enum (attrNames formats);
+        default = defaultFormat;
+        description = "HCL formatter to use";
+      };
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "HCL formatter package";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    {
+      # hcl style official: https://developer.hashicorp.com/terraform/language/style#code-formatting
+      vim.pluginRC.hcl = ''
+        vim.api.nvim_create_autocmd("FileType", {
+          pattern = "hcl",
+          callback = function(opts)
+            local bo = vim.bo[opts.buf]
+            bo.tabstop = 2
+            bo.shiftwidth = 2
+            bo.softtabstop = 2
+          end
+        })
+
+        local ft = require('Comment.ft')
+        ft
+          .set('hcl', '#%s')
+      '';
+    }
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources = lib.optionalAttrs (! config.vim.languages.terraform.lsp.enable) {
+        terraform-ls = servers.${cfg.lsp.server}.lspConfig;
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.lsp.null-ls.enable = true;
+      vim.lsp.null-ls.sources.hcl-format = formats.${cfg.format.type}.nullConfig;
+    })
+  ]);
+}

modules/plugins/languages/nu.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) str either package listOf;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.lua) expToLua;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (builtins) isList;
+
+  defaultServer = "nushell";
+  servers = {
+    nushell = {
+      package = pkgs.nushell;
+      lspConfig = ''
+        lspconfig.nushell.setup{
+          capabilities = capabilities,
+          on_attach = default_on_attach,
+          cmd = ${
+          if isList cfg.lsp.package
+          then expToLua cfg.lsp.package
+          else ''{"${cfg.lsp.package}/bin/nu", "--no-config-file", "--lsp"}''
+        }
+        }
+      '';
+    };
+  };
+
+  cfg = config.vim.languages.nu;
+in {
+  options.vim.languages.nu = {
+    enable = mkEnableOption "Nu language support";
+
+    treesitter = {
+      enable = mkEnableOption "Nu treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "nu";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Nu LSP support" // {default = config.vim.languages.enableLSP;};
+      server = mkOption {
+        type = str;
+        default = defaultServer;
+        description = "Nu LSP server to use";
+      };
+
+      package = mkOption {
+        type = either package (listOf str);
+        default = servers.${cfg.lsp.server}.package;
+        example = ''[(lib.getExe pkgs.nushell) "--lsp"]'';
+        description = "Nu LSP server package, or the command to run as a list of strings";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.nu-lsp = servers.${cfg.lsp.server}.lspConfig;
+    })
+  ]);
+}

modules/plugins/languages/typst.nix

@@ -21,7 +21,10 @@
       lspConfig = ''
         lspconfig.typst_lsp.setup {
           capabilities = capabilities,
-          on_attach = default_on_attach,
+          on_attach = function(client, bufnr)
+            -- Disable semantic tokens as a workaround for a semantic token error when using non-english characters
+            client.server_capabilities.semanticTokensProvider = nil
+          end,
           cmd = ${
           if isList cfg.lsp.package
           then expToLua cfg.lsp.package
@@ -36,7 +39,10 @@
         lspconfig.tinymist.setup {
           capabilities = capabilities,
           single_file_support = true,
-          on_attach = default_on_attach,
+          on_attach = function(client, bufnr)
+            -- Disable semantic tokens as a workaround for a semantic token error when using non-english characters
+            client.server_capabilities.semanticTokensProvider = nil
+          end,
           cmd = ${
           if isList cfg.lsp.package
           then expToLua cfg.lsp.package