From c07136c7ba49391069b11b856d73d7b9f9083b3a Mon Sep 17 00:00:00 2001
From: dish <pyrox@pyrox.dev>
Date: Wed, 14 Jan 2026 13:24:13 -0500
Subject: [PATCH] toml: init language plugin

---
 configuration.nix                     |   1 +
 docs/manual/release-notes/rl-0.9.md   |   4 +
 modules/plugins/languages/default.nix |   1 +
 modules/plugins/languages/toml.nix    | 151 ++++++++++++++++++++++++++
 4 files changed, 157 insertions(+)
 create mode 100644 modules/plugins/languages/toml.nix

diff --git a/configuration.nix b/configuration.nix
index e3b85f92..b9e3b8ec 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -71,6 +71,7 @@ isMaximal: {
         enable = isMaximal;
         extensions.crates-nvim.enable = isMaximal;
       };
+      toml.enable = isMaximal;
 
       # Language modules that are not as common.
       assembly.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 437dddcf..929f442c 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -134,6 +134,10 @@
 
 - Added [Pyrefly](https://pyrefly.org/) support to `languages.python`
 
+- Added TOML support via {option}`languages.toml` and the
+  [Tombi](https://tombi-toml.github.io/tombi/) language server, linter, and
+  formatter.
+
 [Machshev](https://github.com/machshev):
 
 - Added `ruff` and `ty` LSP support for Python under `programs.python`.
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index fd45758f..9b0d241b 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -38,6 +38,7 @@ in {
     ./svelte.nix
     ./tailwind.nix
     ./terraform.nix
+    ./toml.nix
     ./ts.nix
     ./typst.nix
     ./zig.nix
diff --git a/modules/plugins/languages/toml.nix b/modules/plugins/languages/toml.nix
new file mode 100644
index 00000000..d771925b
--- /dev/null
+++ b/modules/plugins/languages/toml.nix
@@ -0,0 +1,151 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.types) bool enum;
+  inherit (lib.nvim.types) diagnostics mkGrammarOption deprecatedSingleOrListOf;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.toml;
+  defaultServers = ["tombi"];
+  servers = {
+    tombi = {
+      enable = true;
+      cmd = [
+        (getExe pkgs.tombi)
+        "lsp"
+      ];
+      filetypes = ["toml"];
+      root_markers = [
+        "tombi.toml"
+        ".git"
+      ];
+    };
+  };
+
+  defaultFormat = ["tombi"];
+  formats = {
+    tombi = {
+      command = getExe pkgs.tombi;
+      args = [
+        "format"
+        "--stdin-filepath"
+        "$FILENAME"
+        "-"
+      ];
+    };
+  };
+  defaultDiagnosticsProvider = ["tombi"];
+  diagnosticsProviders = {
+    tombi = {
+      package = pkgs.tombi;
+      args = ["lint"];
+    };
+  };
+in {
+  options.vim.languages.toml = {
+    enable = mkEnableOption "TOML configuration language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "TOML treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+        };
+      package = mkGrammarOption pkgs "toml";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "TOML LSP support"
+        // {
+          default = config.vim.lsp.enable;
+        };
+
+      servers = mkOption {
+        description = "TOML LSP server to use";
+        type = deprecatedSingleOrListOf "vim.language.toml.lsp.servers" (enum (attrNames servers));
+        default = defaultServers;
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "TOML formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+        };
+
+      type = mkOption {
+        type = deprecatedSingleOrListOf "vim.language.toml.format.type" (enum (attrNames formats));
+        default = defaultFormat;
+        description = "TOML formatter to use.";
+      };
+    };
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra TOML diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+        };
+      types = diagnostics {
+        langDesc = "TOML";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [
+        cfg.treesitter.package
+      ];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.toml = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.toml = cfg.extraDiagnostics.types;
+        linters = mkMerge (
+          map (name: {
+            ${name}.cmd = getExe diagnosticsProviders.${name}.package;
+          })
+          cfg.extraDiagnostics.types
+        );
+      };
+    })
+  ]);
+}