modules: start breaking down core modules; simplify tree structure

modules/plugins/terminal/toggleterm/config.nix

@@ -0,0 +1,68 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (builtins) toJSON;
+  inherit (lib) mkMerge mkIf mkBinding nvim getExe;
+
+  cfg = config.vim.terminal.toggleterm;
+in {
+  config = mkMerge [
+    (
+      mkIf cfg.enable {
+        vim.startPlugins = [
+          "toggleterm-nvim"
+        ];
+
+        vim.maps.normal = mkBinding cfg.mappings.open "<Cmd>execute v:count . \"ToggleTerm\"<CR>" "Toggle terminal";
+
+        vim.luaConfigRC.toggleterm = nvim.dag.entryAnywhere ''
+          require("toggleterm").setup({
+            open_mapping = null,
+            direction = '${toString cfg.direction}',
+            -- TODO: this should probably be turned into a module that uses the lua function if and only if the user has not set it
+            size = function(term)
+              if term.direction == "horizontal" then
+                return 15
+              elseif term.direction == "vertical" then
+                return vim.o.columns * 0.4
+              end
+            end,
+            winbar = {
+              enabled = '${toString cfg.enable_winbar}',
+              name_formatter = function(term) --  term: Terminal
+                return term.name
+              end
+            },
+          })
+        '';
+      }
+    )
+    (
+      mkIf (cfg.enable && cfg.lazygit.enable)
+      {
+        vim.startPlugins = lib.optionals (cfg.lazygit.package != null) [
+          cfg.lazygit.package
+        ];
+        vim.luaConfigRC.toggleterm-lazygit = nvim.dag.entryAfter ["toggleterm"] ''
+          local terminal = require 'toggleterm.terminal'
+          local lazygit = terminal.Terminal:new({
+            cmd = '${
+            if (cfg.lazygit.package != null)
+            then getExe cfg.lazygit.package
+            else "lazygit"
+          }',
+            direction = '${cfg.lazygit.direction}',
+            hidden = true,
+            on_open = function(term)
+              vim.cmd("startinsert!")
+            end
+          })
+
+          vim.keymap.set('n', ${toJSON cfg.lazygit.mappings.open}, function() lazygit:toggle() end, {silent = true, noremap = true, desc = 'Open lazygit [toggleterm]'})
+        '';
+      }
+    )
+  ];
+}

modules/plugins/terminal/toggleterm/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./toggleterm.nix
+    ./config.nix
+  ];
+}

modules/plugins/terminal/toggleterm/toggleterm.nix

@@ -0,0 +1,50 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkOption types mkMappingOption;
+in {
+  options.vim.terminal.toggleterm = {
+    enable = mkEnableOption "toggleterm as a replacement to built-in terminal command";
+    mappings = {
+      open = mkOption {
+        type = types.nullOr types.str;
+        description = "The keymapping to open toggleterm";
+        default = "<c-t>";
+      };
+    };
+
+    direction = mkOption {
+      type = types.enum ["horizontal" "vertical" "tab" "float"];
+      default = "horizontal";
+      description = "Direction of the terminal";
+    };
+
+    enable_winbar = mkOption {
+      type = types.bool;
+      default = false;
+      description = "Enable winbar";
+    };
+
+    lazygit = {
+      enable = mkEnableOption "LazyGit integration";
+      direction = mkOption {
+        type = types.enum ["horizontal" "vertical" "tab" "float"];
+        default = "float";
+        description = "Direction of the lazygit window";
+      };
+
+      package = mkOption {
+        type = with types; nullOr package;
+        default = pkgs.lazygit;
+        description = "The package that should be used for lazygit. Setting it to null will attempt to use lazygit from your PATH";
+      };
+
+      mappings = {
+        open = mkMappingOption "Open lazygit [toggleterm]" "<leader>gg";
+      };
+    };
+  };
+}