modules: start breaking down core modules; simplify tree structure

modules/plugins/notes/default.nix

@@ -0,0 +1,8 @@
+_: {
+  imports = [
+    ./obsidian
+    ./orgmode
+    ./mind-nvim
+    ./todo-comments
+  ];
+}

modules/plugins/notes/mind-nvim/config.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkIf nvim;
+
+  cfg = config.vim.notes.mind-nvim;
+in {
+  config = mkIf (cfg.enable) {
+    vim.startPlugins = [
+      "mind-nvim"
+    ];
+
+    vim.maps.normal = {
+      "<leader>om" = {action = ":MindOpenMain<CR>";};
+      "<leader>op" = {action = ":MindOpenProject<CR>";};
+      "<leader>oc" = {action = ":MindClose<CR>";};
+    };
+
+    vim.luaConfigRC.mind-nvim = nvim.dag.entryAnywhere ''
+      require'mind'.setup()
+    '';
+  };
+}

modules/plugins/notes/mind-nvim/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./mind-nvim.nix
+    ./config.nix
+  ];
+}

modules/plugins/notes/mind-nvim/mind-nvim.nix

@@ -0,0 +1,11 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption;
+in {
+  options.vim.notes.mind-nvim = {
+    enable = mkEnableOption "organizer tool for Neovim.";
+  };
+}

modules/plugins/notes/obsidian/config.nix

@@ -0,0 +1,43 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkIf nvim;
+
+  cfg = config.vim.notes.obsidian;
+  auto = config.vim.autocomplete;
+in {
+  config = mkIf (cfg.enable) {
+    vim.startPlugins = [
+      "obsidian-nvim"
+      "vim-markdown"
+      "tabular"
+    ];
+
+    vim.luaConfigRC.obsidian = nvim.dag.entryAnywhere ''
+      require("obsidian").setup({
+        dir = "${cfg.dir}",
+        completion = {
+          nvim_cmp = ${
+        if (auto.type == "nvim-cmp")
+        then "true"
+        else "false"
+      }
+        },
+        daily_notes = {
+          folder = ${
+        if (cfg.daily-notes.folder == "")
+        then "nil,"
+        else "'${cfg.daily-notes.folder}',"
+      }
+          date_format = ${
+        if (cfg.daily-notes.date-format == "")
+        then "nil,"
+        else "'${cfg.daily-notes.date-format}',"
+      }
+        }
+      })
+    '';
+  };
+}

modules/plugins/notes/obsidian/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./obsidian.nix
+    ./config.nix
+  ];
+}

modules/plugins/notes/obsidian/obsidian.nix

@@ -0,0 +1,39 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkOption types;
+in {
+  options.vim.notes = {
+    obsidian = {
+      enable = mkEnableOption "complementary neovim plugins for Obsidian editor";
+      dir = mkOption {
+        type = types.str;
+        default = "~/my-vault";
+        description = "Obsidian vault directory";
+      };
+
+      daily-notes = {
+        folder = mkOption {
+          type = types.str;
+          default = "";
+          description = "Directory in which daily notes should be created";
+        };
+        date-format = mkOption {
+          type = types.str;
+          default = "";
+          description = "Date format used for creating daily notes";
+        };
+      };
+
+      completion = {
+        nvim_cmp = mkOption {
+          # if using nvim-cmp, otherwise set to false
+          type = types.bool;
+          description = "If using nvim-cmp, otherwise set to false";
+        };
+      };
+    };
+  };
+}

modules/plugins/notes/orgmode/config.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkIf mkMerge nvim;
+
+  cfg = config.vim.notes.orgmode;
+in {
+  config = mkIf cfg.enable (mkMerge [
+    {
+      vim.startPlugins = [
+        "orgmode-nvim"
+      ];
+
+      vim.luaConfigRC.orgmode = nvim.dag.entryAnywhere ''
+        -- Load custom treesitter grammar for org filetype
+        require('orgmode').setup_ts_grammar()
+
+        -- Treesitter configuration
+        require('nvim-treesitter.configs').setup {
+
+          -- If TS highlights are not enabled at all, or disabled via `disable` prop,
+          -- highlighting will fallback to default Vim syntax highlighting
+          highlight = {
+            enable = true,
+            -- Required for spellcheck, some LaTex highlights and
+            -- code block highlights that do not have ts grammar
+            additional_vim_regex_highlighting = {'org'},
+          },
+        }
+
+        require('orgmode').setup({
+          org_agenda_files = ${cfg.orgAgendaFiles},
+          org_default_notes_file = '${cfg.orgDefaultNotesFile}',
+        })
+      '';
+    }
+
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+
+      vim.treesitter.grammars = [cfg.treesitter.orgPackage];
+    })
+  ]);
+}

modules/plugins/notes/orgmode/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./orgmode.nix
+    ./config.nix
+  ];
+}

modules/plugins/notes/orgmode/orgmode.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) mkEnableOption types mkOption nvim;
+in {
+  options.vim.notes.orgmode = {
+    enable = mkEnableOption "nvim-orgmode: Neovim plugin for Emac Orgmode. Get the best of both worlds";
+
+    orgAgendaFiles = mkOption {
+      type = types.str;
+      default = "{'~/Documents/org/*', '~/my-orgs/**/*'}";
+      description = "List of org files to be used as agenda files.";
+    };
+
+    orgDefaultNotesFile = mkOption {
+      type = types.str;
+      default = "~/Documents/org/refile.org";
+      description = "Default org file to be used for notes.";
+    };
+
+    treesitter = {
+      enable = mkEnableOption "Orgmode treesitter" // {default = config.vim.languages.enableTreesitter;};
+
+      orgPackage = nvim.types.mkGrammarOption pkgs "org";
+    };
+  };
+}

modules/plugins/notes/todo-comments/config.nix

@@ -0,0 +1,49 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkMerge mkBinding mkIf;
+
+  cfg = config.vim.notes.todo-comments;
+  self = import ./todo-comments.nix {inherit lib;};
+  mappings = self.options.vim.notes.todo-comments.mappings;
+in {
+  config = mkIf (cfg.enable) {
+    vim.startPlugins = [
+      "todo-comments"
+    ];
+
+    vim.maps.normal = mkMerge [
+      (mkBinding cfg.mappings.quickFix ":TodoQuickFix<CR>" mappings.quickFix.description)
+      (mkIf config.vim.telescope.enable (mkBinding cfg.mappings.telescope ":TodoTelescope<CR>" mappings.telescope.description))
+      (mkIf config.vim.lsp.trouble.enable (mkBinding cfg.mappings.trouble ":TodoTrouble<CR>" mappings.trouble.description))
+    ];
+
+    vim.luaConfigRC.todo-comments = ''
+      require('todo-comments').setup {
+        highlight = {
+          before = "", -- "fg" or "bg" or empty
+          keyword = "bg", -- "fg", "bg", "wide" or empty
+          after = "fg", -- "fg" or "bg" or empty
+          pattern = ${cfg.patterns.highlight},
+          comments_only = true, -- uses treesitter to match keywords in comments only
+          max_line_len = 400, -- ignore lines longer than this
+          exclude = {}, -- list of file types to exclude highlighting
+        },
+        search = {
+          command = "${pkgs.ripgrep}/bin/rg",
+          args = {
+            "--color=never",
+            "--no-heading",
+            "--with-filename",
+            "--line-number",
+            "--column",
+          },
+          pattern = ${cfg.patterns.search},
+        },
+      }
+    '';
+  };
+}

modules/plugins/notes/todo-comments/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./todo-comments.nix
+    ./config.nix
+  ];
+}

modules/plugins/notes/todo-comments/todo-comments.nix

@@ -0,0 +1,27 @@
+{lib, ...}: let
+  inherit (lib) mkEnableOption mkOption types mkMappingOption;
+in {
+  options.vim.notes.todo-comments = {
+    enable = mkEnableOption "todo-comments: highlight and search for todo comments like TODO, HACK, BUG in your code base";
+
+    patterns = {
+      highlight = mkOption {
+        type = types.str;
+        default = ''[[.*<(KEYWORDS)(\([^\)]*\))?:]]'';
+        description = "vim regex pattern used for highlighting comments";
+      };
+
+      search = mkOption {
+        type = types.str;
+        default = ''[[\b(KEYWORDS)(\([^\)]*\))?:]]'';
+        description = "ripgrep regex pattern used for searching comments";
+      };
+    };
+
+    mappings = {
+      quickFix = mkMappingOption "Open Todo-s in a quickfix list" "<leader>tdq";
+      telescope = mkMappingOption "Open Todo-s in telescope" "<leader>tds";
+      trouble = mkMappingOption "Open Todo-s in Trouble" "<leader>tdt";
+    };
+  };
+}