modules: start breaking down core modules; simplify tree structure

modules/plugins/minimap/codewindow/codewindow.nix

@@ -0,0 +1,14 @@
+{lib, ...}: let
+  inherit (lib) mkEnableOption mkMappingOption;
+in {
+  options.vim.minimap.codewindow = {
+    enable = mkEnableOption "codewindow plugin for minimap view";
+
+    mappings = {
+      open = mkMappingOption "Open minimap [codewindow]" "<leader>mo";
+      close = mkMappingOption "Close minimap [codewindow]" "<leader>mc";
+      toggle = mkMappingOption "Toggle minimap [codewindow]" "<leader>mm";
+      toggleFocus = mkMappingOption "Toggle minimap focus [codewindow]" "<leader>mf";
+    };
+  };
+}

modules/plugins/minimap/codewindow/config.nix

@@ -0,0 +1,34 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) addDescriptionsToMappings mkIf mkMerge mkSetLuaBinding nvim;
+
+  cfg = config.vim.minimap.codewindow;
+
+  self = import ./codewindow.nix {inherit lib;};
+
+  mappingDefinitions = self.options.vim.minimap.codewindow.mappings;
+  mappings = addDescriptionsToMappings cfg.mappings mappingDefinitions;
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins = [
+      "codewindow-nvim"
+    ];
+
+    vim.maps.normal = mkMerge [
+      (mkSetLuaBinding mappings.open "require('codewindow').open_minimap")
+      (mkSetLuaBinding mappings.close "require('codewindow').close_minimap")
+      (mkSetLuaBinding mappings.toggle "require('codewindow').toggle_minimap")
+      (mkSetLuaBinding mappings.toggleFocus "require('codewindow').toggle_focus")
+    ];
+
+    vim.luaConfigRC.codewindow = nvim.dag.entryAnywhere ''
+      local codewindow = require('codewindow')
+      codewindow.setup({
+        exclude_filetypes = { 'NvimTree', 'orgagenda', 'Alpha'},
+      })
+    '';
+  };
+}

modules/plugins/minimap/codewindow/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./codewindow.nix
+    ./config.nix
+  ];
+}

modules/plugins/minimap/default.nix

@@ -0,0 +1,6 @@
+{...}: {
+  imports = [
+    ./minimap-vim
+    ./codewindow
+  ];
+}

modules/plugins/minimap/minimap-vim/config.nix

@@ -0,0 +1,17 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkIf;
+
+  cfg = config.vim.minimap.minimap-vim;
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins = [
+      pkgs.code-minimap
+      "minimap-vim"
+    ];
+  };
+}

modules/plugins/minimap/minimap-vim/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./minimap-vim.nix
+    ./config.nix
+  ];
+}

modules/plugins/minimap/minimap-vim/minimap-vim.nix

@@ -0,0 +1,11 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption;
+in {
+  options.vim.minimap.minimap-vim = {
+    enable = mkEnableOption "minimap-vim plugin for minimap view";
+  };
+}