modules: start breaking down core modules; simplify tree structure

modules/plugins/autopairs/nvim-autopairs/config.nix

@@ -0,0 +1,26 @@
+{
+  lib,
+  config,
+  ...
+}: let
+  inherit (lib) mkIf nvim optionalString boolToString;
+
+  cfg = config.vim.autopairs;
+in {
+  config =
+    mkIf (cfg.enable)
+    {
+      vim.startPlugins = ["nvim-autopairs"];
+
+      vim.luaConfigRC.autopairs = nvim.dag.entryAnywhere ''
+        require("nvim-autopairs").setup{}
+        ${optionalString (config.vim.autocomplete.type == "nvim-compe") ''
+          require('nvim-autopairs.completion.compe').setup({
+            map_cr = ${boolToString cfg.nvim-compe.map_cr},
+            map_complete = ${boolToString cfg.nvim-compe.map_complete},
+            auto_select = ${boolToString cfg.nvim-compe.auto_select},
+          })
+        ''}
+      '';
+    };
+}

modules/plugins/autopairs/nvim-autopairs/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./config.nix
+    ./nvim-autopairs.nix
+  ];
+}

modules/plugins/autopairs/nvim-autopairs/nvim-autopairs.nix

@@ -0,0 +1,35 @@
+{lib, ...}: let
+  inherit (lib) mkEnableOption mkOption types;
+in {
+  options.vim = {
+    autopairs = {
+      enable = mkEnableOption "autopairs" // {default = false;};
+
+      type = mkOption {
+        type = types.enum ["nvim-autopairs"];
+        default = "nvim-autopairs";
+        description = "Set the autopairs type. Options: nvim-autopairs [nvim-autopairs]";
+      };
+
+      nvim-compe = {
+        map_cr = mkOption {
+          type = types.bool;
+          default = true;
+          description = ''map <CR> on insert mode'';
+        };
+
+        map_complete = mkOption {
+          type = types.bool;
+          default = true;
+          description = "auto insert `(` after select function or method item";
+        };
+
+        auto_select = mkOption {
+          type = types.bool;
+          default = false;
+          description = "auto select first item";
+        };
+      };
+    };
+  };
+}