modules: start breaking down core modules; simplify tree structure

modules/plugins/assistant/copilot/config.nix

@@ -0,0 +1,90 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  inherit (builtins) toJSON;
+  inherit (lib) mkIf nvim mkLuaBinding mkMerge;
+
+  cfg = config.vim.assistant.copilot;
+
+  wrapPanelBinding = luaFunction: key: ''
+    function()
+      local s, _ = pcall(${luaFunction})
+
+      if not s then
+        local termcode = vim.api.nvim_replace_termcodes(${toJSON key}, true, false, true)
+
+        vim.fn.feedkeys(termcode, 'n')
+      end
+    end
+  '';
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins =
+      [
+        "copilot-lua"
+        cfg.copilotNodePackage
+      ]
+      ++ lib.optionals (cfg.cmp.enable) [
+        "copilot-cmp"
+      ];
+
+    vim.luaConfigRC.copilot = nvim.dag.entryAnywhere ''
+      require("copilot").setup({
+        -- available options: https://github.com/zbirenbaum/copilot.lua
+        copilot_node_command = "${cfg.copilotNodeCommand}",
+        panel = {
+          enabled = ${lib.boolToString (!cfg.cmp.enable)},
+          keymap = {
+            jump_prev = false,
+            jump_next = false,
+            accept = false,
+            refresh = false,
+            open = false,
+          },
+          layout = {
+            position = "${cfg.panel.position}",
+            ratio = ${toString cfg.panel.ratio},
+          },
+        },
+        suggestion = {
+          enabled = ${lib.boolToString (!cfg.cmp.enable)},
+          keymap = {
+            accept = false,
+            accept_word = false,
+            accept_line = false,
+            next = false,
+            prev = false,
+            dismiss = false,
+          },
+        },
+      })
+
+      ${lib.optionalString (cfg.cmp.enable) ''
+        require("copilot_cmp").setup()
+      ''}
+    '';
+
+    vim.maps.normal = mkMerge [
+      (mkLuaBinding cfg.mappings.panel.jumpPrev (wrapPanelBinding "require(\"copilot.panel\").jump_prev" cfg.mappings.panel.jumpPrev) "[copilot] Accept suggestion")
+      (mkLuaBinding cfg.mappings.panel.jumpNext (wrapPanelBinding "require(\"copilot.panel\").jump_next" cfg.mappings.panel.jumpNext) "[copilot] Accept suggestion")
+      (mkLuaBinding cfg.mappings.panel.accept (wrapPanelBinding ''require("copilot.panel").accept'' cfg.mappings.panel.accept) "[copilot] Accept suggestion")
+      (mkLuaBinding cfg.mappings.panel.refresh (wrapPanelBinding "require(\"copilot.panel\").refresh" cfg.mappings.panel.refresh) "[copilot] Accept suggestion")
+      (mkLuaBinding cfg.mappings.panel.open (wrapPanelBinding ''
+          function() require("copilot.panel").open({ position = "${cfg.panel.position}", ratio = ${toString cfg.panel.ratio}, }) end
+        ''
+        cfg.mappings.panel.open) "[copilot] Accept suggestion")
+    ];
+
+    vim.maps.insert = mkMerge [
+      (mkLuaBinding cfg.mappings.suggestion.accept "require(\"copilot.suggestion\").accept" "[copilot] Accept suggestion")
+      (mkLuaBinding cfg.mappings.suggestion.acceptLine "require(\"copilot.suggestion\").accept_line" "[copilot] Accept suggestion (line)")
+      (mkLuaBinding cfg.mappings.suggestion.acceptWord "require(\"copilot.suggestion\").accept_word" "[copilot] Accept suggestion (word)")
+      (mkLuaBinding cfg.mappings.suggestion.next "require(\"copilot.suggestion\").next" "[copilot] next suggestion")
+      (mkLuaBinding cfg.mappings.suggestion.prev "require(\"copilot.suggestion\").prev" "[copilot] previous suggestion")
+      (mkLuaBinding cfg.mappings.suggestion.dismiss "require(\"copilot.suggestion\").dismiss" "[copilot] dismiss suggestion")
+    ];
+  };
+}

modules/plugins/assistant/copilot/copilot.nix

@@ -0,0 +1,113 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkOption types;
+
+  cfg = config.vim.assistant.copilot;
+in {
+  options.vim.assistant.copilot = {
+    enable = mkEnableOption "GitHub Copilot AI assistant";
+    cmp.enable = mkEnableOption "nvim-cmp integration for GitHub Copilot";
+
+    panel = {
+      position = mkOption {
+        type = types.enum [
+          "bottom"
+          "top"
+          "left"
+          "right"
+        ];
+        default = "bottom";
+        description = "Panel position";
+      };
+      ratio = mkOption {
+        type = types.float;
+        default = 0.4;
+        description = "Panel size";
+      };
+    };
+
+    mappings = {
+      panel = {
+        jumpPrev = mkOption {
+          type = types.nullOr types.str;
+          default = "[[";
+          description = "Jump to previous suggestion";
+        };
+        jumpNext = mkOption {
+          type = types.nullOr types.str;
+          default = "]]";
+          description = "Jump to next suggestion";
+        };
+        accept = mkOption {
+          type = types.nullOr types.str;
+          default = "<CR>";
+          description = "Accept suggestion";
+        };
+        refresh = mkOption {
+          type = types.nullOr types.str;
+          default = "gr";
+          description = "Refresh suggestions";
+        };
+        open = mkOption {
+          type = types.nullOr types.str;
+          default = "<M-CR>";
+          description = "Open suggestions";
+        };
+      };
+      suggestion = {
+        accept = mkOption {
+          type = types.nullOr types.str;
+          default = "<M-l>";
+          description = "Accept suggetion";
+        };
+        acceptWord = mkOption {
+          type = types.nullOr types.str;
+          default = null;
+          description = "Accept next word";
+        };
+        acceptLine = mkOption {
+          type = types.nullOr types.str;
+          default = null;
+          description = "Accept next line";
+        };
+        prev = mkOption {
+          type = types.nullOr types.str;
+          default = "<M-[>";
+          description = "Previous suggestion";
+        };
+        next = mkOption {
+          type = types.nullOr types.str;
+          default = "<M-]>";
+          description = "Next suggestion";
+        };
+        dismiss = mkOption {
+          type = types.nullOr types.str;
+          default = "<C-]>";
+          description = "Dismiss suggestion";
+        };
+      };
+    };
+
+    copilotNodeCommand = mkOption {
+      type = types.str;
+      default = "${lib.getExe cfg.copilotNodePackage}";
+      description = ''
+        The command that will be executed to initiate nodejs for GitHub Copilot.
+        Recommended to leave as default.
+      '';
+    };
+
+    copilotNodePackage = mkOption {
+      type = with types; nullOr package;
+      default = pkgs.nodejs-slim;
+      description = ''
+        The nodeJS package that will be used for GitHub Copilot. If you are using a custom node command
+        you may want to set this option to null so that the package is not pulled from nixpkgs.
+      '';
+    };
+  };
+}

modules/plugins/assistant/copilot/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./copilot.nix
+    ./config.nix
+  ];
+}

modules/plugins/assistant/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./copilot
+    # ./tabnine.nix # removed until I find a way around the initialisation script the plugin requires
+  ];
+}

modules/plugins/assistant/tabnine/config.nix

@@ -0,0 +1,54 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (builtins) toJSON;
+  inherit (lib) mkIf mkMerge mkExprBinding boolToString nvim;
+
+  cfg = config.vim.assistant.tabnine;
+in {
+  config = mkIf cfg.enable {
+    vim.startPlugins = ["tabnine-nvim"];
+
+    vim.maps.insert = mkMerge [
+      (mkExprBinding cfg.mappings.accept ''
+        function()
+          local state = require("tabnine.state")
+          local completion = require("tabnine.completion")
+
+        	if not state.completions_cache then
+          	return "${toJSON cfg.mappings.accept}"
+          end
+
+          vim.schedule(completion.accept)
+        end
+      '' "orzel")
+      (mkExprBinding cfg.mappings.dismiss ''
+        function()
+          local state = require("tabnine.state")
+          local completion = require("tabnine.completion")
+
+        	if not state.completions_cache then
+          	return "${toJSON cfg.mappings.dismiss}"
+          end
+
+          vim.schedule(function()
+            completion.clear()
+            state.completions_cache = nil
+          end)
+        end
+      '' "orzel")
+    ];
+
+    vim.luaConfigRC.tabnine-nvim = nvim.dag.entryAnywhere ''
+      require('tabnine').setup({
+        disable_auto_comment = ${boolToString cfg.disable_auto_comment},
+        accept_keymap = null,
+        dismiss_keymap = null,
+        debounce_ms = ${cfg.debounce_ms},
+        exclude_filetypes = ${cfg.exclude_filetypes},
+      })
+    '';
+  };
+}

modules/plugins/assistant/tabnine/default.nix

@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./config.nix
+    ./tabnine.nix
+  ];
+}

modules/plugins/assistant/tabnine/tabnine.nix

@@ -0,0 +1,30 @@
+{lib, ...}: let
+  inherit (lib) mkEnableOption mkOption types mkMappingOption;
+in {
+  options.vim.assistant.tabnine = {
+    enable = mkEnableOption "Tabnine assistant";
+
+    disable_auto_comment = mkOption {
+      type = types.bool;
+      default = true;
+      description = "Disable auto comment";
+    };
+
+    mappings = {
+      accept = mkMappingOption "Accept [Tabnine]" "<Tab>";
+      dismiss = mkMappingOption "Dismiss [Tabnine]" "<C-]>";
+    };
+
+    debounce_ms = mkOption {
+      type = types.int;
+      default = 800;
+      description = "Debounce ms";
+    };
+
+    exclude_filetypes = mkOption {
+      type = types.listOf types.str;
+      default = ["TelescopePrompt" "NvimTree" "alpha"];
+      description = "Exclude filetypes";
+    };
+  };
+}