languages/vhdl: init

modules/plugins/languages/default.nix

@@ -48,6 +48,7 @@ in {
     ./scala.nix
     ./sql.nix
     ./svelte.nix
+    ./vhdl.nix
     ./vue.nix
     ./terraform.nix
     ./toml.nix

modules/plugins/languages/vhdl.nix

@@ -0,0 +1,65 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkOption mkEnableOption literalExpression;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum bool listOf;
+  inherit (lib) genAttrs;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.vhdl;
+
+  defaultServers = ["vhdl-ls"];
+  servers = ["vhdl-ls"];
+in {
+  options.vim.languages.vhdl = {
+    enable = mkEnableOption "VHDL language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "VHDL treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+          defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        };
+      package = mkGrammarOption pkgs "vhdl";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "VHDL LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+      servers = mkOption {
+        type = listOf (enum servers);
+        default = defaultServers;
+        description = "VHDL LSP server to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp = {
+        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
+        servers = genAttrs cfg.lsp.servers (_: {
+          filetypes = ["vhdl"];
+        });
+      };
+    })
+  ]);
+}

modules/plugins/lsp/presets/default.nix

@@ -72,6 +72,7 @@
     ./typescript-go.nix
     ./typescript-language-server.nix
     ./vala-language-server.nix
+    ./vhdl-ls.nix
     ./vscode-css-language-server.nix
     ./vscode-json-language-server.nix
     ./vtsls.nix

modules/plugins/lsp/presets/vhdl-ls.nix

@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.types) mkLspPresetEnableOption;
+
+  cfg = config.vim.lsp.presets.vhdl-ls;
+in {
+  options.vim.lsp.presets.vhdl-ls = {
+    enable = mkLspPresetEnableOption "vhdl-ls" "VHDL" [];
+  };
+
+  config = mkIf cfg.enable {
+    vim.lsp.servers.vhdl-ls = {
+      enable = true;
+      cmd = [(getExe pkgs.vhdl-ls)];
+      root_markers = [".git" "vhdl_ls.toml"];
+    };
+  };
+}