From 2efe2147c166da28e3e5fe5db51be0afc3f0f71d Mon Sep 17 00:00:00 2001
From: Snoweuph <snow@euph.email>
Date: Sun, 1 Feb 2026 11:52:33 +0100
Subject: [PATCH] language/make: add treesitter, formatter and diagnostics
 support

---
 configuration.nix                     |  1 +
 docs/manual/release-notes/rl-0.9.md   |  2 +
 modules/plugins/languages/default.nix |  1 +
 modules/plugins/languages/make.nix    | 93 +++++++++++++++++++++++++++
 4 files changed, 97 insertions(+)
 create mode 100644 modules/plugins/languages/make.nix

diff --git a/configuration.nix b/configuration.nix
index 958311b1..2602a811 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -92,6 +92,7 @@ isMaximal: {
       ruby.enable = false;
       fsharp.enable = false;
       just.enable = false;
+      make.enable = false;
       qml.enable = false;
       jinja.enable = false;
       tailwind.enable = false;
diff --git a/docs/manual/release-notes/rl-0.9.md b/docs/manual/release-notes/rl-0.9.md
index 662f7aeb..735ef61d 100644
--- a/docs/manual/release-notes/rl-0.9.md
+++ b/docs/manual/release-notes/rl-0.9.md
@@ -172,6 +172,8 @@
 
 - Added [`golangci-lint`](https://golangci-lint.run/) for more diagnostics.
 
+- Added Makefile support via `languages.make`.
+
 [vagahbond](https://github.com/vagahbond): [codewindow.nvim]:
 https://github.com/gorbit99/codewindow.nvim
 
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 7cc5bda5..0986e1e1 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -52,6 +52,7 @@ in {
     ./yaml.nix
     ./ruby.nix
     ./just.nix
+    ./make.nix
     ./xml.nix
 
     # This is now a hard deprecation.
diff --git a/modules/plugins/languages/make.nix b/modules/plugins/languages/make.nix
new file mode 100644
index 00000000..f7780cd9
--- /dev/null
+++ b/modules/plugins/languages/make.nix
@@ -0,0 +1,93 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.meta) getExe;
+  inherit (lib.types) listOf enum;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.make;
+
+  defaultFormat = ["bake"];
+  formats = {
+    bake = {
+      command = "${pkgs.mbake}/bin/mbake";
+    };
+  };
+
+  defaultDiagnosticsProvider = ["checkmake"];
+  diagnosticsProviders = {
+    checkmake = {
+      config = {
+        cmd = getExe pkgs.checkmake;
+      };
+    };
+  };
+in {
+  options.vim.languages.make = {
+    enable = mkEnableOption "Make support";
+
+    treesitter = {
+      enable = mkEnableOption "Make treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "make";
+    };
+
+    format = {
+      enable = mkEnableOption "Make formatting" // {default = config.vim.languages.enableFormat;};
+      type = mkOption {
+        description = "make formatter to use";
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+      };
+    };
+
+    extraDiagnostics = {
+      enable = mkEnableOption "extra Make diagnostics" // {default = config.vim.languages.enableExtraDiagnostics;};
+      types = diagnostics {
+        langDesc = "Make";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.make = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.make = cfg.extraDiagnostics.types;
+        linters =
+          mkMerge (map (name: {${name} = diagnosticsProviders.${name}.config;})
+            cfg.extraDiagnostics.types);
+      };
+    })
+  ]);
+}