From 4b99fb6d90cd048afa827e38bf9464b512f0d7f3 Mon Sep 17 00:00:00 2001
From: Cool-Game-Dev <softwaredevelopment.stingray177@passinbox.com>
Date: Sat, 26 Jul 2025 18:45:42 -0500
Subject: [PATCH] language/just: init

Create the module `vim.languages.just` which provides support for
treesitting and just-lsp.
---
 configuration.nix                     |  1 +
 docs/release-notes/rl-0.8.md          |  7 +++
 modules/plugins/languages/default.nix |  1 +
 modules/plugins/languages/just.nix    | 64 +++++++++++++++++++++++++++
 4 files changed, 73 insertions(+)
 create mode 100644 modules/plugins/languages/just.nix

diff --git a/configuration.nix b/configuration.nix
index b3828826..537a6863 100644
--- a/configuration.nix
+++ b/configuration.nix
@@ -87,6 +87,7 @@ isMaximal: {
       hcl.enable = false;
       ruby.enable = false;
       fsharp.enable = false;
+      just.enable = false;
 
       tailwind.enable = false;
       svelte.enable = false;
diff --git a/docs/release-notes/rl-0.8.md b/docs/release-notes/rl-0.8.md
index c72f65d7..6c871c75 100644
--- a/docs/release-notes/rl-0.8.md
+++ b/docs/release-notes/rl-0.8.md
@@ -468,4 +468,11 @@
   https://github.com/NotAShelf/nvf/commit/fc8206e7a61d7eb02006f9010e62ebdb3336d0d2).
 
 [soliprem](https://github.com/soliprem):
+
 - fix broken `neorg` grammars
+
+[Cool-Game-Dev](https://github.com/Cool-Game-Dev):
+
+[just-lsp]: https://github.com/terror/just-lsp
+
+- Add just support under `vim.languages.just` using [just-lsp].
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 961d7cc5..803c076c 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -46,6 +46,7 @@ in {
     ./wgsl.nix
     ./yaml.nix
     ./ruby.nix
+    ./just.nix
 
     # This is now a hard deprecation.
     (mkRenamedOptionModule ["vim" "languages" "enableLSP"] ["vim" "lsp" "enable"])
diff --git a/modules/plugins/languages/just.nix b/modules/plugins/languages/just.nix
new file mode 100644
index 00000000..7645f255
--- /dev/null
+++ b/modules/plugins/languages/just.nix
@@ -0,0 +1,64 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.meta) getExe;
+  inherit (lib.types) enum listOf;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.just;
+
+  defaultServers = ["just-lsp"];
+  servers = {
+    just-lsp = {
+      enable = true;
+      cmd = [(getExe pkgs.just-lsp)];
+      filetypes = ["just"];
+      root_markers = [".git" "justfile"];
+    };
+  };
+in {
+  options.vim.languages.just = {
+    enable = mkEnableOption "Just support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "Just treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "just";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "Just LSP support" // {default = config.vim.lsp.enable;};
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Just LSP server to use";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [cfg.treesitter.package];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers =
+        mapListToAttrs (n: {
+          name = n;
+          value = servers.${n};
+        })
+        cfg.lsp.servers;
+    })
+  ]);
+}