nix: initial tooling

Signed-off-by: NotAShelf <raf@notashelf.dev>
Change-Id: If73b2f64914bc4fe934eba44985e34646a6a6964

.envrc

@@ -0,0 +1,2 @@
+use flake
+

flake.lock

@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1773579282,
+        "narHash": "sha256-LWvZj9Bvm1EuoO6zbX4yjZebwnZNfeTbmCJGS7RGQ3Y=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "5a88de74db0e948139be4b46f9a94d64aa11391c",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,22 @@
+{
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs?ref=nixos-unstable";
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    systems = ["x86_64-linux" "aarch64-linux"];
+    forEachSystem = nixpkgs.lib.genAttrs systems;
+    pkgsForEach = nixpkgs.legacyPackages;
+  in {
+    packages = forEachSystem (system: {
+      default = pkgsForEach.${system}.callPackage ./nix/package.nix {};
+    });
+
+    devShells = forEachSystem (system: {
+      default = pkgsForEach.${system}.callPackage ./nix/shell.nix {};
+    });
+
+    hydraJobs = self.packages;
+  };
+}

nix/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  rustPlatform,
+}:
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "konservejo";
+  version = "0.1.0";
+
+  src = let
+    fs = lib.fileset;
+    s = ../.;
+  in
+    fs.toSource {
+      root = s;
+      fileset = fs.unions [
+        (fs.fileFilter (file: builtins.any file.hasExt ["rs"]) (s + /src))
+        (s + /Cargo.lock)
+        (s + /Cargo.toml)
+      ];
+    };
+
+  cargoLock.lockFile = "${finalAttrs.src}/Cargo.lock";
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Forgejo backup service";
+    maintainers = with lib.maintainers; [NotAShelf];
+  };
+})

nix/shell.nix

@@ -0,0 +1,30 @@
+{
+  mkShell,
+  rustc,
+  cargo,
+  rust-analyzer-unwrapped,
+  rustfmt,
+  clippy,
+  taplo,
+  rustPlatform,
+}:
+mkShell {
+  name = "rust";
+
+  strictDeps = true;
+  packages = [
+    rustc
+    cargo
+
+    # Tools
+    rustfmt
+    clippy
+    cargo
+    taplo
+
+    # LSP
+    rust-analyzer-unwrapped
+  ];
+
+  RUST_SRC_PATH = "${rustPlatform.rustLibSrc}";
+}